src/moonshot-identities-manager.vala

   1 /*
   2  * Copyright (c) 2011-2016, JANET(UK)
   3  * All rights reserved.
   4  *
   5  * Redistribution and use in source and binary forms, with or without
   6  * modification, are permitted provided that the following conditions
   7  * are met:
   8  *
   9  * 1. Redistributions of source code must retain the above copyright
  10  *    notice, this list of conditions and the following disclaimer.
  11  *
  12  * 2. Redistributions in binary form must reproduce the above copyright
  13  *    notice, this list of conditions and the following disclaimer in the
  14  *    documentation and/or other materials provided with the distribution.
  15  *
  16  * 3. Neither the name of JANET(UK) nor the names of its contributors
  17  *    may be used to endorse or promote products derived from this software
  18  *    without specific prior written permission.
  19  *
  20  * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS"
  21  * AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  22  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  23  * ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDER OR CONTRIBUTORS BE LIABLE
  24  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  25  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  26  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  27  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  28  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  29  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  30  * SUCH DAMAGE.
  31 */
  32 using Gee;
  33
  34 public class Password {
  35 #if GNOME_KEYRING
  36     private unowned string _password;
  37     public string password {
  38         get {
  39             return _password;
  40         }
  41         set {
  42             if (_password != null) {
  43                 GnomeKeyring.memory_free((void *)_password);
  44                 _password = null;
  45             }
  46             if (value != null)
  47                 _password = GnomeKeyring.memory_strdup(value);
  48         }
  49     }
  50 #else
  51     public string password { get; set; default = null; }
  52 #endif
  53
  54     public Password(string in_password) {
  55         password = in_password;
  56     }
  57
  58     ~Password() {
  59         password = null;
  60     }
  61 }
  62
  63 public class PasswordHashTable : Object {
  64     private HashTable<string, Password> password_table;
  65
  66     private static string ComputeHashKey(IdCard card, IIdentityCardStore store) {
  67         return "%s_store_%d".printf( card.nai, store.get_store_type() );
  68     }
  69
  70     public void CachePassword(IdCard card, IIdentityCardStore store) {
  71         password_table.replace(ComputeHashKey(card, store), new Password(card.password));
  72     }
  73
  74     public void RemovePassword(IdCard card, IIdentityCardStore store) {
  75         password_table.remove(ComputeHashKey(card, store));
  76     }
  77     public void RetrievePassword(IdCard card, IIdentityCardStore store) {
  78         weak Password password = password_table.lookup(ComputeHashKey(card, store));
  79         if (password != null) {
  80             card.password = password.password;
  81         }
  82     }
  83     public PasswordHashTable() {
  84         password_table = new HashTable<string, Password>(GLib.str_hash, GLib.str_equal);
  85     }
  86 }
  87
  88 public class IdentityManagerModel : Object {
  89     static MoonshotLogger logger = get_logger("IdentityManagerModel");
  90
  91     private const string FILE_NAME = "identities.txt";
  92     private PasswordHashTable password_table;
  93     private IIdentityCardStore store;
  94     public LinkedList<IdCard>  get_card_list() {
  95         var identities = store.get_card_list();
  96         identities.sort((a, b) => {
  97                 IdCard id_a = (IdCard )a;
  98                 IdCard id_b = (IdCard )b;
  99                 if (id_a.is_no_identity() && !id_b.is_no_identity()) {
 100                     return -1;
 101                 } else if (id_b.is_no_identity() && !id_a.is_no_identity()) {
 102                     return 1;
 103                 }
 104                 return strcmp(id_a.display_name, id_b.display_name);
 105             });
 106         if (identities.is_empty || !identities[0].is_no_identity())
 107             identities.insert(0, IdCard.NewNoIdentity());
 108         foreach (IdCard id_card in identities) {
 109             if (!id_card.store_password) {
 110                 password_table.RetrievePassword(id_card, store);
 111             }
 112         }
 113         return identities;
 114     }
 115     public signal void card_list_changed();
 116
 117     /* This method finds a valid display name */
 118     public bool display_name_is_valid(string name,
 119                                       out string? candidate)
 120     {
 121         if (&candidate != null)
 122             candidate = null;
 123         foreach (IdCard id_card in this.store.get_card_list())
 124         {
 125             if (id_card.display_name == name)
 126             {
 127                 if (&candidate != null)
 128                 {
 129                     for (int i = 0; i < 1000; i++)
 130                     {
 131                         string tmp = "%s %d".printf(name, i);
 132                         if (display_name_is_valid(tmp, null))
 133                         {
 134                             candidate = tmp;
 135                             break;
 136                         }
 137                     }
 138                 }
 139                 return false;
 140             }
 141         }
 142         return true;
 143     }
 144
 145     private bool remove_duplicates(IdCard new_card, ArrayList<IdCard> old_duplicates)
 146     {
 147         old_duplicates.clear();
 148         var cards = this.store.get_card_list();
 149         foreach (IdCard id_card in cards) {
 150             if ((new_card != id_card) && (id_card.nai == new_card.nai)) {
 151                 old_duplicates.add(id_card);
 152             }
 153         }
 154
 155         foreach (IdCard id_card in old_duplicates) {
 156             logger.trace("removing duplicate id for '%s'\n".printf(new_card.nai));
 157             remove_card_internal(id_card);
 158
 159             if (new_card.trust_anchor.Compare(id_card.trust_anchor) == 0) {
 160                 logger.trace("Old and new cards have same trust anchor. Re-using the datetime_added field from the old card.");
 161                 new_card.trust_anchor.set_datetime_added(id_card.trust_anchor.datetime_added);
 162             }
 163         }
 164
 165         return (old_duplicates.size > 0);
 166     }
 167
 168
 169     public bool find_duplicate_nai_sets(out ArrayList<ArrayList<IdCard>> duplicates)
 170     {
 171         var nais = new HashMap<string, ArrayList<IdCard>>();
 172
 173         duplicates = new ArrayList<ArrayList<IdCard>>();
 174         LinkedList<IdCard> card_list = get_card_list() ;
 175         if (card_list == null) {
 176             return false;
 177         }
 178
 179         bool found = false;
 180         foreach (IdCard id_card in card_list) {
 181             logger.trace(@"load_id_cards: Loading card with display name '$(id_card.display_name)' and nai '$(id_card.nai)'");
 182
 183             //!!TODO: This uniqueness check really belongs somewhere else -- like where we add
 184             // IDs, and/or read them from storage. However, we should never hit this.
 185
 186             if (nais.has_key(id_card.nai)) {
 187                 ArrayList<IdCard> list = nais.get(id_card.nai);
 188                 list.add(id_card);
 189             }
 190             else {
 191                 ArrayList<IdCard> list = new ArrayList<IdCard>();
 192                 list.add(id_card);
 193                 nais.set(id_card.nai, list);
 194             }
 195         }
 196
 197         duplicates = new ArrayList<ArrayList<IdCard>>();
 198         foreach (Map.Entry<string, ArrayList<IdCard>> entry in nais.entries) {
 199             var list = entry.value;
 200             if (list.size > 1) {
 201                 duplicates.add(list);
 202                 found = true;
 203             }
 204         }
 205         return found;
 206     }
 207
 208
 209     public IdCard? find_id_card(string? nai, bool force_flat_file_store) {
 210         IdCard? retval = null;
 211         IIdentityCardStore.StoreType saved_store_type = get_store_type();
 212         if (force_flat_file_store)
 213             set_store_type(IIdentityCardStore.StoreType.FLAT_FILE);
 214
 215         foreach (IdCard id in get_card_list()) {
 216             if (id.nai == nai) {
 217                 retval = id;
 218                 break;
 219             }
 220         }
 221         set_store_type(saved_store_type);
 222         if (force_flat_file_store &&
 223             (saved_store_type != IIdentityCardStore.StoreType.FLAT_FILE))
 224             card_list_changed();
 225         return retval;
 226     }
 227
 228     public void add_card(IdCard card, bool force_flat_file_store, ArrayList<IdCard> old_duplicates) {
 229         if (card.temporary) {
 230             logger.trace("add_card: card is temporary; returning.");
 231             return;
 232         }
 233
 234         string candidate;
 235         IIdentityCardStore.StoreType saved_store_type = get_store_type();
 236
 237         if (force_flat_file_store)
 238             set_store_type(IIdentityCardStore.StoreType.FLAT_FILE);
 239
 240         remove_duplicates(card, old_duplicates);
 241
 242         if (!display_name_is_valid(card.display_name, out candidate))
 243         {
 244             card.display_name = candidate;
 245         }
 246
 247         if (!card.store_password)
 248             password_table.CachePassword(card, store);
 249
 250         logger.trace("add_card: Adding card '%s' with services: '%s'"
 251                      .printf(card.display_name, card.get_services_string("; ")));
 252
 253         store.add_card(card);
 254         set_store_type(saved_store_type);
 255         card_list_changed();
 256     }
 257
 258     public IdCard update_card(IdCard card) {
 259         logger.trace("update_card");
 260
 261         IdCard retval;
 262         if (card.temporary) {
 263             retval = card;
 264             return retval;
 265         }
 266
 267         if (!card.store_password)
 268             password_table.CachePassword(card, store);
 269         else
 270             password_table.RemovePassword(card, store);
 271         retval = store.update_card(card);
 272         card_list_changed();
 273         return retval;
 274     }
 275
 276     private bool remove_card_internal(IdCard card) {
 277         if (card.temporary)
 278             return false;
 279         password_table.RemovePassword(card, store);
 280         return store.remove_card(card);
 281     }
 282
 283     public bool remove_card(IdCard card) {
 284         if (remove_card_internal(card)) {
 285             logger.trace(@"remove_card: Removed '$(card.display_name)'");
 286             card_list_changed();
 287             return true;
 288         }
 289         logger.warn(@"remove_card: Couldn't remove '$(card.display_name)'");
 290         return false;
 291     }
 292
 293     // The name is misleading: This not only sets the store type,
 294     // it also creates a new store instance, which loads the card data.
 295     public void set_store_type(IIdentityCardStore.StoreType type) {
 296         if ((store != null) && (store.get_store_type() == type))
 297             return;
 298         switch (type) {
 299             #if GNOME_KEYRING
 300         case IIdentityCardStore.StoreType.KEYRING:
 301             store = new KeyringStore();
 302             break;
 303             #endif
 304         case IIdentityCardStore.StoreType.FLAT_FILE:
 305         default:
 306             store = new LocalFlatFileStore();
 307             break;
 308         }
 309
 310         // Loop through the loaded IDs. If any trust anchors are old enough that we didn't record
 311         // the datetime_added, add it now.
 312         string before_now = _("Before ") + TrustAnchor.format_datetime_now();
 313         bool save_needed = false;
 314         foreach (IdCard id in this.store.get_card_list()) {
 315             if (!id.trust_anchor.is_empty() && id.trust_anchor.datetime_added == "") {
 316                 logger.trace("set_store_type : Set ta_datetime_added for old trust anchor on '%s' to '%s'".printf(id.display_name, before_now));
 317                 id.trust_anchor.set_datetime_added(before_now);
 318                 save_needed = true;
 319             }
 320         }
 321         if (save_needed) {
 322             this.store.store_id_cards();
 323         }
 324     }
 325
 326     public IIdentityCardStore.StoreType get_store_type() {
 327         return store.get_store_type();
 328     }
 329
 330     public bool HasNonTrivialIdentities() {
 331         foreach (IdCard card in this.store.get_card_list()) {
 332             // The 'NoIdentity' card is non-trivial if it has services or rules.
 333             // All other cards are automatically non-trivial.
 334             if ((!card.is_no_identity()) ||
 335                 (card.services.size > 0) ||
 336                 (card.rules.length > 0)) {
 337                 return true;
 338             }
 339         }
 340         return false;
 341     }
 342
 343
 344     private IdentityManagerApp parent;
 345
 346     public IdentityManagerModel(IdentityManagerApp parent_app, IIdentityCardStore.StoreType store_type) {
 347         logger.trace("IdentityManagerModel: store_type=" + store_type.to_string());
 348         parent = parent_app;
 349         password_table = new PasswordHashTable();
 350         set_store_type(store_type);
 351     }
 352 }