configure.ac

   1 AC_PREREQ([2.50])
   2 AC_INIT([opensaml],[2.5],[https://issues.shibboleth.net/],[opensaml])
   3 AC_CONFIG_SRCDIR(saml)
   4 AC_CONFIG_AUX_DIR(build-aux)
   5 AC_CONFIG_MACRO_DIR(m4)
   6 AM_INIT_AUTOMAKE
   7 AC_DISABLE_STATIC
   8 AC_PROG_LIBTOOL
   9
  10 # Docygen features
  11 DX_HTML_FEATURE(ON)
  12 DX_CHM_FEATURE(OFF)
  13 DX_CHI_FEATURE(OFF)
  14 DX_MAN_FEATURE(OFF)
  15 DX_RTF_FEATURE(OFF)
  16 DX_XML_FEATURE(OFF)
  17 DX_PDF_FEATURE(OFF)
  18 DX_PS_FEATURE(OFF)
  19 DX_INIT_DOXYGEN(opensaml, doxygen.cfg, doc/api)
  20 DX_INCLUDE=
  21
  22 AC_ARG_ENABLE(debug,
  23     AS_HELP_STRING([--enable-debug],[Have GCC compile with symbols (Default = no)]),
  24     enable_debug=$enableval, enable_debug=no)
  25
  26 if test "$enable_debug" = "yes" ; then
  27     GCC_CFLAGS="$CFLAGS -Wall -g -D_DEBUG"
  28     GCC_CXXFLAGS="$CXXFLAGS -Wall -g -D_DEBUG"
  29 else
  30     GCC_CFLAGS="$CFLAGS -Wall -O2 -DNDEBUG"
  31     GCC_CXXFLAGS="$CXXFLAGS -Wall -O2 -DNDEBUG"
  32 fi
  33
  34 AC_CONFIG_HEADERS([config.h])
  35 AC_CONFIG_FILES([opensaml.spec])
  36 AC_CONFIG_FILES([Makefile saml/Makefile samltest/Makefile samlsign/Makefile schemas/Makefile doc/Makefile])
  37
  38 AC_PROG_CC([gcc gcc3 cc])
  39 AC_PROG_CXX([g++ g++3 c++ CC])
  40 AC_CANONICAL_HOST
  41
  42 if test "$GCC" = "yes" ; then
  43 #    AC_HAVE_GCC_VERSION(4,0,0,0,
  44 #        [
  45 #        AC_DEFINE(GCC_HASCLASSVISIBILITY,1,
  46 #            [Define to enable class visibility control in gcc.])
  47 #        GCC_CFLAGS="$GCC_CFLAGS -fvisibility=hidden -fvisibility-inlines-hidden"
  48 #        GCC_CXXFLAGS="$GCC_CXXFLAGS -fvisibility=hidden -fvisibility-inlines-hidden"
  49 #        ])
  50     CFLAGS="$GCC_CFLAGS"
  51     CXXFLAGS="$GCC_CXXFLAGS"
  52 else
  53 # Fix for Sun Workshop compiler in debug mode, may be Sun case #6360993
  54         case "${host_cpu}-${host_os}" in
  55                 *solaris*)
  56                         if test "$CXX" = "CC" ; then
  57                                 CXXFLAGS="$CXXFLAGS -Qoption ccfe -stabs=no%dfltlit+no%dflthlp"
  58                         fi
  59                 ;;
  60         esac
  61 fi
  62
  63 # Checks for typedefs, structures, and compiler characteristics.
  64 AC_C_CONST
  65 AC_TYPE_SIZE_T
  66 AC_HEADER_DIRENT
  67
  68 # Checks for library functions.
  69 AC_CHECK_FUNCS([strchr strdup strstr])
  70 AC_CHECK_SIZEOF(time_t)
  71
  72 # checks for pthreads
  73 ACX_PTHREAD([enable_threads="pthread"],[enable_threads="no"])
  74 if test $enable_threads != "pthread"; then
  75     AC_MSG_ERROR([unable to find pthreads, currently this is required])
  76 else
  77     AC_DEFINE(HAVE_PTHREAD,1,[Define if you have POSIX threads libraries and header files.])
  78     LIBS="$PTHREAD_LIBS $LIBS"
  79     CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
  80     CXXFLAGS="$PTHREAD_CFLAGS $CXXFLAGS"
  81 fi
  82
  83 # zlib settings
  84 AC_ARG_WITH(zlib,
  85     AS_HELP_STRING([--with-zlib=PATH],[where zlib is installed]),
  86     [
  87         if test -d "$withval" ; then
  88             CPPFLAGS="${CPPFLAGS} -I$withval/include"
  89             LDFLAGS="${LDFLAGS} -L$withval/lib"
  90         fi
  91     ]
  92 )
  93 AC_CHECK_HEADER([zlib.h],,AC_MSG_ERROR([unable to find zlib header files]))
  94 AC_CHECK_LIB([z],[deflateInit2_],,AC_MSG_ERROR([unable to link with zlib library]))
  95
  96 # OpenSSL settings
  97 AC_ARG_WITH(openssl,
  98     AS_HELP_STRING([--with-openssl=PATH],[where openssl is installed]),
  99     [if test x_$with_openssl != x_/usr; then
 100         SSLFLAGS="-I${with_openssl}/include"
 101     fi])
 102
 103 if test "x$with_openssl" = "x" ; then
 104     AC_PATH_PROG(PKG_CONFIG, pkg-config)
 105     if test "x$PKG_CONFIG" != x && test "x$PKG_CONFIG" != "xno" ; then
 106         if pkg-config openssl ; then
 107             SSLFLAGS="`$PKG_CONFIG --cflags openssl`"
 108         else
 109             AC_MSG_WARN([OpenSSL not supported by pkg-config, try --with-openssl instead])
 110         fi
 111     fi
 112 fi
 113
 114 AC_MSG_CHECKING(for OpenSSL cflags)
 115 AC_MSG_RESULT($SSLFLAGS)
 116 CPPFLAGS="$SSLFLAGS $CPPFLAGS"
 117
 118 AC_CHECK_HEADER([openssl/x509.h],,AC_MSG_ERROR([unable to find openssl header files]))
 119
 120 AC_LANG([C++])
 121
 122 # C++ requirements
 123 AC_CXX_NAMESPACES
 124 AC_CXX_REQUIRE_STL
 125
 126 # log4shib settings (favor this version over the log4cpp code)
 127 AC_PATH_PROG(LOG4SHIB_CONFIG,log4shib-config)
 128 AC_ARG_WITH(log4shib,
 129     AS_HELP_STRING([--with-log4shib=PATH],[where log4shib-config is installed]),
 130     [
 131     LOG4SHIB_CONFIG="${with_log4shib}"
 132     if ! test -f "${LOG4SHIB_CONFIG}"; then
 133         LOG4SHIB_CONFIG="${with_log4shib}/bin/log4shib-config"
 134     fi
 135     ])
 136 if test -f "${LOG4SHIB_CONFIG}" ; then
 137     LIBS="`${LOG4SHIB_CONFIG} --libs` $LIBS"
 138     CPPFLAGS="`${LOG4SHIB_CONFIG} --cflags` $CPPFLAGS"
 139         AC_CHECK_HEADER([log4shib/CategoryStream.hh],,AC_MSG_ERROR([unable to find log4shib header files]))
 140     AC_LINK_IFELSE(
 141         [AC_LANG_PROGRAM([[#include <log4shib/Category.hh>
 142 #include <log4shib/CategoryStream.hh>]],
 143             [[log4shib::Category::getInstance("foo").errorStream() << log4shib::eol]])],
 144         [AC_DEFINE([OPENSAML_LOG4SHIB],[1],[Define to 1 if log4shib library is used.])],
 145         [AC_MSG_ERROR([unable to link with log4shib])])
 146 else
 147     AC_MSG_WARN([log4shib-config not found, may need to use --with-log4shib option])
 148     AC_MSG_WARN([will look for original log4cpp library])
 149
 150     # log4cpp settings
 151     AC_PATH_PROG(LOG4CPP_CONFIG,log4cpp-config)
 152     AC_ARG_WITH(log4cpp,
 153         AS_HELP_STRING([--with-log4cpp=PATH],[where log4cpp-config is installed]),
 154         [
 155         LOG4CPP_CONFIG="${with_log4cpp}"
 156         if ! test -f "${LOG4CPP_CONFIG}"; then
 157                 LOG4CPP_CONFIG="${with_log4cpp}/bin/log4cpp-config"
 158         fi
 159         ])
 160     if test -f "${LOG4CPP_CONFIG}"; then
 161         AC_MSG_WARN([will try to use log4cpp, note that most non-Internet2 supplied versions are not thread-safe])
 162         LIBS="`${LOG4CPP_CONFIG} --libs` $LIBS"
 163         CPPFLAGS="`${LOG4CPP_CONFIG} --cflags` $CPPFLAGS"
 164         AC_CHECK_HEADER([log4cpp/CategoryStream.hh],,AC_MSG_ERROR([unable to find log4cpp header files]))
 165         AC_LINK_IFELSE(
 166             [AC_LANG_PROGRAM([[#include <log4cpp/Category.hh>
 167 #include <log4cpp/CategoryStream.hh>]],
 168                 [[log4cpp::Category::getInstance("foo").errorStream() << log4cpp::eol]])],
 169             [AC_DEFINE([OPENSAML_LOG4CPP],[1],[Define to 1 if log4cpp library is used.])],
 170             [AC_MSG_ERROR([unable to link with log4cpp, need version 1.0 or later])])
 171     else
 172         AC_MSG_ERROR([log4cpp-config not found, may need to use --with-log4cpp option])
 173     fi
 174 fi
 175
 176 # Xerces settings
 177 AC_ARG_WITH(xerces,
 178     AS_HELP_STRING([--with-xerces=PATH],[where xerces-c is installed]),
 179     [if test x_$with_xerces != x_/usr; then
 180         LDFLAGS="-L${with_xerces}/lib $LDFLAGS"
 181         CPPFLAGS="-I${with_xerces}/include $CPPFLAGS"
 182     fi])
 183 LIBS="-lxerces-c $LIBS"
 184 AC_CHECK_HEADER([xercesc/dom/DOM.hpp],,AC_MSG_ERROR([unable to find xerces header files]))
 185 AC_MSG_CHECKING([Xerces version])
 186 AC_PREPROC_IFELSE(
 187     [AC_LANG_PROGRAM([#include <xercesc/util/XercesVersion.hpp>],
 188 [#if  _XERCES_VERSION != 20600
 189 int i = 0;
 190 #else
 191 #error cannot use version 2.6.0
 192 #endif])],
 193     [AC_MSG_RESULT(OK)],
 194     [AC_MSG_FAILURE([Xerces-C v2.6.0 has bugs that inhibit use with signed XML, please use a newer version])])
 195 AC_LINK_IFELSE(
 196     [AC_LANG_PROGRAM([[#include <xercesc/util/PlatformUtils.hpp>]],[[xercesc::XMLPlatformUtils::Initialize()]])],
 197     ,[AC_MSG_ERROR([unable to link with Xerces])])
 198
 199 AC_MSG_CHECKING([whether Xerces XMLString::release(XMLByte**) exists])
 200 AC_COMPILE_IFELSE(
 201     [AC_LANG_PROGRAM([[#include <xercesc/util/XMLString.hpp>]],
 202     [[using namespace XERCES_CPP_NAMESPACE; XMLByte* buf=NULL; XMLString::release(&buf);]])],
 203     [AC_MSG_RESULT([yes])AC_DEFINE([OPENSAML_XERCESC_HAS_XMLBYTE_RELEASE],[1],[Define to 1 if Xerces XMLString includes XMLByte release.])],
 204     [AC_MSG_RESULT([no])])
 205
 206 # XML-Security settings
 207 AC_ARG_WITH(xmlsec,
 208     AS_HELP_STRING([--with-xmlsec=PATH],[where xmlsec is installed]),
 209     [if test x_$with_xmlsec != x_/usr; then
 210         LDFLAGS="-L${with_xmlsec}/lib $LDFLAGS"
 211         CPPFLAGS="-I${with_xmlsec}/include $CPPFLAGS"
 212     fi])
 213 LIBS="-lxml-security-c $LIBS"
 214 AC_CHECK_HEADER([xsec/utils/XSECPlatformUtils.hpp],,AC_MSG_ERROR([unable to find xmlsec header files]))
 215 AC_MSG_CHECKING([XML-Security version])
 216 AC_PREPROC_IFELSE(
 217     [AC_LANG_PROGRAM([#include <xsec/utils/XSECPlatformUtils.hpp>],
 218     [#if XSEC_VERSION_MAJOR > 1 || (XSEC_VERSION_MAJOR == 1 && XSEC_VERSION_MEDIUM > 3)
 219 int i = 0;
 220 #else
 221 #error need version 1.4.0 or later
 222 #endif])],
 223     [AC_MSG_RESULT(OK)],
 224     [AC_MSG_FAILURE([XML-Security version 1.4.0 or greater is required.])])
 225     AC_LINK_IFELSE(
 226         [AC_LANG_PROGRAM([[#include <xsec/utils/XSECPlatformUtils.hpp>]],
 227             [[XSECPlatformUtils::Initialise()]])],,
 228         [AC_MSG_ERROR([unable to link with XML-Security])])
 229
 230 # XML-Tooling settings
 231 AC_ARG_WITH(xmltooling,
 232     AS_HELP_STRING([--with-xmltooling=PATH],[where xmltooling is installed]),
 233     [if test x_$with_xmltooling != x_/usr; then
 234         LDFLAGS="-L${with_xmltooling}/lib $LDFLAGS"
 235         CPPFLAGS="-I${with_xmltooling}/include $CPPFLAGS"
 236         DX_INCLUDE="${with_xmltooling}/include"
 237     fi])
 238 LIBS="-lxmltooling $LIBS"
 239 AC_CHECK_HEADER([xmltooling/XMLToolingConfig.h],,AC_MSG_ERROR([unable to find xmltooling header files]))
 240
 241 AC_LINK_IFELSE(
 242     [AC_LANG_PROGRAM([[#include <xmltooling/XMLToolingConfig.h>
 243 #include <xmltooling/version.h>]],
 244         [[#if _XMLTOOLING_VERSION >= 10400
 245 xmltooling::XMLToolingConfig::getConfig();
 246 #else
 247 #error Need XMLTooling version 1.4 or higher
 248 #endif]])],
 249     ,[AC_MSG_ERROR([unable to link with XMLTooling, or version was too old])])
 250
 251 # Check for unit test support
 252 CXXTEST="/usr/bin/cxxtestgen.pl"
 253 CXXTESTFLAGS=""
 254 AC_ARG_WITH(cxxtest,
 255     AS_HELP_STRING([--with-cxxtest=PATH], [where cxxtest is installed]),
 256     [if test x_$with_cxxtest != x_/usr; then
 257         CXXTEST="${with_cxxtest}/cxxtestgen.pl"
 258         CXXTESTFLAGS="-I${with_cxxtest}"
 259     fi])
 260 if ! test -f "${CXXTEST}"; then
 261     AC_MSG_WARN([cxxtestgen not found, won't build unit tests])
 262 fi
 263
 264 AC_SUBST(CXXTEST)
 265 AC_SUBST(CXXTESTFLAGS)
 266 AM_CONDITIONAL(BUILD_UNITTEST,test -f ${CXXTEST})
 267
 268 AX_CREATE_PKGCONFIG_INFO(,,[$LIBS -lsaml],[OpenSAML library])
 269
 270 AC_SUBST(DX_INCLUDE)
 271 LIBTOOL="$LIBTOOL --silent"
 272
 273 # output packaging and makefiles
 274 AC_OUTPUT