src/moonshot-identities-manager.vala

   1 class IdentitiesManager : Object {
   2
   3     public SList<IdCard> id_card_list;
   4
   5     private const string FILE_NAME = "identities.txt";
   6
   7     public IdentitiesManager ()
   8     {
   9         var key_file = new KeyFile ();
  10
  11         var path = get_data_dir ();
  12         var filename = Path.build_filename (path, FILE_NAME);
  13
  14         try
  15         {
  16             key_file.load_from_file (filename, KeyFileFlags.NONE);
  17         }
  18         catch (Error e)
  19         {
  20             stdout.printf("Error: %s\n", e.message);
  21         }
  22
  23         var identities_uris = key_file.get_groups ();
  24         foreach (string identity in identities_uris)
  25         {
  26             try
  27             {
  28                 IdCard id_card = new IdCard ();
  29
  30                 id_card.issuer = key_file.get_string (identity, "Issuer");
  31                 id_card.username = key_file.get_string (identity, "Username");
  32                 id_card.password = key_file.get_string (identity, "Password");
  33                 id_card.services = key_file.get_string_list (identity, "Services");
  34                 id_card.display_name = key_file.get_string (identity, "DisplayName");
  35                 id_card.pixbuf = find_icon ("avatar-default", 48);
  36
  37                 id_card_list.prepend (id_card);
  38             }
  39             catch (Error e)
  40             {
  41                 stdout.printf ("Error:  %s\n", e.message);
  42             }
  43         }
  44     }
  45
  46     public void store_id_cards ()
  47     {
  48         var key_file = new KeyFile ();
  49
  50         foreach (IdCard id_card in this.id_card_list)
  51         {
  52             key_file.set_string (id_card.display_name, "Issuer", id_card.issuer);
  53             key_file.set_string (id_card.display_name, "DisplayName", id_card.display_name);
  54             key_file.set_string (id_card.display_name, "Username", id_card.username);
  55             key_file.set_string (id_card.display_name, "Password", id_card.password ?? "");
  56             key_file.set_string_list (id_card.display_name, "Services", id_card.services);
  57         }
  58
  59         var text = key_file.to_data (null);
  60
  61         try
  62         {
  63             var path = get_data_dir ();
  64             var filename = Path.build_filename (path, FILE_NAME);
  65             FileUtils.set_contents (filename, text, -1);
  66         }
  67         catch (Error e)
  68         {
  69             stdout.printf ("Error:  %s\n", e.message);
  70         }
  71     }
  72
  73     private string get_data_dir()
  74     {
  75         string path;
  76
  77         path = Path.build_filename (Environment.get_user_data_dir (),
  78                                     Config.PACKAGE_TARNAME);
  79         if (!FileUtils.test (path, FileTest.EXISTS))
  80         {
  81             DirUtils.create (path, 0700);
  82         }
  83
  84         return path;
  85     }
  86 }