src/moonshot-id.vala

   1 /*
   2  * Copyright (c) 2011-2016, JANET(UK)
   3  * All rights reserved.
   4  *
   5  * Redistribution and use in source and binary forms, with or without
   6  * modification, are permitted provided that the following conditions
   7  * are met:
   8  *
   9  * 1. Redistributions of source code must retain the above copyright
  10  *    notice, this list of conditions and the following disclaimer.
  11  *
  12  * 2. Redistributions in binary form must reproduce the above copyright
  13  *    notice, this list of conditions and the following disclaimer in the
  14  *    documentation and/or other materials provided with the distribution.
  15  *
  16  * 3. Neither the name of JANET(UK) nor the names of its contributors
  17  *    may be used to endorse or promote products derived from this software
  18  *    without specific prior written permission.
  19  *
  20  * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS"
  21  * AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  22  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  23  * ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDER OR CONTRIBUTORS BE LIABLE
  24  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  25  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  26  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  27  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  28  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  29  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  30  * SUCH DAMAGE.
  31 */
  32
  33 using Gee;
  34
  35 extern char* get_cert_valid_before(uchar* inbuf, int inlen, char* outbuf, int outlen);
  36
  37
  38 // A TrustAnchor object can be imported or installed via the API, but cannot
  39 // be modified by the user, other than being cleared. Hence the fields are read-only.
  40 public class TrustAnchor : Object
  41 {
  42     private static const string CERT_HEADER = "-----BEGIN CERTIFICATE-----";
  43     private static const string CERT_FOOTER = "-----END CERTIFICATE-----";
  44
  45     public enum TrustAnchorType {
  46         CA_CERT,
  47         SERVER_CERT
  48     }
  49
  50     private string _ca_cert = "";
  51     private string _subject = "";
  52     private string _subject_alt = "";
  53     private string _server_cert = "";
  54     private string _datetime_added = "";
  55     public bool user_verified = false;
  56
  57     private static string fixup (string s) {
  58         return (s == null ? "" : s.strip());
  59     }
  60
  61     public TrustAnchor(string ca_cert, string server_cert, string subject, string subject_alt, bool user_verified) {
  62         _ca_cert = fixup(ca_cert);
  63         _server_cert = fixup(server_cert);
  64         _subject = fixup(subject);
  65         _subject_alt = fixup(subject_alt);
  66         this.user_verified = user_verified;
  67
  68         // If we're reading from store, this will be overridden (see set_datetime_added)
  69         _datetime_added = "";
  70     }
  71
  72     public TrustAnchor.empty() {
  73     }
  74
  75
  76     public string ca_cert {
  77         get {
  78             return _ca_cert;
  79         }
  80     }
  81
  82     public string subject {
  83         get {
  84             return _subject;
  85         }
  86     }
  87
  88     public string subject_alt  {
  89         get {
  90             return _subject_alt;
  91         }
  92     }
  93
  94
  95     public string server_cert {
  96         get {
  97             return _server_cert;
  98         }
  99     }
 100
 101     public string datetime_added {
 102         get {
 103             return _datetime_added;
 104         }
 105     }
 106
 107     public bool is_empty() {
 108         return ca_cert == "" && subject == "" && subject_alt == "" && server_cert == "";
 109     }
 110
 111     public TrustAnchorType get_anchor_type() {
 112         return server_cert == "" ? TrustAnchorType.CA_CERT : TrustAnchorType.SERVER_CERT;
 113     }
 114
 115     internal void set_datetime_added(string datetime) {
 116         _datetime_added = fixup(datetime);
 117     }
 118
 119     internal static string format_datetime_now() {
 120         DateTime now = new DateTime.now_utc();
 121         string dt = now.format("%b %d %T %Y %Z");
 122         return dt;
 123     }
 124
 125     public int Compare(TrustAnchor other)
 126     {
 127         if (this.ca_cert != other.ca_cert) {
 128             // IdCard.logger.trace("TrustAnchor.Compare: this.ca_cert='%s'; other.ca_cert='%s'".printf(this.ca_cert, other.ca_cert));
 129             return 1;
 130         }
 131         if (this.subject != other.subject) {
 132             // IdCard.logger.trace("TrustAnchor.Compare: this.subject='%s'; other.subject='%s'".printf(this.subject, other.subject));
 133             return 1;
 134         }
 135         if (this.subject_alt != other.subject_alt) {
 136             // IdCard.logger.trace("TrustAnchor.Compare: this.subject_alt='%s'; other.subject_alt='%s'".printf(this.subject_alt, other.subject_alt));
 137             return 1;
 138         }
 139         if (this.server_cert != other.server_cert) {
 140             // IdCard.logger.trace("TrustAnchor.Compare: this.server_cert=%s'; other.server_cert='%s'".printf(this.server_cert, other.server_cert));
 141             return 1;
 142         }
 143
 144         // Do not compare the user_verified and datetime_added fields; they are not essential.
 145
 146         return 0;
 147     }
 148
 149     public string? get_expiration_date(out string? err_out=null)
 150     {
 151         if (this.ca_cert == "") {
 152             if (&err_out != null) {
 153                 err_out = "Trust anchor does not have a ca_certificate";
 154                 return null;
 155             }
 156         }
 157
 158         string cert = this.ca_cert;
 159         cert.chomp();
 160
 161         uchar[] binary = Base64.decode(cert);
 162         IdCard.logger.trace("get_expiration_date: encoded length=%d; decoded length=%d".printf(cert.length, binary.length));
 163
 164         char buf[64];
 165         string err = (string) get_cert_valid_before(binary, binary.length, buf, 64);
 166         if (err != "") {
 167             IdCard.logger.error(@"get_expiration_date: get_cert_valid_before returned '$err'");
 168             if (&err_out != null) {
 169                 err_out = err;
 170             }
 171             return null;
 172         }
 173
 174         string date = (string) buf;
 175         IdCard.logger.trace(@"get_expiration_date: get_cert_valid_before returned '$date'");
 176
 177         return date;
 178     }
 179 }
 180
 181
 182 public struct Rule
 183 {
 184     public string pattern;
 185     public string always_confirm;
 186     public int Compare(Rule other) {
 187         if (this.pattern != other.pattern)
 188             return 1;
 189         if (this.always_confirm != other.always_confirm)
 190             return 1;
 191         return 0;
 192     }
 193 }
 194
 195 public class IdCard : Object
 196 {
 197     internal static MoonshotLogger logger = get_logger("IdCard");
 198
 199     public const string NO_IDENTITY = "No Identity";
 200
 201     private string _nai;
 202
 203     public string display_name { get; set; default = ""; }
 204
 205     public string username { get; set; default = ""; }
 206 #if GNOME_KEYRING
 207     private unowned string _password;
 208     public string password {
 209         get {
 210             return (_password!=null) ? _password : "";
 211         }
 212         set {
 213             if (_password != null) {
 214                 GnomeKeyring.memory_free((void *)_password);
 215                 _password = null;
 216             }
 217             if (value != null)
 218                 _password = GnomeKeyring.memory_strdup(value);
 219         }
 220     }
 221 #else
 222     public string password { get; set; default = null; }
 223 #endif
 224
 225     public string issuer { get; set; default = ""; }
 226
 227     private Rule[] _rules = new Rule[0];
 228     public Rule[] rules {
 229         get {return _rules;}
 230         internal set {_rules = value ?? new Rule[0] ;}
 231     }
 232
 233     private ArrayList<string> _services = new ArrayList<string>();
 234
 235     internal ArrayList<string> services {
 236          get {return  _services;}
 237     }
 238
 239     // Returns the list of services as a string, using the given separator.
 240     internal string get_services_string(string sep) {
 241         if (_services.is_empty) {
 242             return "";
 243         }
 244
 245         // ArrayList.to_array() seems to be unreliable -- it causes segfaults
 246         // semi-randomly. (Possibly because it returns an unowned ref?)
 247         // return string.joinv(sep, _services.to_array());
 248         //
 249         // This problem may be related to the one noted elsewhere as the
 250         // "Centos vala array property bug".
 251
 252         string[] svcs = new string[_services.size];
 253         for (int i = 0; i < _services.size; i++) {
 254             svcs[i] = _services[i];
 255         }
 256
 257         return string.joinv(sep, svcs);
 258     }
 259
 260     internal void update_services(string[] services) {
 261         _services.clear();
 262
 263         // Doesn't exist in older versions of libgee:
 264         // _services.add_all_array(services);
 265
 266         if (services != null) {
 267             foreach (string s in services) {
 268                 _services.add(s);
 269             }
 270         }
 271     }
 272
 273     internal void update_services_from_list(ArrayList<string> services) {
 274         if (services == this._services) {
 275             // Don't try to update from self.
 276             return;
 277         }
 278
 279         _services.clear();
 280
 281         if (services != null) {
 282             _services.add_all(services);
 283         }
 284     }
 285
 286
 287     public bool temporary {get; set; default = false; }
 288
 289     private TrustAnchor _trust_anchor = new TrustAnchor.empty();
 290     public TrustAnchor trust_anchor  {
 291         get {
 292             return _trust_anchor;
 293         }
 294     }
 295
 296     // For use by storage implementations.
 297     internal void set_trust_anchor_from_store(TrustAnchor ta) {
 298         _trust_anchor = ta;
 299     }
 300
 301     internal void clear_trust_anchor() {
 302         _trust_anchor = new TrustAnchor.empty();
 303     }
 304
 305     public unowned string nai { get {  _nai = username + "@" + issuer; return _nai;}}
 306
 307     public bool store_password { get; set; default = false; }
 308
 309     public bool is_no_identity()
 310     {
 311         return (display_name == NO_IDENTITY);
 312     }
 313
 314     public enum DiffFlags {
 315         DISPLAY_NAME,
 316         USERNAME,
 317         PASSWORD,
 318         ISSUER,
 319         RULES,
 320         SERVICES,
 321         TRUST_ANCHOR;
 322     }
 323
 324     public int Compare(IdCard other)
 325     {
 326         int diff = 0;
 327         if (this.display_name != other.display_name)
 328             diff |= 1 << DiffFlags.DISPLAY_NAME;
 329
 330         if (this.username != other.username)
 331             diff |= 1 << DiffFlags.USERNAME;
 332
 333         if (this.password != other.password)
 334             diff |= 1 << DiffFlags.PASSWORD;
 335
 336         if (this.issuer != other.issuer)
 337             diff |= 1 << DiffFlags.ISSUER;
 338
 339         if (CompareRules(this.rules, other.rules)!=0)
 340             diff |= 1 << DiffFlags.RULES;
 341
 342         if (CompareStringArrayList(this._services, other._services)!=0)
 343             diff |= 1 << DiffFlags.SERVICES;
 344
 345         if (this.trust_anchor.Compare(other.trust_anchor)!=0)
 346             diff |= 1 << DiffFlags.TRUST_ANCHOR;
 347
 348         // stdout.printf("Diff Flags: %x\n", diff);
 349         if (this.display_name == other.display_name && diff != 0) {
 350             logger.trace("Compare: Two IDs with display_name '%s', but diff_flags=%0x".printf(this.display_name, diff));
 351         }
 352         return diff;
 353     }
 354
 355     public static IdCard NewNoIdentity()
 356     {
 357         IdCard card = new IdCard();
 358         card.display_name = NO_IDENTITY;
 359         return card;
 360     }
 361
 362     ~IdCard() {
 363         password = null;
 364     }
 365
 366     internal void add_rule(Rule rule) {
 367         _rules += rule;
 368     }
 369 }
 370
 371 public int CompareRules(Rule[] a, Rule[] b)
 372 {
 373     if (a.length != b.length) {
 374         return 1;
 375     }
 376
 377     for (int i = 0; i < a.length; i++) {
 378         if (a[i].Compare(b[i]) != 0) {
 379             return 1;
 380         }
 381     }
 382     return 0;
 383 }
 384
 385 public int CompareStringArrayList(ArrayList<string> a, ArrayList<string> b)
 386 {
 387     if (a.size != b.size) {
 388         return 1;
 389     }
 390
 391     for (int i = 0; i < a.size; i++) {
 392         if (a[i] != b[i]) {
 393             return 1;
 394         }
 395     }
 396     return 0;
 397 }