src/moonshot-identity-request.vala

   1 /*
   2  * Copyright (c) 2011-2014, JANET(UK)
   3  * All rights reserved.
   4  *
   5  * Redistribution and use in source and binary forms, with or without
   6  * modification, are permitted provided that the following conditions
   7  * are met:
   8  *
   9  * 1. Redistributions of source code must retain the above copyright
  10  *    notice, this list of conditions and the following disclaimer.
  11  *
  12  * 2. Redistributions in binary form must reproduce the above copyright
  13  *    notice, this list of conditions and the following disclaimer in the
  14  *    documentation and/or other materials provided with the distribution.
  15  *
  16  * 3. Neither the name of JANET(UK) nor the names of its contributors
  17  *    may be used to endorse or promote products derived from this software
  18  *    without specific prior written permission.
  19  *
  20  * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS"
  21  * AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  22  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  23  * ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDER OR CONTRIBUTORS BE LIABLE
  24  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  25  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  26  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  27  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  28  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  29  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  30  * SUCH DAMAGE.
  31 */
  32 public delegate void ReturnIdentityCallback (IdentityRequest request);
  33
  34 public class IdentityRequest : Object {
  35     public IdCard? id_card = null;
  36     public bool complete = false;
  37     public bool select_default = false;
  38
  39     private IdentityManagerApp parent_app;
  40     public string nai;
  41     public string password;
  42     public string service;
  43     public SList<IdCard> candidates;
  44
  45     ReturnIdentityCallback callback = null;
  46
  47     public IdentityRequest (IdentityManagerApp           app,
  48                             string                       nai,
  49                             string                       password,
  50                             string                       service)
  51     {
  52         this.parent_app = app;
  53         this.nai = nai;
  54         this.password = password;
  55         this.service = service;
  56     }
  57
  58     public IdentityRequest.default (IdentityManagerApp app)
  59     {
  60         this.parent_app = app;
  61         this.select_default = true;
  62     }
  63
  64     public void set_callback (owned ReturnIdentityCallback cb)
  65     {
  66 #if VALA_0_12
  67         this.callback = ((owned) cb);
  68 #else
  69         this.callback = ((IdCard) => cb (IdCard));
  70 #endif
  71     }
  72
  73     public bool execute () {
  74         parent_app.select_identity (this);
  75
  76         /* This function works as a GSourceFunc, so it can be passed to
  77          * the main loop from other threads
  78          */
  79         return false;
  80     }
  81
  82     public void return_identity (IdCard? id_card) {
  83         this.id_card = id_card;
  84         this.complete = true;
  85
  86         /* update id_card service list */
  87         if (id_card != null && this.service != null && this.service != "")
  88         {
  89             bool duplicate_service = false;
  90
  91             foreach (string service in id_card.services)
  92             {
  93                 if (service == this.service)
  94                     duplicate_service = true;
  95             }
  96             if (duplicate_service == false)
  97             {
  98                 string[] services = new string[id_card.services.length + 1];
  99
 100                 for (int i = 0; i < id_card.services.length; i++)
 101                     services[i] = id_card.services[i];
 102
 103                 services[id_card.services.length] = this.service;
 104                 id_card.services = services;
 105
 106                 this.id_card = this.parent_app.model.update_card (id_card);
 107             }
 108         }
 109
 110         return_if_fail (callback != null);
 111         callback (this);
 112     }
 113
 114 #if OS_WIN32
 115     /* For synchronisation between RPC thread and main loop. Because
 116      * these objects are not refcounted, it's best to tie them to the
 117      * lifecycle of the IdentityRequest object.
 118      */
 119     public Mutex mutex;
 120     public Cond cond;
 121 #endif
 122 }