src/moonshot-local-flat-file-store.vala

   1 using Gee;
   2
   3 public class LocalFlatFileStore : Object, IIdentityCardStore {
   4     private LinkedList<IdCard> id_card_list;
   5     private const string FILE_NAME = "identities.txt";
   6
   7     public void add_card(IdCard card) {
   8         id_card_list.add(card);
   9         store_id_cards ();
  10     }
  11
  12     public IdCard? update_card(IdCard card) {
  13         id_card_list.remove(card);
  14         id_card_list.add(card);
  15         store_id_cards ();
  16         foreach(IdCard idcard in id_card_list)
  17             if (idcard.display_name == card.display_name)
  18                 return idcard;
  19         return null;
  20     }
  21
  22     public void remove_card(IdCard card) {
  23         id_card_list.remove(card);
  24         store_id_cards ();
  25     }
  26
  27     public LinkedList<IdCard> get_card_list() {
  28         return id_card_list;
  29     }
  30
  31     public IIdentityCardStore.StoreType get_store_type() {
  32         return IIdentityCardStore.StoreType.FLAT_FILE;
  33     }
  34
  35     private void load_id_cards() {
  36         id_card_list.clear();
  37         var key_file = new KeyFile ();
  38         var path = get_data_dir ();
  39         var filename = Path.build_filename (path, FILE_NAME);
  40
  41         try {
  42             key_file.load_from_file (filename, KeyFileFlags.NONE);
  43         }
  44         catch (Error e) {
  45             stdout.printf("Error: %s\n", e.message);
  46             return;
  47         }
  48
  49         var identities_uris = key_file.get_groups ();
  50         foreach (string identity in identities_uris) {
  51             try {
  52                 IdCard id_card = new IdCard ();
  53
  54                 id_card.issuer = key_file.get_string (identity, "Issuer");
  55                 id_card.username = key_file.get_string (identity, "Username");
  56                 id_card.password = key_file.get_string (identity, "Password");
  57                 id_card.services = key_file.get_string_list (identity, "Services");
  58                 id_card.display_name = key_file.get_string (identity, "DisplayName");
  59                 if (key_file.has_key (identity, "StorePassword")) {
  60                     id_card.store_password = (key_file.get_string (identity, "StorePassword") == "yes");
  61                 } else {
  62                     id_card.store_password = (id_card.password != null) && (id_card.password != "");
  63                 }
  64
  65                 if (key_file.has_key (identity, "Rules-Patterns") &&
  66                     key_file.has_key (identity, "Rules-AlwaysConfirm")) {
  67                     string [] rules_patterns =    key_file.get_string_list (identity, "Rules-Patterns");
  68                     string [] rules_always_conf = key_file.get_string_list (identity, "Rules-AlwaysConfirm");
  69
  70                     if (rules_patterns.length == rules_always_conf.length) {
  71                       Rule[] rules = new Rule[rules_patterns.length];
  72                       for (int i = 0; i < rules_patterns.length; i++) {
  73                         rules[i] = {rules_patterns[i], rules_always_conf[i]};
  74                       }
  75                       id_card.rules = rules;
  76                     }
  77                 }
  78
  79                 // Trust anchor
  80                 id_card.trust_anchor.ca_cert = key_file.get_string (identity, "CA-Cert");
  81                 id_card.trust_anchor.subject = key_file.get_string (identity, "Subject");
  82                 id_card.trust_anchor.subject_alt = key_file.get_string (identity, "SubjectAlt");
  83                 id_card.trust_anchor.server_cert = key_file.get_string (identity, "ServerCert");
  84
  85                 id_card_list.add (id_card);
  86             }
  87             catch (Error e) {
  88                 stdout.printf ("Error:  %s\n", e.message);
  89             }
  90         }
  91     }
  92
  93     private string get_data_dir() {
  94         string path;
  95         path = Path.build_filename (Environment.get_user_data_dir (),
  96                                     Config.PACKAGE_TARNAME);
  97
  98         if (!FileUtils.test (path, FileTest.EXISTS)) {
  99             DirUtils.create_with_parents (path, 0700);
 100         }
 101         return path;
 102     }
 103
 104     public void store_id_cards () {
 105         var key_file = new KeyFile ();
 106         foreach (IdCard id_card in this.id_card_list) {
 107             string[] rules_patterns = new string[id_card.rules.length];
 108             string[] rules_always_conf = new string[id_card.rules.length];
 109
 110             for (int i=0; i<id_card.rules.length; i++) {
 111               rules_patterns[i] = id_card.rules[i].pattern;
 112               rules_always_conf[i] = id_card.rules[i].always_confirm;
 113             }
 114
 115             key_file.set_string (id_card.display_name, "Issuer", id_card.issuer ?? "");
 116             key_file.set_string (id_card.display_name, "DisplayName", id_card.display_name ?? "");
 117             key_file.set_string (id_card.display_name, "Username", id_card.username ?? "");
 118             if (id_card.store_password && (id_card.password != null))
 119               key_file.set_string (id_card.display_name, "Password", id_card.password);
 120             else
 121               key_file.set_string (id_card.display_name, "Password", "");
 122             key_file.set_string_list (id_card.display_name, "Services", id_card.services ?? {});
 123
 124             if (id_card.rules.length > 0) {
 125               key_file.set_string_list (id_card.display_name, "Rules-Patterns", rules_patterns);
 126               key_file.set_string_list (id_card.display_name, "Rules-AlwaysConfirm", rules_always_conf);
 127             }
 128             key_file.set_string (id_card.display_name, "StorePassword", id_card.store_password ? "yes" : "no");
 129
 130             // Trust anchor
 131             key_file.set_string (id_card.display_name, "CA-Cert", id_card.trust_anchor.ca_cert ?? "");
 132             key_file.set_string (id_card.display_name, "Subject", id_card.trust_anchor.subject ?? "");
 133             key_file.set_string (id_card.display_name, "SubjectAlt", id_card.trust_anchor.subject_alt ?? "");
 134             key_file.set_string (id_card.display_name, "ServerCert", id_card.trust_anchor.server_cert ?? "");
 135         }
 136
 137         var text = key_file.to_data (null);
 138
 139         try {
 140             var path = get_data_dir ();
 141             var filename = Path.build_filename (path, FILE_NAME);
 142             FileUtils.set_contents (filename, text, -1);
 143         }
 144         catch (Error e) {
 145             stdout.printf ("Error:  %s\n", e.message);
 146         }
 147
 148         load_id_cards();
 149     }
 150
 151      public LocalFlatFileStore () {
 152         id_card_list = new LinkedList<IdCard>();
 153         load_id_cards();
 154      }
 155  }
 156