src/moonshot-identities-manager.vala

   1 /*
   2  * Copyright (c) 2011-2014, JANET(UK)
   3  * All rights reserved.
   4  *
   5  * Redistribution and use in source and binary forms, with or without
   6  * modification, are permitted provided that the following conditions
   7  * are met:
   8  *
   9  * 1. Redistributions of source code must retain the above copyright
  10  *    notice, this list of conditions and the following disclaimer.
  11  *
  12  * 2. Redistributions in binary form must reproduce the above copyright
  13  *    notice, this list of conditions and the following disclaimer in the
  14  *    documentation and/or other materials provided with the distribution.
  15  *
  16  * 3. Neither the name of JANET(UK) nor the names of its contributors
  17  *    may be used to endorse or promote products derived from this software
  18  *    without specific prior written permission.
  19  *
  20  * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS"
  21  * AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  22  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  23  * ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDER OR CONTRIBUTORS BE LIABLE
  24  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  25  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  26  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  27  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  28  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  29  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  30  * SUCH DAMAGE.
  31 */
  32 using Gee;
  33
  34 public class Password {
  35 #if GNOME_KEYRING
  36     private unowned string _password;
  37     public string password {
  38         get {
  39             return _password;
  40         }
  41         set {
  42             if (_password != null) {
  43                 GnomeKeyring.memory_free((void *)_password);
  44                 _password = null;
  45             }
  46             if (value != null)
  47                 _password = GnomeKeyring.memory_strdup(value);
  48         }
  49     }
  50 #else
  51     public string password { get; set; default = null; }
  52 #endif
  53
  54     public Password(string in_password) {
  55         password = in_password;
  56     }
  57
  58     ~Password() {
  59         password = null;
  60     }
  61 }
  62
  63 public class PasswordHashTable : Object {
  64     private HashTable<string, Password> password_table;
  65
  66     private static string ComputeHashKey(IdCard card, IIdentityCardStore store) {
  67         return "%s_store_%d".printf( card.display_name, store.get_store_type() );
  68     }
  69
  70     public void CachePassword(IdCard card, IIdentityCardStore store) {
  71         password_table.replace(ComputeHashKey(card, store), new Password(card.password));
  72     }
  73
  74     public void RemovePassword(IdCard card, IIdentityCardStore store) {
  75         password_table.remove(ComputeHashKey(card, store));
  76     }
  77     public void RetrievePassword(IdCard card, IIdentityCardStore store) {
  78         weak Password password = password_table.lookup(ComputeHashKey(card, store));
  79         if (password != null) {
  80             card.password = password.password;
  81         }
  82     }
  83     public PasswordHashTable() {
  84         password_table = new HashTable<string, Password>(GLib.str_hash, GLib.str_equal);
  85     }
  86 }
  87
  88 public class IdentityManagerModel : Object {
  89     static MoonshotLogger logger = get_logger("IdentityManagerModel");
  90
  91     private const string FILE_NAME = "identities.txt";
  92     private PasswordHashTable password_table;
  93     private IIdentityCardStore store;
  94     public LinkedList<IdCard>  get_card_list() {
  95         var identities = store.get_card_list();
  96         identities.sort((a, b) => {
  97                 IdCard id_a = (IdCard )a;
  98                 IdCard id_b = (IdCard )b;
  99                 if (id_a.is_no_identity() && !id_b.is_no_identity()) {
 100                     return -1;
 101                 } else if (id_b.is_no_identity() && !id_a.is_no_identity()) {
 102                     return 1;
 103                 }
 104                 return strcmp(id_a.display_name, id_b.display_name);
 105             });
 106         if (identities.is_empty || !identities[0].is_no_identity())
 107             identities.insert(0, IdCard.NewNoIdentity());
 108         foreach (IdCard id_card in identities) {
 109             if (!id_card.store_password) {
 110                 password_table.RetrievePassword(id_card, store);
 111             }
 112         }
 113         return identities;
 114     }
 115     public signal void card_list_changed();
 116
 117     /* This method finds a valid display name */
 118     public bool display_name_is_valid(string name,
 119                                       out string? candidate)
 120     {
 121         if (&candidate != null)
 122             candidate = null;
 123         foreach (IdCard id_card in this.store.get_card_list())
 124         {
 125             if (id_card.display_name == name)
 126             {
 127                 if (&candidate != null)
 128                 {
 129                     for (int i = 0; i < 1000; i++)
 130                     {
 131                         string tmp = "%s %d".printf(name, i);
 132                         if (display_name_is_valid(tmp, null))
 133                         {
 134                             candidate = tmp;
 135                             break;
 136                         }
 137                     }
 138                 }
 139                 return false;
 140             }
 141         }
 142         return true;
 143     }
 144
 145     private bool remove_duplicates(IdCard card)
 146     {
 147         bool duplicate_found = false;
 148         bool found = false;
 149         do {
 150             var cards = this.store.get_card_list();
 151             found = false;
 152             foreach (IdCard id_card in cards) {
 153                 if ((card != id_card) && (id_card.nai == card.nai)) {
 154                     stdout.printf("removing duplicate id for '%s'\n", card.nai);
 155                     logger.trace("removing duplicate id for '%s'\n".printf(card.nai));
 156                     remove_card_internal(id_card);
 157                     found = duplicate_found = true;
 158                     break;
 159                 }
 160             }
 161         } while (found);
 162         return duplicate_found;
 163     }
 164
 165     public IdCard? find_id_card(string nai, bool force_flat_file_store) {
 166         IdCard? retval = null;
 167         IIdentityCardStore.StoreType saved_store_type = get_store_type();
 168         if (force_flat_file_store)
 169             set_store_type(IIdentityCardStore.StoreType.FLAT_FILE);
 170
 171         foreach (IdCard id in get_card_list()) {
 172             if (id.nai == nai) {
 173                 retval = id;
 174                 break;
 175             }
 176         }
 177         set_store_type(saved_store_type);
 178         if (force_flat_file_store &&
 179             (saved_store_type != IIdentityCardStore.StoreType.FLAT_FILE))
 180             card_list_changed();
 181         return retval;
 182     }
 183
 184     public void add_card(IdCard card, bool force_flat_file_store) {
 185         if (card.temporary)
 186             return;
 187
 188         string candidate;
 189         IIdentityCardStore.StoreType saved_store_type = get_store_type();
 190
 191         if (force_flat_file_store)
 192             set_store_type(IIdentityCardStore.StoreType.FLAT_FILE);
 193
 194         remove_duplicates(card);
 195
 196         if (!display_name_is_valid(card.display_name, out candidate))
 197         {
 198             card.display_name = candidate;
 199         }
 200
 201         if (!card.store_password)
 202             password_table.CachePassword(card, store);
 203         store.add_card(card);
 204         set_store_type(saved_store_type);
 205         card_list_changed();
 206     }
 207
 208     public IdCard update_card(IdCard card) {
 209         IdCard retval;
 210         if (card.temporary) {
 211             retval = card;
 212             return retval;
 213         }
 214
 215         if (!card.store_password)
 216             password_table.CachePassword(card, store);
 217         else
 218             password_table.RemovePassword(card, store);
 219         retval = store.update_card(card);
 220         card_list_changed();
 221         return retval;
 222     }
 223
 224     private bool remove_card_internal(IdCard card) {
 225         if (card.temporary)
 226             return false;
 227         password_table.RemovePassword(card, store);
 228         return store.remove_card(card);
 229     }
 230
 231     public bool remove_card(IdCard card) {
 232         if (remove_card_internal(card)) {
 233             card_list_changed();
 234             return true;
 235         }
 236         return false;
 237     }
 238
 239     public void set_store_type(IIdentityCardStore.StoreType type) {
 240         if ((store != null) && (store.get_store_type() == type))
 241             return;
 242         switch (type) {
 243             #if GNOME_KEYRING
 244         case IIdentityCardStore.StoreType.KEYRING:
 245             store = new KeyringStore();
 246             break;
 247             #endif
 248         case IIdentityCardStore.StoreType.FLAT_FILE:
 249         default:
 250             store = new LocalFlatFileStore();
 251             break;
 252         }
 253     }
 254
 255     public IIdentityCardStore.StoreType get_store_type() {
 256         return store.get_store_type();
 257     }
 258
 259     public bool HasNonTrivialIdentities() {
 260         foreach (IdCard card in this.store.get_card_list()) {
 261             // The 'NoIdentity' card is non-trivial if it has services or rules.
 262             // All other cards are automatically non-trivial.
 263             if ((!card.is_no_identity()) ||
 264                 (card.services.length > 0) ||
 265                 (card.rules.length > 0)) {
 266                 return true;
 267             }
 268         }
 269         return false;
 270     }
 271
 272
 273     private IdentityManagerApp parent;
 274
 275     public IdentityManagerModel(IdentityManagerApp parent_app, IIdentityCardStore.StoreType store_type) {
 276         logger.trace("IdentityManagerModel: store_type=" + store_type.to_string());
 277         parent = parent_app;
 278         password_table = new PasswordHashTable();
 279         set_store_type(store_type);
 280     }
 281 }