src/moonshot-local-flat-file-store.vala

   1 using Gee;
   2
   3 public class LocalFlatFileStore : Object, IIdentityCardStore {
   4     private LinkedList<IdCard> id_card_list;
   5     private const string FILE_NAME = "identities.txt";
   6
   7     public void add_card(IdCard card) {
   8         id_card_list.add(card);
   9         store_id_cards ();
  10     }
  11
  12     public IdCard? update_card(IdCard card) {
  13         id_card_list.remove(card);
  14         id_card_list.add(card);
  15         store_id_cards ();
  16         foreach(IdCard idcard in id_card_list)
  17             if (idcard.display_name == card.display_name)
  18                 return idcard;
  19         return null;
  20     }
  21
  22     public bool remove_card(IdCard card) {
  23         if (id_card_list.remove(card)) {
  24             store_id_cards ();
  25             return true;
  26         }
  27         return false;
  28     }
  29
  30     public LinkedList<IdCard> get_card_list() {
  31         return id_card_list;
  32     }
  33
  34     public IIdentityCardStore.StoreType get_store_type() {
  35         return IIdentityCardStore.StoreType.FLAT_FILE;
  36     }
  37
  38     private void load_id_cards() {
  39         id_card_list.clear();
  40         var key_file = new KeyFile ();
  41         var path = get_data_dir ();
  42         var filename = Path.build_filename (path, FILE_NAME);
  43
  44         try {
  45             key_file.load_from_file (filename, KeyFileFlags.NONE);
  46         }
  47         catch (Error e) {
  48             stdout.printf("Error: %s\n", e.message);
  49             return;
  50         }
  51
  52         var identities_uris = key_file.get_groups ();
  53         foreach (string identity in identities_uris) {
  54             try {
  55                 IdCard id_card = new IdCard ();
  56
  57                 id_card.issuer = key_file.get_string (identity, "Issuer");
  58                 id_card.username = key_file.get_string (identity, "Username");
  59                 id_card.password = key_file.get_string (identity, "Password");
  60                 id_card.services = key_file.get_string_list (identity, "Services");
  61                 id_card.display_name = key_file.get_string (identity, "DisplayName");
  62                 if (key_file.has_key (identity, "StorePassword")) {
  63                     id_card.store_password = (key_file.get_string (identity, "StorePassword") == "yes");
  64                 } else {
  65                     id_card.store_password = (id_card.password != null) && (id_card.password != "");
  66                 }
  67
  68                 if (key_file.has_key (identity, "Rules-Patterns") &&
  69                     key_file.has_key (identity, "Rules-AlwaysConfirm")) {
  70                     string [] rules_patterns =    key_file.get_string_list (identity, "Rules-Patterns");
  71                     string [] rules_always_conf = key_file.get_string_list (identity, "Rules-AlwaysConfirm");
  72
  73                     if (rules_patterns.length == rules_always_conf.length) {
  74                       Rule[] rules = new Rule[rules_patterns.length];
  75                       for (int i = 0; i < rules_patterns.length; i++) {
  76                         rules[i] = {rules_patterns[i], rules_always_conf[i]};
  77                       }
  78                       id_card.rules = rules;
  79                     }
  80                 }
  81
  82                 // Trust anchor
  83                 id_card.trust_anchor.ca_cert = key_file.get_string (identity, "CA-Cert");
  84                 id_card.trust_anchor.subject = key_file.get_string (identity, "Subject");
  85                 id_card.trust_anchor.subject_alt = key_file.get_string (identity, "SubjectAlt");
  86                 id_card.trust_anchor.server_cert = key_file.get_string (identity, "ServerCert");
  87
  88                 id_card_list.add (id_card);
  89             }
  90             catch (Error e) {
  91                 stdout.printf ("Error:  %s\n", e.message);
  92             }
  93         }
  94     }
  95
  96     private string get_data_dir() {
  97         string path;
  98         path = Path.build_filename (Environment.get_user_data_dir (),
  99                                     Config.PACKAGE_TARNAME);
 100
 101         if (!FileUtils.test (path, FileTest.EXISTS)) {
 102             DirUtils.create_with_parents (path, 0700);
 103         }
 104         return path;
 105     }
 106
 107     public void store_id_cards () {
 108         var key_file = new KeyFile ();
 109         foreach (IdCard id_card in this.id_card_list) {
 110             /* workaround for Centos vala array property bug: use temp arrays */
 111             var rules = id_card.rules;
 112             var services = id_card.services;
 113             string[] rules_patterns = new string[rules.length];
 114             string[] rules_always_conf = new string[rules.length];
 115
 116             for (int i=0; i<rules.length; i++) {
 117               rules_patterns[i] = rules[i].pattern;
 118               rules_always_conf[i] = rules[i].always_confirm;
 119             }
 120
 121             key_file.set_string (id_card.display_name, "Issuer", id_card.issuer ?? "");
 122             key_file.set_string (id_card.display_name, "DisplayName", id_card.display_name ?? "");
 123             key_file.set_string (id_card.display_name, "Username", id_card.username ?? "");
 124             if (id_card.store_password && (id_card.password != null))
 125               key_file.set_string (id_card.display_name, "Password", id_card.password);
 126             else
 127               key_file.set_string (id_card.display_name, "Password", "");
 128             key_file.set_string_list (id_card.display_name, "Services", services ?? {});
 129
 130             if (rules.length > 0) {
 131               key_file.set_string_list (id_card.display_name, "Rules-Patterns", rules_patterns);
 132               key_file.set_string_list (id_card.display_name, "Rules-AlwaysConfirm", rules_always_conf);
 133             }
 134             key_file.set_string (id_card.display_name, "StorePassword", id_card.store_password ? "yes" : "no");
 135
 136             // Trust anchor
 137             key_file.set_string (id_card.display_name, "CA-Cert", id_card.trust_anchor.ca_cert ?? "");
 138             key_file.set_string (id_card.display_name, "Subject", id_card.trust_anchor.subject ?? "");
 139             key_file.set_string (id_card.display_name, "SubjectAlt", id_card.trust_anchor.subject_alt ?? "");
 140             key_file.set_string (id_card.display_name, "ServerCert", id_card.trust_anchor.server_cert ?? "");
 141         }
 142
 143         var text = key_file.to_data (null);
 144
 145         try {
 146             var path = get_data_dir ();
 147             var filename = Path.build_filename (path, FILE_NAME);
 148             var file  = File.new_for_path(filename);
 149             var stream = file.replace(null, false, FileCreateFlags.PRIVATE);
 150 #if IPC_DBUS_GLIB
 151             var bits = text.data;
 152             stream.write(&bits[0], bits.length);
 153 #else
 154             stream.write(text.data);
 155 #endif
 156         }
 157         catch (Error e) {
 158             stdout.printf ("Error:  %s\n", e.message);
 159         }
 160
 161         load_id_cards();
 162     }
 163
 164      public LocalFlatFileStore () {
 165         id_card_list = new LinkedList<IdCard>();
 166         load_id_cards();
 167      }
 168  }
 169