src/moonshot-identities-manager.vala

   1 /*
   2  * Copyright (c) 2011-2016, JANET(UK)
   3  * All rights reserved.
   4  *
   5  * Redistribution and use in source and binary forms, with or without
   6  * modification, are permitted provided that the following conditions
   7  * are met:
   8  *
   9  * 1. Redistributions of source code must retain the above copyright
  10  *    notice, this list of conditions and the following disclaimer.
  11  *
  12  * 2. Redistributions in binary form must reproduce the above copyright
  13  *    notice, this list of conditions and the following disclaimer in the
  14  *    documentation and/or other materials provided with the distribution.
  15  *
  16  * 3. Neither the name of JANET(UK) nor the names of its contributors
  17  *    may be used to endorse or promote products derived from this software
  18  *    without specific prior written permission.
  19  *
  20  * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS"
  21  * AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  22  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  23  * ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDER OR CONTRIBUTORS BE LIABLE
  24  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  25  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  26  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  27  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  28  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  29  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  30  * SUCH DAMAGE.
  31 */
  32 using Gee;
  33
  34 public class Password {
  35 #if GNOME_KEYRING
  36     private unowned string _password;
  37     public string password {
  38         get {
  39             return _password;
  40         }
  41         set {
  42             if (_password != null) {
  43                 GnomeKeyring.memory_free((void *)_password);
  44                 _password = null;
  45             }
  46             if (value != null)
  47                 _password = GnomeKeyring.memory_strdup(value);
  48         }
  49     }
  50 #else
  51     public string password { get; set; default = null; }
  52 #endif
  53
  54     public Password(string in_password) {
  55         password = in_password;
  56     }
  57
  58     ~Password() {
  59         password = null;
  60     }
  61 }
  62
  63 public class PasswordHashTable : Object {
  64     private HashTable<string, Password> password_table;
  65
  66     private static string ComputeHashKey(IdCard card, IIdentityCardStore store) {
  67         return "%s_store_%d".printf( card.display_name, store.get_store_type() );
  68     }
  69
  70     public void CachePassword(IdCard card, IIdentityCardStore store) {
  71         password_table.replace(ComputeHashKey(card, store), new Password(card.password));
  72     }
  73
  74     public void RemovePassword(IdCard card, IIdentityCardStore store) {
  75         password_table.remove(ComputeHashKey(card, store));
  76     }
  77     public void RetrievePassword(IdCard card, IIdentityCardStore store) {
  78         weak Password password = password_table.lookup(ComputeHashKey(card, store));
  79         if (password != null) {
  80             card.password = password.password;
  81         }
  82     }
  83     public PasswordHashTable() {
  84         password_table = new HashTable<string, Password>(GLib.str_hash, GLib.str_equal);
  85     }
  86 }
  87
  88 public class IdentityManagerModel : Object {
  89     static MoonshotLogger logger = get_logger("IdentityManagerModel");
  90
  91     private const string FILE_NAME = "identities.txt";
  92     private PasswordHashTable password_table;
  93     private IIdentityCardStore store;
  94     public LinkedList<IdCard>  get_card_list() {
  95         var identities = store.get_card_list();
  96         identities.sort((a, b) => {
  97                 IdCard id_a = (IdCard )a;
  98                 IdCard id_b = (IdCard )b;
  99                 if (id_a.is_no_identity() && !id_b.is_no_identity()) {
 100                     return -1;
 101                 } else if (id_b.is_no_identity() && !id_a.is_no_identity()) {
 102                     return 1;
 103                 }
 104                 return strcmp(id_a.display_name, id_b.display_name);
 105             });
 106         if (identities.is_empty || !identities[0].is_no_identity())
 107             identities.insert(0, IdCard.NewNoIdentity());
 108         foreach (IdCard id_card in identities) {
 109             if (!id_card.store_password) {
 110                 password_table.RetrievePassword(id_card, store);
 111             }
 112         }
 113         return identities;
 114     }
 115     public signal void card_list_changed();
 116
 117     /* This method finds a valid display name */
 118     public bool display_name_is_valid(string name,
 119                                       out string? candidate)
 120     {
 121         if (&candidate != null)
 122             candidate = null;
 123         foreach (IdCard id_card in this.store.get_card_list())
 124         {
 125             if (id_card.display_name == name)
 126             {
 127                 if (&candidate != null)
 128                 {
 129                     for (int i = 0; i < 1000; i++)
 130                     {
 131                         string tmp = "%s %d".printf(name, i);
 132                         if (display_name_is_valid(tmp, null))
 133                         {
 134                             candidate = tmp;
 135                             break;
 136                         }
 137                     }
 138                 }
 139                 return false;
 140             }
 141         }
 142         return true;
 143     }
 144
 145     private bool remove_duplicates(IdCard new_card, out ArrayList<IdCard>? old_duplicates)
 146     {
 147         ArrayList<IdCard> dups = new ArrayList<IdCard>();
 148         var cards = this.store.get_card_list();
 149         foreach (IdCard id_card in cards) {
 150             if ((new_card != id_card) && (id_card.nai == new_card.nai)) {
 151                 dups.add(id_card);
 152             }
 153         }
 154
 155         foreach (IdCard id_card in dups) {
 156             logger.trace("removing duplicate id for '%s'\n".printf(new_card.nai));
 157             remove_card_internal(id_card);
 158
 159             if (new_card.trust_anchor.Compare(id_card.trust_anchor) == 0) {
 160                 logger.trace("Old and new cards have same trust anchor. Re-using the datetime_added and user_verified fields from the old card.");
 161                 new_card.trust_anchor.set_datetime_added(id_card.trust_anchor.datetime_added);
 162                 new_card.trust_anchor.user_verified = id_card.trust_anchor.user_verified;
 163             }
 164         }
 165
 166         if (&old_duplicates != null) {
 167             old_duplicates = dups;
 168         }
 169
 170         return (dups.size > 0);
 171     }
 172
 173     public IdCard? find_id_card(string nai, bool force_flat_file_store) {
 174         IdCard? retval = null;
 175         IIdentityCardStore.StoreType saved_store_type = get_store_type();
 176         if (force_flat_file_store)
 177             set_store_type(IIdentityCardStore.StoreType.FLAT_FILE);
 178
 179         foreach (IdCard id in get_card_list()) {
 180             if (id.nai == nai) {
 181                 retval = id;
 182                 break;
 183             }
 184         }
 185         set_store_type(saved_store_type);
 186         if (force_flat_file_store &&
 187             (saved_store_type != IIdentityCardStore.StoreType.FLAT_FILE))
 188             card_list_changed();
 189         return retval;
 190     }
 191
 192     public void add_card(IdCard card, bool force_flat_file_store, out ArrayList<IdCard>? old_duplicates=null) {
 193         if (card.temporary) {
 194             logger.trace("add_card: card is temporary; returning.");
 195             return;
 196         }
 197
 198         string candidate;
 199         IIdentityCardStore.StoreType saved_store_type = get_store_type();
 200
 201         if (force_flat_file_store)
 202             set_store_type(IIdentityCardStore.StoreType.FLAT_FILE);
 203
 204         remove_duplicates(card, out old_duplicates);
 205
 206         if (!display_name_is_valid(card.display_name, out candidate))
 207         {
 208             card.display_name = candidate;
 209         }
 210
 211         if (!card.store_password)
 212             password_table.CachePassword(card, store);
 213
 214         logger.trace("add_card: Adding card '%s' with services: '%s'"
 215                      .printf(card.display_name, card.get_services_string("; ")));
 216
 217         store.add_card(card);
 218         set_store_type(saved_store_type);
 219         card_list_changed();
 220     }
 221
 222     public IdCard update_card(IdCard card) {
 223         logger.trace("update_card");
 224
 225         IdCard retval;
 226         if (card.temporary) {
 227             retval = card;
 228             return retval;
 229         }
 230
 231         if (!card.store_password)
 232             password_table.CachePassword(card, store);
 233         else
 234             password_table.RemovePassword(card, store);
 235         retval = store.update_card(card);
 236         card_list_changed();
 237         return retval;
 238     }
 239
 240     private bool remove_card_internal(IdCard card) {
 241         if (card.temporary)
 242             return false;
 243         password_table.RemovePassword(card, store);
 244         return store.remove_card(card);
 245     }
 246
 247     public bool remove_card(IdCard card) {
 248         if (remove_card_internal(card)) {
 249             logger.trace(@"remove_card: Removed '$(card.display_name)'");
 250             card_list_changed();
 251             return true;
 252         }
 253         logger.warn(@"remove_card: Couldn't remove '$(card.display_name)'");
 254         return false;
 255     }
 256
 257     // The name is misleading: This not only sets the store type,
 258     // it also creates a new store instance, which loads the card data.
 259     public void set_store_type(IIdentityCardStore.StoreType type) {
 260         if ((store != null) && (store.get_store_type() == type))
 261             return;
 262         switch (type) {
 263             #if GNOME_KEYRING
 264         case IIdentityCardStore.StoreType.KEYRING:
 265             store = new KeyringStore();
 266             break;
 267             #endif
 268         case IIdentityCardStore.StoreType.FLAT_FILE:
 269         default:
 270             store = new LocalFlatFileStore();
 271             break;
 272         }
 273
 274         // Loop through the loaded IDs. If any trust anchors are old enough that we didn't record
 275         // the datetime_added, add it now.
 276         string before_now = _("Before ") + TrustAnchor.format_datetime_now();
 277         bool save_needed = false;
 278         foreach (IdCard id in this.store.get_card_list()) {
 279             if (!id.trust_anchor.is_empty() && id.trust_anchor.datetime_added == "") {
 280                 logger.trace("set_store_type : Set ta_datetime_added for old trust anchor on '%s' to '%s'".printf(id.display_name, before_now));
 281                 id.trust_anchor.set_datetime_added(before_now);
 282                 save_needed = true;
 283             }
 284         }
 285         if (save_needed) {
 286             this.store.store_id_cards();
 287         }
 288     }
 289
 290     public IIdentityCardStore.StoreType get_store_type() {
 291         return store.get_store_type();
 292     }
 293
 294     public bool HasNonTrivialIdentities() {
 295         foreach (IdCard card in this.store.get_card_list()) {
 296             // The 'NoIdentity' card is non-trivial if it has services or rules.
 297             // All other cards are automatically non-trivial.
 298             if ((!card.is_no_identity()) ||
 299                 (card.services.size > 0) ||
 300                 (card.rules.length > 0)) {
 301                 return true;
 302             }
 303         }
 304         return false;
 305     }
 306
 307
 308     private IdentityManagerApp parent;
 309
 310     public IdentityManagerModel(IdentityManagerApp parent_app, IIdentityCardStore.StoreType store_type) {
 311         logger.trace("IdentityManagerModel: store_type=" + store_type.to_string());
 312         parent = parent_app;
 313         password_table = new PasswordHashTable();
 314         set_store_type(store_type);
 315     }
 316 }