src/moonshot-identity-manager-app.vala

   1 /*
   2  * Copyright (c) 2011-2014, JANET(UK)
   3  * All rights reserved.
   4  *
   5  * Redistribution and use in source and binary forms, with or without
   6  * modification, are permitted provided that the following conditions
   7  * are met:
   8  *
   9  * 1. Redistributions of source code must retain the above copyright
  10  *    notice, this list of conditions and the following disclaimer.
  11  *
  12  * 2. Redistributions in binary form must reproduce the above copyright
  13  *    notice, this list of conditions and the following disclaimer in the
  14  *    documentation and/or other materials provided with the distribution.
  15  *
  16  * 3. Neither the name of JANET(UK) nor the names of its contributors
  17  *    may be used to endorse or promote products derived from this software
  18  *    without specific prior written permission.
  19  *
  20  * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS"
  21  * AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  22  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  23  * ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDER OR CONTRIBUTORS BE LIABLE
  24  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  25  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  26  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  27  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  28  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  29  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  30  * SUCH DAMAGE.
  31 */
  32 using Gee;
  33 using Gtk;
  34
  35 #if IPC_DBUS
  36 [DBus (name = "org.janet.Moonshot")]
  37 interface IIdentityManager : GLib.Object {
  38 #if IPC_DBUS_GLIB
  39     public abstract bool show_ui() throws DBus.Error;
  40 #else
  41     public abstract bool show_ui() throws IOError;
  42 #endif
  43 }
  44 #endif
  45
  46
  47 public class IdentityManagerApp {
  48     public static MoonshotLogger logger = get_logger("IdentityManagerApp");
  49
  50     public IdentityManagerModel model;
  51     public IdCard default_id_card;
  52     public bool explicitly_launched;
  53     public IdentityManagerView view;
  54     private MoonshotServer ipc_server;
  55     private bool name_is_owned;
  56     private bool show_requested;
  57
  58 #if OS_MACOS
  59     public OSXApplication osxApp;
  60
  61     // the signal handler function.
  62     // the current instance of our app class is passed in the
  63     // id_manager_app_instanceparameter
  64     public static bool on_osx_open_files(OSXApplication osx_app_instance,
  65                                          string file_name,
  66                                          IdentityManagerApp id_manager_app_instance ) {
  67         int added_cards = id_manager_app_instance.ipc_server.install_from_file(file_name);
  68         return true;
  69     }
  70 #endif
  71
  72     /** If we're successfully registered with DBus, then show the UI. Otherwise, wait until we're registered. */
  73     public void show() {
  74         if (name_is_owned) {
  75             if (view != null) {
  76                 view.make_visible();
  77             }
  78         }
  79         else {
  80             show_requested = true;
  81         }
  82     }
  83
  84 #if LOG4VALA
  85     // Call this from main() to ensure that the logger is initialized
  86     internal IdentityManagerApp.dummy() {}
  87 #endif
  88
  89     public IdentityManagerApp(bool headless, bool use_flat_file_store) {
  90         use_flat_file_store |= UserForcesFlatFileStore();
  91
  92 #if GNOME_KEYRING
  93         bool keyring_available = (!use_flat_file_store) && GnomeKeyring.is_available();
  94 #else
  95         bool keyring_available = false;
  96 #endif
  97
  98         IIdentityCardStore.StoreType store_type;
  99         if (headless || use_flat_file_store || !keyring_available)
 100             store_type = IIdentityCardStore.StoreType.FLAT_FILE;
 101         else
 102             store_type = IIdentityCardStore.StoreType.KEYRING;
 103
 104         model = new IdentityManagerModel(this, store_type);
 105         /* if headless, but we have nothing in the flat file store
 106          * and keyring is available, switch to keyring */
 107         if (headless && keyring_available && !use_flat_file_store && !model.HasNonTrivialIdentities())
 108             model.set_store_type(IIdentityCardStore.StoreType.KEYRING);
 109
 110         if (!headless)
 111             view = new IdentityManagerView(this);
 112         LinkedList<IdCard> card_list = model.get_card_list();
 113         if (card_list.size > 0)
 114             this.default_id_card = card_list.last();
 115
 116         init_ipc_server();
 117
 118 #if OS_MACOS
 119         osxApp = OSXApplication.get_instance();
 120         // The 'correct' way of connecting won't work in Mac OS with Vala 0.12; e.g.
 121         //     osxApp.ns_application_open_file.connect(install_from_file);
 122         // so we have to use this old way
 123         Signal.connect(osxApp, "NSApplicationOpenFile", (GLib.Callback)(on_osx_open_files), this);
 124 #endif
 125     }
 126
 127     public bool add_identity(IdCard id, bool force_flat_file_store) {
 128         if (view != null)
 129         {
 130             logger.trace("add_identity: calling view.add_identity");
 131             return view.add_identity(id, force_flat_file_store);
 132         }
 133
 134         logger.trace("add_identity: calling model.add_card");
 135         model.add_card(id, force_flat_file_store);
 136         return true;
 137     }
 138
 139     public void select_identity(IdentityRequest request) {
 140         logger.trace("select_identity: request.nai=%s".printf(request.nai ?? "[null]"));
 141
 142         IdCard identity = null;
 143
 144         if (request.select_default)
 145         {
 146             identity = default_id_card;
 147         }
 148
 149         if (identity == null)
 150         {
 151             bool has_nai = request.nai != null && request.nai != "";
 152             bool has_srv = request.service != null && request.service != "";
 153             bool confirm = false;
 154
 155             foreach (IdCard id in model.get_card_list())
 156             {
 157                 /* If NAI matches, use this id card */
 158                 if (has_nai && request.nai == id.nai)
 159                 {
 160                     logger.trace("select_identity: request has nai; returning " + id.display_name);
 161                     identity = id;
 162                     break;
 163                 }
 164
 165                 /* If any service matches we add id card to the candidate list */
 166                 if (has_srv)
 167                 {
 168                     if (id.services.contains(request.service)) {
 169                         logger.trace(@"select_identity: request has service '$(request.service); matched on '$(id.display_name)'");
 170                         request.candidates.append(id);
 171                     }
 172                 }
 173             }
 174
 175             /* If more than one candidate we dissasociate service from all ids */
 176             if ((identity == null) && has_srv && request.candidates.length() > 1)
 177             {
 178                 logger.trace(@"select_identity: multiple candidates; removing service '$(request.service) from all.");
 179                 foreach (IdCard id in request.candidates)
 180                 {
 181                     id.services.remove(request.service);
 182                 }
 183             }
 184
 185             /* If there are no candidates we use the service matching rules */
 186             if ((identity == null) && (request.candidates.length() == 0))
 187             {
 188                 logger.trace("select_identity: No candidates; using service matching rules.");
 189                 foreach (IdCard id in model.get_card_list())
 190                 {
 191                     foreach (Rule rule in id.rules)
 192                     {
 193                         if (!match_service_pattern(request.service, rule.pattern))
 194                             continue;
 195
 196                         logger.trace(@"select_identity: ID $(id.display_name) matched on service matching rules.");
 197                         request.candidates.append(id);
 198
 199                         if (rule.always_confirm == "true")
 200                             confirm = true;
 201                     }
 202                 }
 203             }
 204
 205             if ((identity == null) && has_nai) {
 206                 logger.trace("select_identity: Creating temp identity");
 207                 // create a temp identity
 208                 string[] components = request.nai.split("@", 2);
 209                 identity = new IdCard();
 210                 identity.display_name = request.nai;
 211                 identity.username = components[0];
 212                 if (components.length > 1)
 213                     identity.issuer = components[1];
 214                 identity.password = request.password;
 215                 identity.temporary = true;
 216             }
 217             if (identity == null) {
 218                 if (request.candidates.length() != 1) {
 219                     logger.trace("select_identity: Have %u candidates; user must make selection.".printf(request.candidates.length()));
 220                     confirm = true;
 221                 } else {
 222                     identity = request.candidates.nth_data(0);
 223                 }
 224             }
 225
 226             if (confirm && (view != null))
 227             {
 228                 if (!explicitly_launched)
 229                     show();
 230                 view.queue_identity_request(request);
 231                 return;
 232             }
 233         }
 234         // Send back the identity (we can't directly run the
 235         // callback because we may be being called from a 'yield')
 236         GLib.Idle.add(
 237             () => {
 238                 if (view != null) {
 239                     logger.trace("select_identity (Idle handler): calling check_add_password");
 240                     identity = view.check_add_password(identity, request, model);
 241                 }
 242                 request.return_identity(identity);
 243 // The following occasionally causes the app to exit without sending the dbus
 244 // reply, so for now we just don't exit
 245 //                if (!explicitly_launched)
 246 //                    Idle.add(() => { Gtk.main_quit(); return false; } );
 247                 return false;
 248             }
 249             );
 250         return;
 251     }
 252
 253     private bool match_service_pattern(string service, string pattern) {
 254         var pspec = new PatternSpec(pattern);
 255         return pspec.match_string(service);
 256     }
 257
 258 #if IPC_MSRPC
 259     private void init_ipc_server() {
 260         // Errors will currently be sent via g_log - ie. to an
 261         // obtrusive message box, on Windows
 262         //
 263         this.ipc_server = MoonshotServer.get_instance();
 264         MoonshotServer.start(this);
 265     }
 266 #elif IPC_DBUS_GLIB
 267     private void init_ipc_server() {
 268         try {
 269             var conn = DBus.Bus.get(DBus.BusType.SESSION);
 270             dynamic DBus.Object bus = conn.get_object("org.freedesktop.DBus",
 271                                                       "/org/freedesktop/DBus",
 272                                                       "org.freedesktop.DBus");
 273
 274             // try to register service in session bus
 275             uint reply = bus.request_name("org.janet.Moonshot", (uint) 0);
 276             if (reply == DBus.RequestNameReply.PRIMARY_OWNER)
 277             {
 278                 this.ipc_server = new MoonshotServer(this);
 279                 logger.trace("init_ipc_server(IPC_DBUS_GLIB) : Constructed new MoonshotServer");
 280                 conn.register_object("/org/janet/moonshot", ipc_server);
 281             } else {
 282                 logger.trace("init_ipc_server: reply != PRIMARY_OWNER");
 283                 bool shown = false;
 284                 GLib.Error e;
 285                 DBus.Object manager_proxy = conn.get_object("org.janet.Moonshot",
 286                                                             "/org/janet/moonshot",
 287                                                             "org.janet.Moonshot");
 288                 if (manager_proxy != null)
 289                     manager_proxy.call("ShowUi", out e, GLib.Type.INVALID, typeof(bool), out shown, GLib.Type.INVALID);
 290
 291                 if (!shown) {
 292                     GLib.error("Couldn't own name org.janet.Moonshot on dbus or show previously launched identity manager.");
 293                 } else {
 294                     stdout.printf("Showed previously launched identity manager.\n");
 295                     GLib.Process.exit(0);
 296                 }
 297             }
 298         }
 299         catch (DBus.Error e)
 300         {
 301             logger.trace("bus_acquired_cb");
 302             try {
 303                 conn.register_object ("/org/janet/moonshot", ipc_server);
 304             }
 305             catch (Error e)
 306             {
 307                 stderr.printf ("%s\n", e.message);
 308                 logger.error("bus_acquired_cb: Caught error: " + e.message);
 309             }
 310         }
 311     }
 312 #else
 313     private void bus_acquired_cb(DBusConnection conn) {
 314         logger.trace("bus_acquired_cb");
 315         try {
 316             conn.register_object("/org/janet/moonshot", ipc_server);
 317         }
 318         catch (Error e)
 319         {
 320             this.ipc_server = new MoonshotServer (this);
 321             logger.trace("init_ipc_server: Constructed new MoonshotServer");
 322             GLib.Bus.own_name (GLib.BusType.SESSION,
 323                                "org.janet.Moonshot",
 324                                GLib.BusNameOwnerFlags.NONE,
 325                                bus_acquired_cb,
 326                                (conn, name) => {logger.trace("init_ipc_server: name_acquired_closure");},
 327                                (conn, name) => {
 328                                    logger.trace("init_ipc_server: name_lost_closure");
 329                                    bool shown=false;
 330                                    try {
 331                                        IIdentityManager manager = Bus.get_proxy_sync (BusType.SESSION, name, "/org/janet/moonshot");
 332                                        shown = manager.show_ui();
 333                                    } catch (IOError e) {
 334                                        logger.error("init_ipc_server.name_lost_closure: Caught error: ");
 335                                    }
 336                                    if (!shown) {
 337                                        logger.error("init_ipc_server.name_lost_closure: Couldn't own name %s on dbus or show previously launched identity manager".printf(name));
 338                                        GLib.error ("Couldn't own name %s on dbus or show previously launched identity manager.", name);
 339                                    } else {
 340                                        logger.trace("init_ipc_server.name_lost_closure: Showed previously launched identity manager.");
 341                                        stdout.printf("Showed previously launched identity manager.\n");
 342                                        GLib.Process.exit(0);
 343                                    }
 344                                });
 345         }
 346     }
 347
 348     private void init_ipc_server() {
 349         this.ipc_server = new MoonshotServer(this);
 350         bool shown = false;
 351         GLib.Bus.own_name(GLib.BusType.SESSION,
 352                           "org.janet.Moonshot",
 353                           GLib.BusNameOwnerFlags.NONE,
 354                           bus_acquired_cb,
 355
 356                           // Name acquired callback:
 357                           (conn, name) => {
 358                               logger.trace(@"init_ipc_server: name_acquired_closure; show_requested=$show_requested");
 359
 360                               name_is_owned = true;
 361
 362                               // Now that we know that we own the name, it's safe to show the UI.
 363                               if (show_requested) {
 364                                   show();
 365                                   show_requested = false;
 366                               }
 367                               shown = true;
 368                           },
 369
 370                           // Name lost callback:
 371                           (conn, name) => {
 372                               logger.trace("init_ipc_server: name_lost_closure");
 373
 374                               // This callback usually means that another moonshot is already running.
 375                               // But it *might* mean that we lost the name for some other reason
 376                               // (though it's unclear to me yet what those reasons are.)
 377                               // Clearing these flags seems like a good idea for that case. -- dbreslau
 378                               name_is_owned = false;
 379                               show_requested = false;
 380
 381                               try {
 382                                   if (!shown) {
 383                                       IIdentityManager manager = Bus.get_proxy_sync(BusType.SESSION, name, "/org/janet/moonshot");
 384                                       shown = manager.show_ui();
 385                                   }
 386                               } catch (IOError e) {
 387                                   logger.error("init_ipc_server.name_lost_closure: Caught IOError: " + e.message);
 388                               }
 389                               if (!shown) {
 390                                   logger.error("init_ipc_server.name_lost_closure: Couldn't own name %s on dbus or show previously launched identity manager".printf(name));
 391                                   GLib.error("Couldn't own name %s on dbus or show previously launched identity manager.", name);
 392                               } else {
 393                                   logger.trace("init_ipc_server.name_lost_closure: Showed previously launched identity manager.");
 394                                   stdout.printf("Showed previously launched identity manager.\n");
 395                                   GLib.Process.exit(0);
 396                               }
 397                           });
 398     }
 399 #endif
 400 }
 401
 402 static bool explicitly_launched = true;
 403 static bool use_flat_file_store = false;
 404 const GLib.OptionEntry[] options = {
 405     {"dbus-launched", 0, GLib.OptionFlags.REVERSE, GLib.OptionArg.NONE,
 406      ref explicitly_launched, "launch for dbus rpc use", null},
 407     {"flat-file-store", 0, 0, GLib.OptionArg.NONE,
 408      ref use_flat_file_store, "force use of flat file identity store (used by default only for headless operation)", null},
 409     {null}
 410 };
 411
 412
 413 public static int main(string[] args) {
 414
 415 #if LOG4VALA
 416     new IdentityManagerApp.dummy();
 417 #endif
 418
 419 #if IPC_MSRPC
 420     bool headless = false;
 421 #else
 422     bool headless = GLib.Environment.get_variable("DISPLAY") == null;
 423 #endif
 424
 425     if (headless) {
 426         try {
 427             var opt_context = new OptionContext(null);
 428             opt_context.set_help_enabled(true);
 429             opt_context.add_main_entries(options, null);
 430             opt_context.parse(ref args);
 431         } catch (OptionError e) {
 432             stdout.printf(_("error: %s\n"),e.message);
 433             stdout.printf(_("Run '%s --help' to see a full list of available options\n"), args[0]);
 434             return -1;
 435         }
 436         explicitly_launched = false;
 437     } else {
 438         try {
 439             if (!Gtk.init_with_args(ref args, _(""), options, null)) {
 440                 stdout.printf(_("unable to initialize window\n"));
 441                 return -1;
 442             }
 443         } catch (GLib.Error e) {
 444             stdout.printf(_("error: %s\n"),e.message);
 445             stdout.printf(_("Run '%s --help' to see a full list of available options\n"), args[0]);
 446             return -1;
 447         }
 448         gtk_available = true;
 449     }
 450
 451 #if OS_WIN32
 452     // Force specific theme settings on Windows without requiring a gtkrc file
 453     Gtk.Settings settings = Gtk.Settings.get_default();
 454     settings.set_string_property("gtk-theme-name", "ms-windows", "moonshot");
 455     settings.set_long_property("gtk-menu-images", 0, "moonshot");
 456 #endif
 457
 458     Intl.bindtextdomain(Config.GETTEXT_PACKAGE, Config.LOCALEDIR);
 459     Intl.bind_textdomain_codeset(Config.GETTEXT_PACKAGE, "UTF-8");
 460     Intl.textdomain(Config.GETTEXT_PACKAGE);
 461
 462
 463     var app = new IdentityManagerApp(headless, use_flat_file_store);
 464     app.explicitly_launched = explicitly_launched;
 465     IdentityManagerApp.logger.trace(@"main: explicitly_launched=$explicitly_launched");
 466
 467     if (app.explicitly_launched) {
 468         app.show();
 469     }
 470
 471     if (headless) {
 472 #if !IPC_MSRPC
 473         MainLoop loop = new MainLoop();
 474         loop.run();
 475 #endif
 476     }
 477     else {
 478         Gtk.main();
 479     }
 480
 481     return 0;
 482 }
 483