src/moonshot-identity-dialog.vala

   1 /*
   2  * Copyright (c) 2016, JANET(UK)
   3  * All rights reserved.
   4  *
   5  * Redistribution and use in source and binary forms, with or without
   6  * modification, are permitted provided that the following conditions
   7  * are met:
   8  *
   9  * 1. Redistributions of source code must retain the above copyright
  10  *    notice, this list of conditions and the following disclaimer.
  11  *
  12  * 2. Redistributions in binary form must reproduce the above copyright
  13  *    notice, this list of conditions and the following disclaimer in the
  14  *    documentation and/or other materials provided with the distribution.
  15  *
  16  * 3. Neither the name of JANET(UK) nor the names of its contributors
  17  *    may be used to endorse or promote products derived from this software
  18  *    without specific prior written permission.
  19  *
  20  * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS"
  21  * AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  22  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  23  * ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDER OR CONTRIBUTORS BE LIABLE
  24  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  25  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  26  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  27  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  28  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  29  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  30  * SUCH DAMAGE.
  31 */
  32 using Gtk;
  33
  34
  35 // Defined here as workaround for emacs vala-mode indentation failure.
  36 #if VALA_0_12
  37 static const string CANCEL = Stock.CANCEL;
  38 #else
  39 static const string CANCEL = STOCK_CANCEL;
  40 #endif
  41
  42
  43 class IdentityDialog : Dialog
  44 {
  45     private static Gdk.Color white = make_color(65535, 65535, 65535);
  46     private static Gdk.Color selected_color = make_color(0xd9 << 8, 0xf7 << 8, 65535);
  47     private static Gdk.Color alt_color = make_color(0xf2 << 8, 0xf2 << 8, 0xf2 << 8);
  48
  49     private static MoonshotLogger logger = get_logger("IdentityDialog");
  50
  51     static const string displayname_labeltext = _("Display Name");
  52     static const string realm_labeltext = _("Realm");
  53     static const string username_labeltext = _("Username");
  54     static const string password_labeltext = _("Password");
  55
  56     private Entry displayname_entry;
  57     private Label displayname_label;
  58     private Entry realm_entry;
  59     private Label realm_label;
  60     private Entry username_entry;
  61     private Label username_label;
  62     private Entry password_entry;
  63     private Label password_label;
  64     private CheckButton remember_checkbutton;
  65     private Label message_label;
  66     public bool complete;
  67     private IdCard card;
  68
  69     private Label selected_item = null;
  70
  71     public string display_name {
  72         get { return displayname_entry.get_text(); }
  73     }
  74
  75     public string issuer {
  76         get { return realm_entry.get_text(); }
  77     }
  78
  79     public string username {
  80         get { return username_entry.get_text(); }
  81     }
  82
  83     public string password {
  84         get { return password_entry.get_text(); }
  85     }
  86
  87     public bool store_password {
  88         get { return remember_checkbutton.active; }
  89     }
  90
  91     internal string[] get_services()
  92     {
  93         return card.services;
  94     }
  95
  96     public IdentityDialog(IdentityManagerView parent)
  97     {
  98         this.with_idcard(null, _("Add ID Card"), parent);
  99     }
 100
 101     public IdentityDialog.with_idcard(IdCard? a_card, string title, IdentityManagerView parent)
 102     {
 103         bool is_new_card = false;
 104         if (a_card == null)
 105         {
 106             is_new_card = true;
 107         }
 108
 109         card = a_card ?? new IdCard();
 110         this.set_title(title);
 111         this.set_modal(true);
 112         this.set_transient_for(parent);
 113
 114         this.add_buttons(_("OK"), ResponseType.OK, CANCEL, ResponseType.CANCEL);
 115         Box content_area = (Box) this.get_content_area();
 116
 117         displayname_label = new Label(@"$displayname_labeltext:");
 118         displayname_label.set_alignment(0, (float) 0.5);
 119         displayname_entry = new Entry();
 120         displayname_entry.set_text(card.display_name);
 121         displayname_entry.set_width_chars(40);
 122
 123         realm_label = new Label(@"$realm_labeltext:");
 124         realm_label.set_alignment(0, (float) 0.5);
 125         realm_entry = new Entry();
 126         realm_entry.set_text(card.issuer);
 127         realm_entry.set_width_chars(60);
 128
 129         username_label = new Label(@"$username_labeltext:");
 130         username_label.set_alignment(0, (float) 0.5);
 131         username_entry = new Entry();
 132         username_entry.set_text(card.username);
 133         username_entry.set_width_chars(40);
 134
 135         password_label = new Label(@"$password_labeltext:");
 136         password_label.set_alignment(0, (float) 0.5);
 137
 138         remember_checkbutton = new CheckButton.with_label(_("Remember password"));
 139         remember_checkbutton.active = card.store_password;
 140
 141         password_entry = new Entry();
 142         password_entry.set_invisible_char('*');
 143         password_entry.set_visibility(false);
 144         password_entry.set_width_chars(40);
 145         password_entry.set_text(card.password);
 146
 147         message_label = new Label("");
 148         message_label.set_visible(false);
 149
 150         set_atk_relation(displayname_label, displayname_entry, Atk.RelationType.LABEL_FOR);
 151         set_atk_relation(realm_label, realm_entry, Atk.RelationType.LABEL_FOR);
 152         set_atk_relation(username_label, username_entry, Atk.RelationType.LABEL_FOR);
 153         set_atk_relation(password_label, password_entry, Atk.RelationType.LABEL_FOR);
 154
 155         content_area.pack_start(message_label, false, false, 6);
 156         add_as_vbox(content_area, displayname_label, displayname_entry);
 157         add_as_vbox(content_area, username_label, username_entry);
 158         add_as_vbox(content_area, realm_label, realm_entry);
 159         add_as_vbox(content_area, password_label, password_entry);
 160
 161         // var entries = new VBox(false, 6);
 162         // add_as_vbox(entries, displayname_label, displayname_entry);
 163         // add_as_vbox(entries, realm_label, realm_entry);
 164         // add_as_vbox(entries, username_label, username_entry);
 165         // add_as_vbox(entries, password_label, password_entry);
 166         // content_area.pack_start(entries, false, false, 0);
 167
 168         var remember_hbox = new HBox(false, 40);
 169         remember_hbox.pack_start(new HBox(false, 0), false, false, 0);
 170         remember_hbox.pack_start(remember_checkbutton, false, false, 0);
 171         content_area.pack_start(remember_hbox, false, false, 2);
 172         // content_area.pack_start(remember_checkbutton, false, false, 2);
 173
 174         this.response.connect(on_response);
 175         content_area.set_border_width(6);
 176
 177         if (!is_new_card)
 178         {
 179             var services_vbox = make_services_vbox();
 180             content_area.pack_start(services_vbox);
 181         }
 182
 183         this.set_border_width(6);
 184         this.set_resizable(false);
 185         this.modify_bg(StateType.NORMAL, white);
 186         this.show_all();
 187     }
 188
 189     private static void add_as_vbox(Box content_area, Label label, Entry entry)
 190     {
 191         VBox vbox = new VBox(false, 2);
 192
 193         vbox.pack_start(label, false, false, 0);
 194         vbox.pack_start(entry, false, false, 0);
 195
 196         // Hack to prevent the text entries from stretching horizontally
 197         HBox hbox = new HBox(false, 0);
 198         hbox.pack_start(vbox, false, false, 0);
 199         content_area.pack_start(hbox, false, false, 6);
 200     }
 201
 202     private static string update_preamble(string preamble)
 203     {
 204         if (preamble == "")
 205             return _("Missing required field: ");
 206         return _("Missing required fields: ");
 207     }
 208
 209     private static string update_message(string old_message, string new_item)
 210     {
 211         string message;
 212         if (old_message == "")
 213             message = new_item;
 214         else
 215             message = old_message + ", " + new_item;
 216         return message;
 217     }
 218
 219     private static void check_field(string field, Label label, string fieldname, ref string preamble, ref string message)
 220     {
 221         if (field != "") {
 222             label.set_markup(@"$fieldname:");
 223             return;
 224         }
 225         label.set_markup(@"<span foreground=\"red\">$fieldname:</span>");
 226         preamble = update_preamble(preamble);
 227         message = update_message(message, fieldname);
 228     }
 229
 230     private bool check_fields()
 231     {
 232         string preamble = "";
 233         string message = "";
 234         string password_test = store_password ? password : "not required";
 235         check_field(display_name, displayname_label, displayname_labeltext, ref preamble, ref message);
 236         check_field(username, username_label, username_labeltext, ref preamble, ref message);
 237         check_field(issuer, realm_label, realm_labeltext, ref preamble, ref message);
 238         check_field(password_test, password_label, password_labeltext, ref preamble, ref message);
 239         if (message != "") {
 240             message_label.set_visible(true);
 241             message_label.set_markup(@"<span foreground=\"red\">$preamble$message</span>");
 242             return false;
 243         }
 244         return true;
 245     }
 246
 247     private void on_response(Dialog source, int response_id)
 248     {
 249         switch (response_id) {
 250         case ResponseType.OK:
 251             complete = check_fields();
 252             break;
 253         case ResponseType.CANCEL:
 254             complete = true;
 255             break;
 256         }
 257     }
 258
 259     private static void label_make_bold(Label label)
 260     {
 261         var font_desc = new Pango.FontDescription();
 262
 263         font_desc.set_weight(Pango.Weight.BOLD);
 264
 265         /* This will only affect the weight of the font. The rest is
 266          * from the current state of the widget, which comes from the
 267          * theme or user prefs, since the font desc only has the
 268          * weight flag turned on.
 269          */
 270         label.modify_font(font_desc);
 271     }
 272
 273     private VBox make_services_vbox()
 274     {
 275         logger.trace("make_services_vbox");
 276
 277         var services_vbox_alignment = new Alignment(0, 0, 0, 1);
 278         var services_vscroll = new ScrolledWindow(null, null);
 279         services_vscroll.set_policy(PolicyType.NEVER, PolicyType.AUTOMATIC);
 280         services_vscroll.set_shadow_type(ShadowType.IN);
 281         services_vscroll.set_size_request(0, 60);
 282         services_vscroll.add_with_viewport(services_vbox_alignment);
 283
 284 #if VALA_0_12
 285         var remove_button = new Button.from_stock(Stock.REMOVE);
 286 #else
 287         var remove_button = new Button.from_stock(STOCK_REMOVE);
 288 #endif
 289         remove_button.set_sensitive(false);
 290
 291
 292         var services_table = new Table(card.services.length, 1, false);
 293         services_table.set_row_spacings(1);
 294         services_table.set_col_spacings(0);
 295         services_table.modify_bg(StateType.NORMAL, white);
 296
 297         var table_button_hbox = new HBox(false, 6);
 298         table_button_hbox.pack_start(services_vscroll, true, true, 6);
 299
 300         // Hack to prevent the button from growing vertically
 301         VBox fixed_height = new VBox(false, 0);
 302         fixed_height.pack_start(remove_button, false, false, 0);
 303         table_button_hbox.pack_start(fixed_height, false, false, 6);
 304
 305         // A table doesn't have a background color, so put it in an EventBox, and
 306         // set the EventBox's background color instead.
 307         EventBox table_bg = new EventBox();
 308         table_bg.modify_bg(StateType.NORMAL, white);
 309         table_bg.add(services_table);
 310         services_vbox_alignment.add(table_bg);
 311
 312         var services_vbox_title = new Label(_("Services:"));
 313         label_make_bold(services_vbox_title);
 314         services_vbox_title.set_alignment(0, (float) 0.5);
 315
 316         var services_vbox = new VBox(false, 6);
 317         services_vbox.pack_start(services_vbox_title, false, false, 6);
 318         services_vbox.pack_start(table_button_hbox, true, true, 6);
 319
 320         int i = 0;
 321         foreach (string service in card.services)
 322         {
 323             var label = new Label(service);
 324             label.set_alignment((float) 0, (float) 0);
 325
 326             EventBox event_box = new EventBox();
 327             event_box.modify_bg(StateType.NORMAL, white);
 328             event_box.add(label);
 329             event_box.button_press_event.connect(() =>
 330                 {
 331                     var state = label.get_state();
 332                     logger.trace("button_press_callback: Label state=" + state.to_string() + " setting bg to " + white.to_string());
 333
 334                     if (selected_item == label)
 335                     {
 336                         // Deselect
 337                         selected_item.parent.modify_bg(state, white);
 338                         selected_item = null;
 339                         remove_button.set_sensitive(false);
 340                     }
 341                     else
 342                     {
 343                         if (selected_item != null)
 344                         {
 345                             // Deselect
 346                             selected_item.parent.modify_bg(state, white);
 347                             selected_item = null;
 348                         }
 349
 350                         // Select
 351                         selected_item = label;
 352                         selected_item.parent.modify_bg(state, selected_color);
 353                         remove_button.set_sensitive(true);
 354                     }
 355                     return false;
 356                 });
 357
 358             AttachOptions opts = AttachOptions.EXPAND | AttachOptions.FILL;
 359             services_table.attach(event_box, 0, 1, i, i+1, opts, opts, 3, 0);
 360             i++;
 361         }
 362
 363         remove_button.clicked.connect((remove_button) =>
 364             {
 365                 var result = WarningDialog.confirm(this,
 366                                                    "<span font-weight='heavy'>You are about to remove the service '%s'.</span>"
 367                                                    .printf(selected_item.label)
 368                                                    + "\n\nAre you sure you want to do this?",
 369                                                    "delete_service");
 370
 371                 if (result)
 372                 {
 373                     if (card != null) {
 374                         SList<string> services = new SList<string>();
 375
 376                         foreach (string srv in card.services)
 377                         {
 378                             if (srv != selected_item.label)
 379                                 services.append(srv);
 380                         }
 381
 382                         card.services = new string[services.length()];
 383                         for (int j = 0; j < card.services.length; j++)
 384                         {
 385                             card.services[j] = services.nth_data(j);
 386                         }
 387
 388                         services_table.remove(selected_item.parent);
 389                         selected_item = null;
 390                         remove_button.set_sensitive(false);
 391                     }
 392                 }
 393
 394             });
 395
 396         return services_vbox;
 397     }
 398
 399
 400 }