src/moonshot-password-dialog.vala

   1 using Gtk;
   2
   3 class AddPasswordDialog : Dialog
   4 {
   5     private Entry password_entry;
   6     private CheckButton remember_checkbutton;
   7
   8     public string password {
   9         get { return password_entry.get_text (); }
  10     }
  11
  12     public bool remember {
  13         get { return remember_checkbutton.get_active (); }
  14     }
  15
  16     public AddPasswordDialog (IdCard id_card, IdentityRequest? request)
  17     {
  18         this.set_title (_("Please enter password for ") + id_card.display_name);
  19         this.set_modal (true);
  20
  21         if (request != null) {
  22             this.add_buttons (_("Send"), ResponseType.OK,
  23                               _("Return to application"), ResponseType.CANCEL);
  24         } else {
  25             this.add_buttons (_("Done"), ResponseType.OK,
  26                               _("Cancel"), ResponseType.CANCEL);
  27         }
  28         this.set_default_response (ResponseType.OK);
  29
  30         var content_area = this.get_content_area ();
  31         ((Box) content_area).set_spacing (12);
  32         Label service_label = null;
  33         Label service_value = null;
  34         if (request != null) {
  35             service_label = new Label (_("for use with:"));
  36             service_label.set_alignment (1, (float) 0.5);
  37             service_value = new Label (request.service);
  38             service_value.set_alignment (0, (float) 0.5);
  39         }
  40
  41         var nai_label = new Label (_("Network Access Identifier:"));
  42         nai_label.set_alignment (1, (float) 0.5);
  43         var nai_value = new Label (id_card.nai);
  44         nai_value.set_alignment (0, (float) 0.5);
  45
  46         var password_label = new Label (_("Password:"));
  47         password_label.set_alignment (1, (float) 0.5);
  48         this.password_entry = new Entry ();
  49         password_entry.set_invisible_char ('*');
  50         password_entry.set_visibility (false);
  51         password_entry.activates_default = true;
  52         remember_checkbutton = new CheckButton.with_label (_("Remember password"));
  53
  54         set_atk_relation (password_entry, password_entry, Atk.RelationType.LABEL_FOR);
  55
  56         var table = new Table (4, 2, false);
  57         int row = 0;
  58         table.set_col_spacings (10);
  59         table.set_row_spacings (10);
  60         if (request != null) {
  61             table.attach_defaults (service_label, 0, 1, row, row + 1);
  62             table.attach_defaults (service_value, 1, 2, row, row + 1);
  63             row++;
  64         }
  65         table.attach_defaults (nai_label, 0, 1, row, row+1);
  66         table.attach_defaults (nai_value, 1, 2, row, row+1);
  67         row++;
  68         table.attach_defaults (password_label, 0, 1, row, row+1);
  69         table.attach_defaults (password_entry, 1, 2, row, row+1);
  70         row++;
  71         table.attach_defaults (remember_checkbutton,  1, 2, row, row+1);
  72
  73         var vbox = new VBox (false, 0);
  74         vbox.set_border_width (6);
  75         vbox.pack_start (table, false, false, 0);
  76
  77         ((Container) content_area).add (vbox);
  78
  79         this.set_border_width (6);
  80         //this.set_resizable (false);
  81         this.show_all ();
  82     }
  83
  84     private void set_atk_relation (Widget widget, Widget target_widget, Atk.RelationType relationship)
  85     {
  86         var atk_widget = widget.get_accessible ();
  87         var atk_target_widget = target_widget.get_accessible ();
  88
  89         atk_widget.add_relationship (relationship, atk_target_widget);
  90     }
  91 }