src/moonshot-identity-dialog.vala

   1 /*
   2  * Copyright (c) 2016, JANET(UK)
   3  * All rights reserved.
   4  *
   5  * Redistribution and use in source and binary forms, with or without
   6  * modification, are permitted provided that the following conditions
   7  * are met:
   8  *
   9  * 1. Redistributions of source code must retain the above copyright
  10  *    notice, this list of conditions and the following disclaimer.
  11  *
  12  * 2. Redistributions in binary form must reproduce the above copyright
  13  *    notice, this list of conditions and the following disclaimer in the
  14  *    documentation and/or other materials provided with the distribution.
  15  *
  16  * 3. Neither the name of JANET(UK) nor the names of its contributors
  17  *    may be used to endorse or promote products derived from this software
  18  *    without specific prior written permission.
  19  *
  20  * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS"
  21  * AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  22  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  23  * ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDER OR CONTRIBUTORS BE LIABLE
  24  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  25  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  26  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  27  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  28  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  29  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  30  * SUCH DAMAGE.
  31 */
  32 using Gtk;
  33
  34
  35 // Defined here as workaround for emacs vala-mode indentation failure.
  36 #if VALA_0_12
  37 static const string CANCEL = Stock.CANCEL;
  38 #else
  39 static const string CANCEL = STOCK_CANCEL;
  40 #endif
  41
  42
  43 class IdentityDialog : Dialog
  44 {
  45     private static Gdk.Color white = make_color(65535, 65535, 65535);
  46     private static Gdk.Color selected_color = make_color(0xd9 << 8, 0xf7 << 8, 65535);
  47
  48     private static MoonshotLogger logger = get_logger("IdentityDialog");
  49
  50     static const string displayname_labeltext = _("Display Name");
  51     static const string realm_labeltext = _("Realm");
  52     static const string username_labeltext = _("Username");
  53     static const string password_labeltext = _("Password");
  54
  55     private Entry displayname_entry;
  56     private Label displayname_label;
  57     private Entry realm_entry;
  58     private Label realm_label;
  59     private Entry username_entry;
  60     private Label username_label;
  61     private Entry password_entry;
  62     private Label password_label;
  63     private CheckButton remember_checkbutton;
  64     private Label message_label;
  65     public bool complete;
  66     private IdCard card;
  67
  68     private Label selected_item = null;
  69
  70     public string display_name {
  71         get { return displayname_entry.get_text(); }
  72     }
  73
  74     public string issuer {
  75         get { return realm_entry.get_text(); }
  76     }
  77
  78     public string username {
  79         get { return username_entry.get_text(); }
  80     }
  81
  82     public string password {
  83         get { return password_entry.get_text(); }
  84     }
  85
  86     public bool store_password {
  87         get { return remember_checkbutton.active; }
  88     }
  89
  90     internal string[] get_services()
  91     {
  92         return card.services;
  93     }
  94
  95     public IdentityDialog(IdentityManagerView parent)
  96     {
  97         this.with_idcard(null, _("Add ID Card"), parent);
  98     }
  99
 100     public IdentityDialog.with_idcard(IdCard? a_card, string title, IdentityManagerView parent)
 101     {
 102         bool is_new_card = false;
 103         if (a_card == null)
 104         {
 105             is_new_card = true;
 106         }
 107
 108         card = a_card ?? new IdCard();
 109         this.set_title(title);
 110         this.set_modal(true);
 111         this.set_transient_for(parent);
 112
 113         this.add_buttons(_("OK"), ResponseType.OK, CANCEL, ResponseType.CANCEL);
 114         Box content_area = (Box) this.get_content_area();
 115
 116         displayname_label = new Label(@"$displayname_labeltext:");
 117         displayname_label.set_alignment(0, (float) 0.5);
 118         displayname_entry = new Entry();
 119         displayname_entry.set_text(card.display_name);
 120         displayname_entry.set_width_chars(40);
 121
 122         realm_label = new Label(@"$realm_labeltext:");
 123         realm_label.set_alignment(0, (float) 0.5);
 124         realm_entry = new Entry();
 125         realm_entry.set_text(card.issuer);
 126         realm_entry.set_width_chars(60);
 127
 128         username_label = new Label(@"$username_labeltext:");
 129         username_label.set_alignment(0, (float) 0.5);
 130         username_entry = new Entry();
 131         username_entry.set_text(card.username);
 132         username_entry.set_width_chars(40);
 133
 134         password_label = new Label(@"$password_labeltext:");
 135         password_label.set_alignment(0, (float) 0.5);
 136
 137         remember_checkbutton = new CheckButton.with_label(_("Remember password"));
 138         remember_checkbutton.active = card.store_password;
 139
 140         password_entry = new Entry();
 141         password_entry.set_invisible_char('*');
 142         password_entry.set_visibility(false);
 143         password_entry.set_width_chars(40);
 144         password_entry.set_text(card.password);
 145
 146         message_label = new Label("");
 147         message_label.set_visible(false);
 148
 149         set_atk_relation(displayname_label, displayname_entry, Atk.RelationType.LABEL_FOR);
 150         set_atk_relation(realm_label, realm_entry, Atk.RelationType.LABEL_FOR);
 151         set_atk_relation(username_label, username_entry, Atk.RelationType.LABEL_FOR);
 152         set_atk_relation(password_label, password_entry, Atk.RelationType.LABEL_FOR);
 153
 154         content_area.pack_start(message_label, false, false, 6);
 155         add_as_vbox(content_area, displayname_label, displayname_entry);
 156         add_as_vbox(content_area, username_label, username_entry);
 157         add_as_vbox(content_area, realm_label, realm_entry);
 158         add_as_vbox(content_area, password_label, password_entry);
 159
 160         // var entries = new VBox(false, 6);
 161         // add_as_vbox(entries, displayname_label, displayname_entry);
 162         // add_as_vbox(entries, realm_label, realm_entry);
 163         // add_as_vbox(entries, username_label, username_entry);
 164         // add_as_vbox(entries, password_label, password_entry);
 165         // content_area.pack_start(entries, false, false, 0);
 166
 167         var remember_hbox = new HBox(false, 40);
 168         remember_hbox.pack_start(new HBox(false, 0), false, false, 0);
 169         remember_hbox.pack_start(remember_checkbutton, false, false, 0);
 170         content_area.pack_start(remember_hbox, false, false, 2);
 171         // content_area.pack_start(remember_checkbutton, false, false, 2);
 172
 173         this.response.connect(on_response);
 174         content_area.set_border_width(6);
 175
 176         if (!is_new_card)
 177         {
 178             var services_vbox = make_services_vbox();
 179             content_area.pack_start(services_vbox);
 180         }
 181
 182         this.set_border_width(6);
 183         this.set_resizable(false);
 184         this.modify_bg(StateType.NORMAL, white);
 185         this.show_all();
 186     }
 187
 188     private static void add_as_vbox(Box content_area, Label label, Entry entry)
 189     {
 190         VBox vbox = new VBox(false, 2);
 191
 192         vbox.pack_start(label, false, false, 0);
 193         vbox.pack_start(entry, false, false, 0);
 194
 195         // Hack to prevent the text entries from stretching horizontally
 196         HBox hbox = new HBox(false, 0);
 197         hbox.pack_start(vbox, false, false, 0);
 198         content_area.pack_start(hbox, false, false, 6);
 199     }
 200
 201     private static string update_preamble(string preamble)
 202     {
 203         if (preamble == "")
 204             return _("Missing required field: ");
 205         return _("Missing required fields: ");
 206     }
 207
 208     private static string update_message(string old_message, string new_item)
 209     {
 210         string message;
 211         if (old_message == "")
 212             message = new_item;
 213         else
 214             message = old_message + ", " + new_item;
 215         return message;
 216     }
 217
 218     private static void check_field(string field, Label label, string fieldname, ref string preamble, ref string message)
 219     {
 220         if (field != "") {
 221             label.set_markup(@"$fieldname:");
 222             return;
 223         }
 224         label.set_markup(@"<span foreground=\"red\">$fieldname:</span>");
 225         preamble = update_preamble(preamble);
 226         message = update_message(message, fieldname);
 227     }
 228
 229     private bool check_fields()
 230     {
 231         string preamble = "";
 232         string message = "";
 233         string password_test = store_password ? password : "not required";
 234         check_field(display_name, displayname_label, displayname_labeltext, ref preamble, ref message);
 235         check_field(username, username_label, username_labeltext, ref preamble, ref message);
 236         check_field(issuer, realm_label, realm_labeltext, ref preamble, ref message);
 237         check_field(password_test, password_label, password_labeltext, ref preamble, ref message);
 238         if (message != "") {
 239             message_label.set_visible(true);
 240             message_label.set_markup(@"<span foreground=\"red\">$preamble$message</span>");
 241             return false;
 242         }
 243         return true;
 244     }
 245
 246     private void on_response(Dialog source, int response_id)
 247     {
 248         switch (response_id) {
 249         case ResponseType.OK:
 250             complete = check_fields();
 251             break;
 252         case ResponseType.CANCEL:
 253             complete = true;
 254             break;
 255         }
 256     }
 257
 258     private static void label_make_bold(Label label)
 259     {
 260         var font_desc = new Pango.FontDescription();
 261
 262         font_desc.set_weight(Pango.Weight.BOLD);
 263
 264         /* This will only affect the weight of the font. The rest is
 265          * from the current state of the widget, which comes from the
 266          * theme or user prefs, since the font desc only has the
 267          * weight flag turned on.
 268          */
 269         label.modify_font(font_desc);
 270     }
 271
 272     private VBox make_services_vbox()
 273     {
 274         logger.trace("make_services_vbox");
 275
 276         var services_vbox_alignment = new Alignment(0, 0, 0, 1);
 277         var services_vscroll = new ScrolledWindow(null, null);
 278         services_vscroll.set_policy(PolicyType.NEVER, PolicyType.AUTOMATIC);
 279         services_vscroll.set_shadow_type(ShadowType.IN);
 280         services_vscroll.set_size_request(0, 60);
 281         services_vscroll.add_with_viewport(services_vbox_alignment);
 282
 283 #if VALA_0_12
 284         var remove_button = new Button.from_stock(Stock.REMOVE);
 285 #else
 286         var remove_button = new Button.from_stock(STOCK_REMOVE);
 287 #endif
 288         remove_button.set_sensitive(false);
 289
 290
 291         var services_table = new Table(card.services.length, 1, false);
 292         services_table.set_row_spacings(1);
 293         services_table.set_col_spacings(0);
 294         services_table.modify_bg(StateType.NORMAL, white);
 295
 296         var table_button_hbox = new HBox(false, 6);
 297         table_button_hbox.pack_start(services_vscroll, true, true, 6);
 298
 299         // Hack to prevent the button from growing vertically
 300         VBox fixed_height = new VBox(false, 0);
 301         fixed_height.pack_start(remove_button, false, false, 0);
 302         table_button_hbox.pack_start(fixed_height, false, false, 6);
 303
 304         // A table doesn't have a background color, so put it in an EventBox, and
 305         // set the EventBox's background color instead.
 306         EventBox table_bg = new EventBox();
 307         table_bg.modify_bg(StateType.NORMAL, white);
 308         table_bg.add(services_table);
 309         services_vbox_alignment.add(table_bg);
 310
 311         var services_vbox_title = new Label(_("Services:"));
 312         label_make_bold(services_vbox_title);
 313         services_vbox_title.set_alignment(0, (float) 0.5);
 314
 315         var services_vbox = new VBox(false, 6);
 316         services_vbox.pack_start(services_vbox_title, false, false, 6);
 317         services_vbox.pack_start(table_button_hbox, true, true, 6);
 318
 319         int i = 0;
 320         foreach (string service in card.services)
 321         {
 322             var label = new Label(service);
 323             label.set_alignment((float) 0, (float) 0);
 324
 325             EventBox event_box = new EventBox();
 326             event_box.modify_bg(StateType.NORMAL, white);
 327             event_box.add(label);
 328             event_box.button_press_event.connect(() =>
 329                 {
 330                     var state = label.get_state();
 331                     logger.trace("button_press_callback: Label state=" + state.to_string() + " setting bg to " + white.to_string());
 332
 333                     if (selected_item == label)
 334                     {
 335                         // Deselect
 336                         selected_item.parent.modify_bg(state, white);
 337                         selected_item = null;
 338                         remove_button.set_sensitive(false);
 339                     }
 340                     else
 341                     {
 342                         if (selected_item != null)
 343                         {
 344                             // Deselect
 345                             selected_item.parent.modify_bg(state, white);
 346                             selected_item = null;
 347                         }
 348
 349                         // Select
 350                         selected_item = label;
 351                         selected_item.parent.modify_bg(state, selected_color);
 352                         remove_button.set_sensitive(true);
 353                     }
 354                     return false;
 355                 });
 356
 357             AttachOptions opts = AttachOptions.EXPAND | AttachOptions.FILL;
 358             services_table.attach(event_box, 0, 1, i, i+1, opts, opts, 3, 0);
 359             i++;
 360         }
 361
 362         remove_button.clicked.connect((remove_button) =>
 363             {
 364                 var result = WarningDialog.confirm(this,
 365                                                    Markup.printf_escaped(
 366                                                        "<span font-weight='heavy'>You are about to remove the service '%s'.</span>",
 367                                                        selected_item.label)
 368                                                    + "\n\nAre you sure you want to do this?",
 369                                                    "delete_service");
 370
 371                 if (result)
 372                 {
 373                     if (card != null) {
 374                         SList<string> services = new SList<string>();
 375
 376                         foreach (string srv in card.services)
 377                         {
 378                             if (srv != selected_item.label)
 379                                 services.append(srv);
 380                         }
 381
 382                         card.services = new string[services.length()];
 383                         for (int j = 0; j < card.services.length; j++)
 384                         {
 385                             card.services[j] = services.nth_data(j);
 386                         }
 387
 388                         services_table.remove(selected_item.parent);
 389                         selected_item = null;
 390                         remove_button.set_sensitive(false);
 391                     }
 392                 }
 393
 394             });
 395
 396         return services_vbox;
 397     }
 398
 399
 400 }