src/moonshot-identity-dialog.vala

   1 /*
   2  * Copyright (c) 2016, JANET(UK)
   3  * All rights reserved.
   4  *
   5  * Redistribution and use in source and binary forms, with or without
   6  * modification, are permitted provided that the following conditions
   7  * are met:
   8  *
   9  * 1. Redistributions of source code must retain the above copyright
  10  *    notice, this list of conditions and the following disclaimer.
  11  *
  12  * 2. Redistributions in binary form must reproduce the above copyright
  13  *    notice, this list of conditions and the following disclaimer in the
  14  *    documentation and/or other materials provided with the distribution.
  15  *
  16  * 3. Neither the name of JANET(UK) nor the names of its contributors
  17  *    may be used to endorse or promote products derived from this software
  18  *    without specific prior written permission.
  19  *
  20  * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS"
  21  * AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  22  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  23  * ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDER OR CONTRIBUTORS BE LIABLE
  24  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  25  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  26  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  27  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  28  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  29  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  30  * SUCH DAMAGE.
  31 */
  32
  33 using Gee;
  34 using Gtk;
  35
  36
  37 // Defined here as workaround for emacs vala-mode indentation failure.
  38 #if VALA_0_12
  39 static const string CANCEL = Stock.CANCEL;
  40 #else
  41 static const string CANCEL = STOCK_CANCEL;
  42 #endif
  43
  44
  45 class IdentityDialog : Dialog
  46 {
  47     private static Gdk.Color white = make_color(65535, 65535, 65535);
  48     private static Gdk.Color selected_color = make_color(0xd9 << 8, 0xf7 << 8, 65535);
  49
  50     private static MoonshotLogger logger = get_logger("IdentityDialog");
  51
  52     static const string displayname_labeltext = _("Display Name");
  53     static const string realm_labeltext = _("Realm");
  54     static const string username_labeltext = _("Username");
  55     static const string password_labeltext = _("Password");
  56
  57     private Entry displayname_entry;
  58     private Label displayname_label;
  59     private Entry realm_entry;
  60     private Label realm_label;
  61     private Entry username_entry;
  62     private Label username_label;
  63     private Entry password_entry;
  64     private Label password_label;
  65     private CheckButton remember_checkbutton;
  66     private Label message_label;
  67     public bool complete;
  68     private IdCard card;
  69
  70     private Label selected_item = null;
  71
  72     public string display_name {
  73         get { return displayname_entry.get_text(); }
  74     }
  75
  76     public string issuer {
  77         get { return realm_entry.get_text(); }
  78     }
  79
  80     public string username {
  81         get { return username_entry.get_text(); }
  82     }
  83
  84     public string password {
  85         get { return password_entry.get_text(); }
  86     }
  87
  88     public bool store_password {
  89         get { return remember_checkbutton.active; }
  90     }
  91
  92     internal ArrayList<string> get_services()
  93     {
  94         return card.services;
  95     }
  96
  97     public IdentityDialog(IdentityManagerView parent)
  98     {
  99         this.with_idcard(null, _("Add ID Card"), parent);
 100     }
 101
 102     public IdentityDialog.with_idcard(IdCard? a_card, string title, IdentityManagerView parent)
 103     {
 104         bool is_new_card = false;
 105         if (a_card == null)
 106         {
 107             is_new_card = true;
 108         }
 109
 110         card = a_card ?? new IdCard();
 111         this.set_title(title);
 112         this.set_modal(true);
 113         this.set_transient_for(parent);
 114
 115         this.add_buttons(_("OK"), ResponseType.OK, CANCEL, ResponseType.CANCEL);
 116         Box content_area = (Box) this.get_content_area();
 117
 118         displayname_label = new Label(@"$displayname_labeltext:");
 119         displayname_label.set_alignment(0, (float) 0.5);
 120         displayname_entry = new Entry();
 121         displayname_entry.set_text(card.display_name);
 122         displayname_entry.set_width_chars(40);
 123
 124         realm_label = new Label(@"$realm_labeltext:");
 125         realm_label.set_alignment(0, (float) 0.5);
 126         realm_entry = new Entry();
 127         realm_entry.set_text(card.issuer);
 128         realm_entry.set_width_chars(60);
 129
 130         username_label = new Label(@"$username_labeltext:");
 131         username_label.set_alignment(0, (float) 0.5);
 132         username_entry = new Entry();
 133         username_entry.set_text(card.username);
 134         username_entry.set_width_chars(40);
 135
 136         password_label = new Label(@"$password_labeltext:");
 137         password_label.set_alignment(0, (float) 0.5);
 138
 139         remember_checkbutton = new CheckButton.with_label(_("Remember password"));
 140         remember_checkbutton.active = card.store_password;
 141
 142         password_entry = new Entry();
 143         password_entry.set_invisible_char('*');
 144         password_entry.set_visibility(false);
 145         password_entry.set_width_chars(40);
 146         password_entry.set_text(card.password);
 147
 148         message_label = new Label("");
 149         message_label.set_visible(false);
 150
 151         set_atk_relation(displayname_label, displayname_entry, Atk.RelationType.LABEL_FOR);
 152         set_atk_relation(realm_label, realm_entry, Atk.RelationType.LABEL_FOR);
 153         set_atk_relation(username_label, username_entry, Atk.RelationType.LABEL_FOR);
 154         set_atk_relation(password_label, password_entry, Atk.RelationType.LABEL_FOR);
 155
 156         content_area.pack_start(message_label, false, false, 6);
 157         add_as_vbox(content_area, displayname_label, displayname_entry);
 158         add_as_vbox(content_area, username_label, username_entry);
 159         add_as_vbox(content_area, realm_label, realm_entry);
 160         add_as_vbox(content_area, password_label, password_entry);
 161
 162         // var entries = new VBox(false, 6);
 163         // add_as_vbox(entries, displayname_label, displayname_entry);
 164         // add_as_vbox(entries, realm_label, realm_entry);
 165         // add_as_vbox(entries, username_label, username_entry);
 166         // add_as_vbox(entries, password_label, password_entry);
 167         // content_area.pack_start(entries, false, false, 0);
 168
 169         var remember_hbox = new HBox(false, 40);
 170         remember_hbox.pack_start(new HBox(false, 0), false, false, 0);
 171         remember_hbox.pack_start(remember_checkbutton, false, false, 0);
 172         content_area.pack_start(remember_hbox, false, false, 2);
 173         // content_area.pack_start(remember_checkbutton, false, false, 2);
 174
 175         this.response.connect(on_response);
 176         content_area.set_border_width(6);
 177
 178         Widget trust_anchor_box = make_trust_anchor_box(card);
 179         content_area.pack_start(trust_anchor_box, false, false, 15);
 180
 181         if (!is_new_card)
 182         {
 183             var services_vbox = make_services_vbox();
 184             content_area.pack_start(services_vbox);
 185         }
 186
 187         if (card.is_no_identity())
 188         {
 189             displayname_entry.set_sensitive(false);
 190             realm_entry.set_sensitive(false);
 191             username_entry.set_sensitive(false);
 192             password_entry.set_sensitive(false);
 193             remember_checkbutton.set_sensitive(false);
 194         }
 195
 196         this.set_border_width(6);
 197         this.set_resizable(false);
 198         this.modify_bg(StateType.NORMAL, white);
 199         this.show_all();
 200     }
 201
 202     private static Widget make_trust_anchor_box(IdCard id)
 203     {
 204
 205         Label ta_label = new Label(_("Trust anchor: ")
 206                                    + (id.trust_anchor.is_empty() ? _("None") : _("Enterprise provisioned")));
 207         ta_label.set_alignment(0, 0.5f);
 208
 209         if (id.trust_anchor.is_empty()) {
 210             return ta_label;
 211         }
 212
 213
 214         AttachOptions opts = AttachOptions.EXPAND | AttachOptions.FILL;
 215         AttachOptions fill = AttachOptions.FILL;
 216
 217         Table ta_table = new Table(6, 2, false);
 218         int row = 0;
 219
 220         var ta_clear_button = new Button.with_label(_("Clear Trust Anchor"));
 221         ta_clear_button.clicked.connect((w) => {id.trust_anchor = new TrustAnchor();});
 222
 223         ta_table.attach(ta_label, 0, 1, row, row + 1, opts, opts, 0, 0);
 224         ta_table.attach(ta_clear_button, 1, 2, row, row + 1, fill, fill, 0, 0);
 225         row++;
 226
 227         //!!TODO
 228         Label added_label = new Label(_("Added on: N/A"));
 229         added_label.set_alignment(0, 0.5f);
 230         ta_table.attach(added_label, 0, 1, row, row + 1, opts, opts, 20, 5);
 231         row++;
 232
 233         if (id.trust_anchor.get_anchor_type() == TrustAnchor.TrustAnchorType.SERVER_CERT) {
 234             Widget fingerprint = make_ta_fingerprint_widget(id.trust_anchor);
 235             ta_table.attach(fingerprint, 0, 2, row, row + 2, opts, opts, 20, 5);
 236         }
 237         else {
 238             Label ca_cert_label = new Label(_("CA Certificate:"));
 239             ca_cert_label.set_alignment(0, 0.5f);
 240             var export_button = new Button.with_label(_("Export Certificate"));
 241             //!!TODO!
 242             export_button.clicked.connect((w) => {/* !!TODO! */});
 243
 244             ta_table.attach(ca_cert_label, 0, 1, row, row + 1, opts, opts, 20, 0);
 245             ta_table.attach(export_button, 1, 2, row, row + 1, fill, fill, 0, 0);
 246             row++;
 247
 248             //!!TODO: When to show Subject, and when (if ever) show Subject-Altname here?
 249             Label subject_label = new Label(_("Subject: ") + id.trust_anchor.subject);
 250             subject_label.set_alignment(0, 0.5f);
 251             ta_table.attach(subject_label, 0, 1, row, row + 1, opts, opts, 40, 5);
 252             row++;
 253
 254             Label expiration_label = new Label(_("Expiration date: ") + id.trust_anchor.get_expiration_date());
 255             expiration_label.set_alignment(0, 0.5f);
 256             ta_table.attach(expiration_label, 0, 1, row, row + 1, opts, opts, 40, 5);
 257             row++;
 258
 259             //!!TODO: What *is* this?
 260             Label constraint_label = new Label(_("Constraint: "));
 261             constraint_label.set_alignment(0, 0.5f);
 262             ta_table.attach(constraint_label, 0, 1, row, row + 1, opts, opts, 20, 0);
 263             row++;
 264         }
 265
 266         return ta_table;
 267
 268     }
 269
 270     private static void add_as_vbox(Box content_area, Label label, Entry entry)
 271     {
 272         VBox vbox = new VBox(false, 2);
 273
 274         vbox.pack_start(label, false, false, 0);
 275         vbox.pack_start(entry, false, false, 0);
 276
 277         // Hack to prevent the text entries from stretching horizontally
 278         HBox hbox = new HBox(false, 0);
 279         hbox.pack_start(vbox, false, false, 0);
 280         content_area.pack_start(hbox, false, false, 6);
 281     }
 282
 283     private static string update_preamble(string preamble)
 284     {
 285         if (preamble == "")
 286             return _("Missing required field: ");
 287         return _("Missing required fields: ");
 288     }
 289
 290     private static string update_message(string old_message, string new_item)
 291     {
 292         string message;
 293         if (old_message == "")
 294             message = new_item;
 295         else
 296             message = old_message + ", " + new_item;
 297         return message;
 298     }
 299
 300     private static void check_field(string field, Label label, string fieldname, ref string preamble, ref string message)
 301     {
 302         if (field != "") {
 303             label.set_markup(@"$fieldname:");
 304             return;
 305         }
 306         label.set_markup(@"<span foreground=\"red\">$fieldname:</span>");
 307         preamble = update_preamble(preamble);
 308         message = update_message(message, fieldname);
 309     }
 310
 311     private bool check_fields()
 312     {
 313         string preamble = "";
 314         string message = "";
 315         string password_test = store_password ? password : "not required";
 316         if (!card.is_no_identity())
 317         {
 318             check_field(display_name, displayname_label, displayname_labeltext, ref preamble, ref message);
 319             check_field(username, username_label, username_labeltext, ref preamble, ref message);
 320             check_field(issuer, realm_label, realm_labeltext, ref preamble, ref message);
 321             check_field(password_test, password_label, password_labeltext, ref preamble, ref message);
 322         }
 323         if (message != "") {
 324             message_label.set_visible(true);
 325             message_label.set_markup(@"<span foreground=\"red\">$preamble$message</span>");
 326             return false;
 327         }
 328         return true;
 329     }
 330
 331     private void on_response(Dialog source, int response_id)
 332     {
 333         switch (response_id) {
 334         case ResponseType.OK:
 335             complete = check_fields();
 336             break;
 337         case ResponseType.CANCEL:
 338             complete = true;
 339             break;
 340         }
 341     }
 342
 343     private static void label_make_bold(Label label)
 344     {
 345         var font_desc = new Pango.FontDescription();
 346
 347         font_desc.set_weight(Pango.Weight.BOLD);
 348
 349         /* This will only affect the weight of the font. The rest is
 350          * from the current state of the widget, which comes from the
 351          * theme or user prefs, since the font desc only has the
 352          * weight flag turned on.
 353          */
 354         label.modify_font(font_desc);
 355     }
 356
 357     private VBox make_services_vbox()
 358     {
 359         logger.trace("make_services_vbox");
 360
 361         var services_vbox_alignment = new Alignment(0, 0, 1, 0);
 362         var services_vscroll = new ScrolledWindow(null, null);
 363         services_vscroll.set_policy(PolicyType.NEVER, PolicyType.AUTOMATIC);
 364         services_vscroll.set_shadow_type(ShadowType.IN);
 365         services_vscroll.set_size_request(0, 60);
 366         services_vscroll.add_with_viewport(services_vbox_alignment);
 367
 368 #if VALA_0_12
 369         var remove_button = new Button.from_stock(Stock.REMOVE);
 370 #else
 371         var remove_button = new Button.from_stock(STOCK_REMOVE);
 372 #endif
 373         remove_button.set_sensitive(false);
 374
 375
 376         var services_table = new Table(card.services.size, 1, false);
 377         services_table.set_row_spacings(1);
 378         services_table.set_col_spacings(0);
 379         services_table.modify_bg(StateType.NORMAL, white);
 380
 381         var table_button_hbox = new HBox(false, 6);
 382         table_button_hbox.pack_start(services_vscroll, true, true, 6);
 383
 384         // Hack to prevent the button from growing vertically
 385         VBox fixed_height = new VBox(false, 0);
 386         fixed_height.pack_start(remove_button, false, false, 0);
 387         table_button_hbox.pack_start(fixed_height, false, false, 0);
 388
 389         // A table doesn't have a background color, so put it in an EventBox, and
 390         // set the EventBox's background color instead.
 391         EventBox table_bg = new EventBox();
 392         table_bg.modify_bg(StateType.NORMAL, white);
 393         table_bg.add(services_table);
 394         services_vbox_alignment.add(table_bg);
 395
 396         var services_vbox_title = new Label(_("Services:"));
 397         label_make_bold(services_vbox_title);
 398         services_vbox_title.set_alignment(0, 0.5f);
 399
 400         var services_vbox = new VBox(false, 6);
 401         services_vbox.pack_start(services_vbox_title, false, false, 0);
 402         services_vbox.pack_start(table_button_hbox, true, true, 0);
 403
 404         int i = 0;
 405         foreach (string service in card.services)
 406         {
 407             var label = new Label(service);
 408             label.set_alignment((float) 0, (float) 0);
 409             label.xpad = 3;
 410
 411             EventBox event_box = new EventBox();
 412             event_box.modify_bg(StateType.NORMAL, white);
 413             event_box.add(label);
 414             event_box.button_press_event.connect(() =>
 415                 {
 416                     var state = label.get_state();
 417                     logger.trace("button_press_callback: Label state=" + state.to_string() + " setting bg to " + white.to_string());
 418
 419                     if (selected_item == label)
 420                     {
 421                         // Deselect
 422                         selected_item.parent.modify_bg(state, white);
 423                         selected_item = null;
 424                         remove_button.set_sensitive(false);
 425                     }
 426                     else
 427                     {
 428                         if (selected_item != null)
 429                         {
 430                             // Deselect
 431                             selected_item.parent.modify_bg(state, white);
 432                             selected_item = null;
 433                         }
 434
 435                         // Select
 436                         selected_item = label;
 437                         selected_item.parent.modify_bg(state, selected_color);
 438                         remove_button.set_sensitive(true);
 439                     }
 440                     return false;
 441                 });
 442
 443             services_table.attach_defaults(event_box, 0, 1, i, i+1);
 444             i++;
 445         }
 446
 447         remove_button.clicked.connect((remove_button) =>
 448             {
 449                 var result = WarningDialog.confirm(this,
 450                                                    Markup.printf_escaped(
 451                                                        "<span font-weight='heavy'>You are about to remove the service '%s'.</span>",
 452                                                        selected_item.label)
 453                                                    + "\n\nAre you sure you want to do this?",
 454                                                    "delete_service");
 455
 456                 if (result)
 457                 {
 458                     if (card != null) {
 459                         card.services.remove(selected_item.label);
 460                         services_table.remove(selected_item.parent);
 461                         selected_item = null;
 462                         remove_button.set_sensitive(false);
 463                     }
 464                 }
 465
 466             });
 467
 468         return services_vbox;
 469     }
 470
 471
 472 }