src/moonshot-idcard-widget.vala

   1 /*
   2  * Copyright (c) 2011-2014, JANET(UK)
   3  * All rights reserved.
   4  *
   5  * Redistribution and use in source and binary forms, with or without
   6  * modification, are permitted provided that the following conditions
   7  * are met:
   8  *
   9  * 1. Redistributions of source code must retain the above copyright
  10  *    notice, this list of conditions and the following disclaimer.
  11  *
  12  * 2. Redistributions in binary form must reproduce the above copyright
  13  *    notice, this list of conditions and the following disclaimer in the
  14  *    documentation and/or other materials provided with the distribution.
  15  *
  16  * 3. Neither the name of JANET(UK) nor the names of its contributors
  17  *    may be used to endorse or promote products derived from this software
  18  *    without specific prior written permission.
  19  *
  20  * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS"
  21  * AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  22  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  23  * ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDER OR CONTRIBUTORS BE LIABLE
  24  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  25  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  26  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  27  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  28  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  29  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  30  * SUCH DAMAGE.
  31 */
  32 using Gtk;
  33
  34 class IdCardWidget : Box
  35 {
  36     static MoonshotLogger logger = get_logger("IdCardWidget");
  37
  38     public IdCard id_card { get; set; default = null; }
  39     private VBox main_vbox;
  40     private HBox table;
  41     private EventBox event_box;
  42     private bool   is_selected = false;
  43
  44     private Label label;
  45
  46     internal int _position = 0;
  47     internal int position {
  48         get {return _position;}
  49         set {_position = value; set_idcard_color();}
  50     }
  51
  52     public signal void expanded();
  53     public signal void collapsed();
  54
  55     private void select()
  56     {
  57         expand();
  58         this.expanded();
  59     }
  60
  61     private void unselect()
  62     {
  63         collapse();
  64         this.collapsed();
  65     }
  66
  67     public void expand()
  68     {
  69         logger.trace("expand");
  70
  71         is_selected = true;
  72         update_id_card_label();
  73
  74         set_idcard_color();
  75         this.expanded();
  76     }
  77
  78     public void collapse()
  79     {
  80         logger.trace("collapse");
  81
  82         is_selected = false;
  83         update_id_card_label();
  84
  85         set_idcard_color();
  86     }
  87
  88     private bool button_press_cb()
  89     {
  90         if (is_selected)
  91             unselect();
  92         else
  93             select();
  94
  95         return false;
  96     }
  97
  98     private void set_idcard_color()
  99     {
 100         var color = Gdk.Color();
 101
 102         if (is_selected)
 103         {
 104                 color.red = 0xd9 << 8;
 105                 color.green = 0xf7 << 8;
 106                 color.blue = 65535;
 107         }
 108         else {
 109             if (position % 2 == 0)
 110             {
 111                 color.red = color.green = color.blue = 0xf2 << 8;
 112             }
 113             else
 114             {
 115                 color.red = 65535;
 116                 color.green = 65535;
 117                 color.blue = 65535;
 118
 119             }
 120         }
 121         var state = this.get_state();
 122         this.event_box.modify_bg(state, color);
 123     }
 124
 125     private void
 126     update_id_card_label()
 127     {
 128         // !!TODO: Use a table to format the labels and values
 129         string services_text = "Services:  ";
 130         string service_spacer = "                ";
 131
 132         var label_text = Markup.printf_escaped("<big>%s</big>", this.id_card.display_name);
 133
 134         if (is_selected)
 135         {
 136             label_text += "\nUsername:  " + id_card.username;
 137             label_text += "\nRealm:  " + id_card.issuer;
 138
 139             var sep = "";
 140             for (int i = 0; i < id_card.services.length; i++)
 141             {
 142                 services_text += sep;
 143                 services_text += id_card.services[i];
 144
 145                 sep = "\n" + service_spacer;
 146             }
 147             label_text += "\n" + services_text;
 148         }
 149
 150         label.set_markup(label_text);
 151     }
 152
 153     public IdCardWidget(IdCard id_card)
 154     {
 155         this.id_card = id_card;
 156
 157         var image = new Image.from_pixbuf(get_pixbuf(id_card));
 158
 159         label = new Label(null);
 160         label.set_alignment((float) 0, (float) 0.5);
 161         label.set_ellipsize(Pango.EllipsizeMode.END);
 162         update_id_card_label();
 163
 164         table = new Gtk.HBox(false, 6);
 165         table.pack_start(image, false, false, 0);
 166         table.pack_start(label, true, true, 0);
 167
 168         this.main_vbox = new VBox(false, 12);
 169         main_vbox.pack_start(table, true, true, 0);
 170         main_vbox.set_border_width(12);
 171
 172         event_box = new EventBox();
 173         event_box.add(main_vbox);
 174         event_box.button_press_event.connect(button_press_cb);
 175         event_box.set_visible(false);
 176         this.pack_start(event_box, true, true);
 177
 178         this.show_all();
 179
 180         set_idcard_color();
 181     }
 182 }