src/moonshot-local-flat-file-store.vala

   1 /*
   2  * Copyright (c) 2011-2014, JANET(UK)
   3  * All rights reserved.
   4  *
   5  * Redistribution and use in source and binary forms, with or without
   6  * modification, are permitted provided that the following conditions
   7  * are met:
   8  *
   9  * 1. Redistributions of source code must retain the above copyright
  10  *    notice, this list of conditions and the following disclaimer.
  11  *
  12  * 2. Redistributions in binary form must reproduce the above copyright
  13  *    notice, this list of conditions and the following disclaimer in the
  14  *    documentation and/or other materials provided with the distribution.
  15  *
  16  * 3. Neither the name of JANET(UK) nor the names of its contributors
  17  *    may be used to endorse or promote products derived from this software
  18  *    without specific prior written permission.
  19  *
  20  * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS"
  21  * AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  22  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  23  * ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDER OR CONTRIBUTORS BE LIABLE
  24  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  25  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  26  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  27  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  28  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  29  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  30  * SUCH DAMAGE.
  31  */
  32 using Gee;
  33
  34 public class LocalFlatFileStore : Object, IIdentityCardStore {
  35     private LinkedList<IdCard> id_card_list;
  36     private const string FILE_NAME = "identities.txt";
  37
  38     public void add_card(IdCard card) {
  39         id_card_list.add(card);
  40         store_id_cards();
  41     }
  42
  43     public IdCard? update_card(IdCard card) {
  44         id_card_list.remove(card);
  45         id_card_list.add(card);
  46         store_id_cards();
  47         foreach(IdCard idcard in id_card_list)
  48         if (idcard.display_name == card.display_name)
  49             return idcard;
  50         return null;
  51     }
  52
  53     public bool remove_card(IdCard card) {
  54         if (id_card_list.remove(card)) {
  55             store_id_cards();
  56             return true;
  57         }
  58         return false;
  59     }
  60
  61     public LinkedList<IdCard> get_card_list() {
  62         return id_card_list;
  63     }
  64
  65     public IIdentityCardStore.StoreType get_store_type() {
  66         return IIdentityCardStore.StoreType.FLAT_FILE;
  67     }
  68
  69     private void load_id_cards() {
  70         id_card_list.clear();
  71         var key_file = new KeyFile();
  72         var path = get_data_dir();
  73         var filename = Path.build_filename(path, FILE_NAME);
  74
  75         try {
  76             key_file.load_from_file(filename, KeyFileFlags.NONE);
  77         }
  78         catch (Error e) {
  79             stdout.printf("Error: %s\n", e.message);
  80             return;
  81         }
  82
  83         var identities_uris = key_file.get_groups();
  84         foreach (string identity in identities_uris) {
  85             try {
  86                 IdCard id_card = new IdCard();
  87
  88                 id_card.issuer = key_file.get_string(identity, "Issuer");
  89                 id_card.username = key_file.get_string(identity, "Username");
  90                 id_card.password = key_file.get_string(identity, "Password");
  91                 id_card.update_services(key_file.get_string_list(identity, "Services"));
  92                 id_card.display_name = key_file.get_string(identity, "DisplayName");
  93                 if (key_file.has_key(identity, "StorePassword")) {
  94                     id_card.store_password = (key_file.get_string(identity, "StorePassword") == "yes");
  95                 } else {
  96                     id_card.store_password = (id_card.password != null) && (id_card.password != "");
  97                 }
  98
  99                 if (key_file.has_key(identity, "Rules-Patterns") &&
 100                     key_file.has_key(identity, "Rules-AlwaysConfirm")) {
 101                     string [] rules_patterns =    key_file.get_string_list(identity, "Rules-Patterns");
 102                     string [] rules_always_conf = key_file.get_string_list(identity, "Rules-AlwaysConfirm");
 103
 104                     if (rules_patterns.length == rules_always_conf.length) {
 105                         Rule[] rules = new Rule[rules_patterns.length];
 106                         for (int i = 0; i < rules_patterns.length; i++) {
 107                             rules[i] = {rules_patterns[i], rules_always_conf[i]};
 108                         }
 109                         id_card.rules = rules;
 110                     }
 111                 }
 112
 113                 // Trust anchor
 114                 string ca_cert = key_file.get_string(identity, "CA-Cert").strip();
 115                 string server_cert = key_file.get_string(identity, "ServerCert");
 116                 string subject = key_file.get_string(identity, "Subject");
 117                 string subject_alt = key_file.get_string(identity, "SubjectAlt");
 118                 bool  user_verified = key_file.get_boolean(identity, "CACert_User_Verified");
 119                 var ta = new TrustAnchor(ca_cert, server_cert, subject, subject_alt, user_verified);
 120                 id_card.set_trust_anchor_from_store(ta);
 121                 id_card_list.add(id_card);
 122             }
 123             catch (Error e) {
 124                 stdout.printf("Error:  %s\n", e.message);
 125             }
 126         }
 127     }
 128
 129     private string get_data_dir() {
 130         string path;
 131         path = Path.build_filename(Environment.get_user_data_dir(),
 132                                    Config.PACKAGE_TARNAME);
 133
 134         if (!FileUtils.test(path, FileTest.EXISTS)) {
 135             DirUtils.create_with_parents(path, 0700);
 136         }
 137         return path;
 138     }
 139
 140     public void store_id_cards() {
 141         var key_file = new KeyFile();
 142         foreach (IdCard id_card in this.id_card_list) {
 143             /* workaround for Centos vala array property bug: use temp arrays */
 144             var rules = id_card.rules;
 145             string[] empty = {};
 146             string[] rules_patterns = new string[rules.length];
 147             string[] rules_always_conf = new string[rules.length];
 148
 149             for (int i = 0; i < rules.length; i++) {
 150                 rules_patterns[i] = rules[i].pattern;
 151                 rules_always_conf[i] = rules[i].always_confirm;
 152             }
 153
 154             key_file.set_string(id_card.display_name, "Issuer", id_card.issuer ?? "");
 155             key_file.set_string(id_card.display_name, "DisplayName", id_card.display_name ?? "");
 156             key_file.set_string(id_card.display_name, "Username", id_card.username ?? "");
 157             if (id_card.store_password && (id_card.password != null))
 158                 key_file.set_string(id_card.display_name, "Password", id_card.password);
 159             else
 160                 key_file.set_string(id_card.display_name, "Password", "");
 161
 162             // Using id_card.services.to_array() seems to cause a crash, possibly due to
 163             // an unowned reference to the array.
 164             string[] svcs = new string[id_card.services.size];
 165             for (int i = 0; i < id_card.services.size; i++) {
 166                 svcs[i] = id_card.services[i];
 167             }
 168
 169             key_file.set_string_list(id_card.display_name, "Services", svcs);
 170
 171             if (rules.length > 0) {
 172                 key_file.set_string_list(id_card.display_name, "Rules-Patterns", rules_patterns);
 173                 key_file.set_string_list(id_card.display_name, "Rules-AlwaysConfirm", rules_always_conf);
 174             }
 175             key_file.set_string(id_card.display_name, "StorePassword", id_card.store_password ? "yes" : "no");
 176
 177             // Trust anchor
 178             key_file.set_string(id_card.display_name, "CA-Cert", id_card.trust_anchor.ca_cert ?? "");
 179             key_file.set_string(id_card.display_name, "Subject", id_card.trust_anchor.subject ?? "");
 180             key_file.set_string(id_card.display_name, "SubjectAlt", id_card.trust_anchor.subject_alt ?? "");
 181             key_file.set_string(id_card.display_name, "ServerCert", id_card.trust_anchor.server_cert ?? "");
 182             key_file.set_boolean(id_card.display_name, "CACert_User_Verified", id_card.trust_anchor.user_verified);
 183         }
 184
 185         var text = key_file.to_data(null);
 186
 187         try {
 188             var path = get_data_dir();
 189             var filename = Path.build_filename(path, FILE_NAME);
 190             var file  = File.new_for_path(filename);
 191             var stream = file.replace(null, false, FileCreateFlags.PRIVATE);
 192             #if GIO_VAPI_USES_ARRAYS
 193             stream.write(text.data);
 194             #else
 195             var bits = text.data;
 196             stream.write(&bits[0], bits.length);
 197             #endif
 198                 }
 199         catch (Error e) {
 200             stdout.printf("Error:  %s\n", e.message);
 201         }
 202
 203         load_id_cards();
 204     }
 205
 206     public LocalFlatFileStore() {
 207         id_card_list = new LinkedList<IdCard>();
 208         load_id_cards();
 209     }
 210 }
 211