configure.ac

   1 AC_PREREQ([2.50])
   2 AC_INIT([opensaml],[2.5.0],[https://issues.shibboleth.net/],[opensaml])
   3 AC_CONFIG_SRCDIR(saml)
   4 AC_CONFIG_AUX_DIR(build-aux)
   5 AC_CONFIG_MACRO_DIR(m4)
   6 AM_INIT_AUTOMAKE
   7 AC_DISABLE_STATIC
   8 AC_PROG_LIBTOOL
   9
  10 # Docygen features
  11 DX_HTML_FEATURE(ON)
  12 DX_CHM_FEATURE(OFF)
  13 DX_CHI_FEATURE(OFF)
  14 DX_MAN_FEATURE(OFF)
  15 DX_RTF_FEATURE(OFF)
  16 DX_XML_FEATURE(OFF)
  17 DX_PDF_FEATURE(OFF)
  18 DX_PS_FEATURE(OFF)
  19 DX_INIT_DOXYGEN(opensaml, doxygen.cfg, doc/api)
  20 DX_INCLUDE=
  21
  22 AC_ARG_ENABLE(debug,
  23     AS_HELP_STRING([--enable-debug],[Have GCC compile with symbols (Default = no)]),
  24     enable_debug=$enableval, enable_debug=no)
  25
  26 if test "$enable_debug" = "yes" ; then
  27     GCC_CFLAGS="$CFLAGS -Wall -g -D_DEBUG"
  28     GCC_CXXFLAGS="$CXXFLAGS -Wall -g -D_DEBUG"
  29 else
  30     GCC_CFLAGS="$CFLAGS -Wall -O2 -DNDEBUG"
  31     GCC_CXXFLAGS="$CXXFLAGS -Wall -O2 -DNDEBUG"
  32 fi
  33
  34 AC_CONFIG_HEADERS([config.h])
  35 AC_CONFIG_FILES([opensaml.spec])
  36 AC_CONFIG_FILES([Makefile saml/Makefile samltest/Makefile samlsign/Makefile schemas/Makefile doc/Makefile])
  37
  38 AC_PROG_CC([gcc gcc3 cc])
  39 AC_PROG_CXX([g++ g++3 c++ CC])
  40 AC_CANONICAL_HOST
  41
  42 if test "$GCC" = "yes" ; then
  43 #    AC_HAVE_GCC_VERSION(4,0,0,0,
  44 #        [
  45 #        AC_DEFINE(GCC_HASCLASSVISIBILITY,1,
  46 #            [Define to enable class visibility control in gcc.])
  47 #        GCC_CFLAGS="$GCC_CFLAGS -fvisibility=hidden -fvisibility-inlines-hidden"
  48 #        GCC_CXXFLAGS="$GCC_CXXFLAGS -fvisibility=hidden -fvisibility-inlines-hidden"
  49 #        ])
  50     CFLAGS="$GCC_CFLAGS"
  51     CXXFLAGS="$GCC_CXXFLAGS"
  52 fi
  53
  54 # Fix for Sun Workshop compiler in debug mode, may be Sun case #6360993
  55 # Also enables POSIX semantics for some functions.
  56 case "${host_cpu}-${host_os}" in
  57     *solaris*)
  58         CFLAGS="$CFLAGS -D_POSIX_PTHREAD_SEMANTICS"
  59         CXXFLAGS="$CXXFLAGS -D_POSIX_PTHREAD_SEMANTICS"
  60         if test "$CXX" = "CC" ; then
  61                 CXXFLAGS="$CXXFLAGS -Qoption ccfe -stabs=no%dfltlit+no%dflthlp"
  62         fi
  63     ;;
  64 esac
  65
  66 # Checks for typedefs, structures, and compiler characteristics.
  67 AC_C_CONST
  68 AC_TYPE_SIZE_T
  69 AC_HEADER_DIRENT
  70
  71 # Checks for library functions.
  72 AC_CHECK_FUNCS([strchr strdup strstr])
  73 AC_CHECK_SIZEOF(time_t)
  74
  75 # checks for pthreads
  76 ACX_PTHREAD([enable_threads="pthread"],[enable_threads="no"])
  77 if test $enable_threads != "pthread"; then
  78     AC_MSG_ERROR([unable to find pthreads, currently this is required])
  79 else
  80     AC_DEFINE(HAVE_PTHREAD,1,[Define if you have POSIX threads libraries and header files.])
  81     LIBS="$PTHREAD_LIBS $LIBS"
  82     CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
  83     CXXFLAGS="$PTHREAD_CFLAGS $CXXFLAGS"
  84 fi
  85
  86 # zlib settings
  87 AC_ARG_WITH(zlib,
  88     AS_HELP_STRING([--with-zlib=PATH],[where zlib is installed]),
  89     [
  90         if test -d "$withval" ; then
  91             CPPFLAGS="${CPPFLAGS} -I$withval/include"
  92             LDFLAGS="${LDFLAGS} -L$withval/lib"
  93         fi
  94     ]
  95 )
  96
  97 AC_ARG_WITH(zlib,
  98     AS_HELP_STRING([--with-zlib=PATH],[where zlib is installed]),,
  99     [with_zlib=/usr])
 100 if test x_$with_zlib != x_/usr; then
 101     CPPFLAGS="-I${with_zlib}/include $CPPFLAGS"
 102     LIBS="-L${with_zlib}/lib -lz $LIBS"
 103 else
 104     LIBS="-lz $LIBS"
 105 fi
 106
 107 AC_CHECK_HEADER([zlib.h],,AC_MSG_ERROR([unable to find zlib header files]))
 108 AC_LINK_IFELSE(
 109     [AC_LANG_PROGRAM([[#include <zlib.h>]],
 110         [[zlibVersion()]])],,
 111     [AC_MSG_ERROR([unable to link with zlib])])
 112
 113
 114 # OpenSSL settings
 115 AC_ARG_WITH(openssl,
 116     AS_HELP_STRING([--with-openssl=PATH],[where openssl is installed]),
 117     [if test x_$with_openssl != x_/usr; then
 118         SSLFLAGS="-I${with_openssl}/include"
 119     fi])
 120
 121 if test "x$with_openssl" = "x" ; then
 122     AC_PATH_PROG(PKG_CONFIG, pkg-config)
 123     if test "x$PKG_CONFIG" != x && test "x$PKG_CONFIG" != "xno" ; then
 124         if pkg-config openssl ; then
 125             SSLFLAGS="`$PKG_CONFIG --cflags openssl`"
 126         else
 127             AC_MSG_WARN([OpenSSL not supported by pkg-config, try --with-openssl instead])
 128         fi
 129     fi
 130 fi
 131
 132 AC_MSG_CHECKING(for OpenSSL cflags)
 133 AC_MSG_RESULT($SSLFLAGS)
 134 CPPFLAGS="$SSLFLAGS $CPPFLAGS"
 135
 136 AC_CHECK_HEADER([openssl/x509.h],,AC_MSG_ERROR([unable to find openssl header files]))
 137
 138 AC_LANG([C++])
 139
 140 # C++ requirements
 141 AC_CXX_NAMESPACES
 142 AC_CXX_REQUIRE_STL
 143
 144 # Boost
 145 BOOST_REQUIRE
 146 BOOST_BIND
 147 BOOST_LAMBDA
 148 BOOST_PTR_CONTAINER
 149 BOOST_SMART_PTR
 150 BOOST_STRING_ALGO
 151 CPPFLAGS="$BOOST_CPPFLAGS $CPPFLAGS"
 152
 153 # log4shib settings (favor this version over the log4cpp code)
 154 AC_PATH_PROG(LOG4SHIB_CONFIG,log4shib-config)
 155 AC_ARG_WITH(log4shib,
 156     AS_HELP_STRING([--with-log4shib=PATH],[where log4shib-config is installed]),
 157     [
 158     LOG4SHIB_CONFIG="${with_log4shib}"
 159     if ! test -f "${LOG4SHIB_CONFIG}"; then
 160         LOG4SHIB_CONFIG="${with_log4shib}/bin/log4shib-config"
 161     fi
 162     ])
 163 if test -f "${LOG4SHIB_CONFIG}" ; then
 164     LIBS="`${LOG4SHIB_CONFIG} --libs` $LIBS"
 165     CPPFLAGS="`${LOG4SHIB_CONFIG} --cflags` $CPPFLAGS"
 166         AC_CHECK_HEADER([log4shib/CategoryStream.hh],,AC_MSG_ERROR([unable to find log4shib header files]))
 167     AC_LINK_IFELSE(
 168         [AC_LANG_PROGRAM([[#include <log4shib/Category.hh>
 169 #include <log4shib/CategoryStream.hh>]],
 170             [[log4shib::Category::getInstance("foo").errorStream() << log4shib::eol]])],
 171         [AC_DEFINE([OPENSAML_LOG4SHIB],[1],[Define to 1 if log4shib library is used.])],
 172         [AC_MSG_ERROR([unable to link with log4shib])])
 173 else
 174     AC_MSG_WARN([log4shib-config not found, may need to use --with-log4shib option])
 175     AC_MSG_WARN([will look for original log4cpp library])
 176
 177     # log4cpp settings
 178     AC_PATH_PROG(LOG4CPP_CONFIG,log4cpp-config)
 179     AC_ARG_WITH(log4cpp,
 180         AS_HELP_STRING([--with-log4cpp=PATH],[where log4cpp-config is installed]),
 181         [
 182         LOG4CPP_CONFIG="${with_log4cpp}"
 183         if ! test -f "${LOG4CPP_CONFIG}"; then
 184                 LOG4CPP_CONFIG="${with_log4cpp}/bin/log4cpp-config"
 185         fi
 186         ])
 187     if test -f "${LOG4CPP_CONFIG}"; then
 188         AC_MSG_WARN([will try to use log4cpp, note that most non-Internet2 supplied versions are not thread-safe])
 189         LIBS="`${LOG4CPP_CONFIG} --libs` $LIBS"
 190         CPPFLAGS="`${LOG4CPP_CONFIG} --cflags` $CPPFLAGS"
 191         AC_CHECK_HEADER([log4cpp/CategoryStream.hh],,AC_MSG_ERROR([unable to find log4cpp header files]))
 192         AC_LINK_IFELSE(
 193             [AC_LANG_PROGRAM([[#include <log4cpp/Category.hh>
 194 #include <log4cpp/CategoryStream.hh>]],
 195                 [[log4cpp::Category::getInstance("foo").errorStream() << log4cpp::eol]])],
 196             [AC_DEFINE([OPENSAML_LOG4CPP],[1],[Define to 1 if log4cpp library is used.])],
 197             [AC_MSG_ERROR([unable to link with log4cpp, need version 1.0 or later])])
 198     else
 199         AC_MSG_ERROR([log4cpp-config not found, may need to use --with-log4cpp option])
 200     fi
 201 fi
 202
 203 # Xerces settings
 204 AC_ARG_WITH(xerces,
 205     AS_HELP_STRING([--with-xerces=PATH],[where xerces-c is installed]),,
 206     [with_xerces=/usr])
 207 if test x_$with_xerces != x_/usr; then
 208     CPPFLAGS="-I${with_xerces}/include $CPPFLAGS"
 209     LIBS="-L${with_xerces}/lib -lxerces-c $LIBS"
 210 else
 211     LIBS="-lxerces-c $LIBS"
 212 fi
 213
 214 AC_CHECK_HEADER([xercesc/dom/DOM.hpp],,AC_MSG_ERROR([unable to find xerces header files]))
 215 AC_MSG_CHECKING([Xerces version])
 216 AC_PREPROC_IFELSE(
 217     [AC_LANG_PROGRAM([#include <xercesc/util/XercesVersion.hpp>],
 218 [#if  _XERCES_VERSION != 20600
 219 int i = 0;
 220 #else
 221 #error cannot use version 2.6.0
 222 #endif])],
 223     [AC_MSG_RESULT(OK)],
 224     [AC_MSG_FAILURE([Xerces-C v2.6.0 has bugs that inhibit use with signed XML, please use a newer version])])
 225 AC_LINK_IFELSE(
 226     [AC_LANG_PROGRAM([[#include <xercesc/util/PlatformUtils.hpp>]],[[xercesc::XMLPlatformUtils::Initialize()]])],
 227     ,[AC_MSG_ERROR([unable to link with Xerces])])
 228
 229 AC_MSG_CHECKING([whether Xerces XMLString::release(XMLByte**) exists])
 230 AC_COMPILE_IFELSE(
 231     [AC_LANG_PROGRAM([[#include <xercesc/util/XMLString.hpp>]],
 232     [[using namespace XERCES_CPP_NAMESPACE; XMLByte* buf=NULL; XMLString::release(&buf);]])],
 233     [AC_MSG_RESULT([yes])AC_DEFINE([OPENSAML_XERCESC_HAS_XMLBYTE_RELEASE],[1],[Define to 1 if Xerces XMLString includes XMLByte release.])],
 234     [AC_MSG_RESULT([no])])
 235
 236 # XML-Security settings
 237 AC_ARG_WITH(xmlsec,
 238     AS_HELP_STRING([--with-xmlsec=PATH],[where xmlsec is installed]),,
 239     [with_xmlsec=/usr])
 240 if test x_$with_xmlsec != x_/usr; then
 241     CPPFLAGS="-I${with_xmlsec}/include $CPPFLAGS"
 242     LIBS="-L${with_xmlsec}/lib -lxml-security-c $LIBS"
 243 else
 244     LIBS="-lxml-security-c $LIBS"
 245 fi
 246 AC_CHECK_HEADER([xsec/utils/XSECPlatformUtils.hpp],,AC_MSG_ERROR([unable to find xmlsec header files]))
 247 AC_MSG_CHECKING([XML-Security version])
 248 AC_PREPROC_IFELSE(
 249     [AC_LANG_PROGRAM([#include <xsec/utils/XSECPlatformUtils.hpp>],
 250     [#if XSEC_VERSION_MAJOR > 1 || (XSEC_VERSION_MAJOR == 1 && XSEC_VERSION_MEDIUM > 3)
 251 int i = 0;
 252 #else
 253 #error need version 1.4.0 or later
 254 #endif])],
 255     [AC_MSG_RESULT(OK)],
 256     [AC_MSG_FAILURE([XML-Security version 1.4.0 or greater is required.])])
 257     AC_LINK_IFELSE(
 258         [AC_LANG_PROGRAM([[#include <xsec/utils/XSECPlatformUtils.hpp>]],
 259             [[XSECPlatformUtils::Initialise()]])],,
 260         [AC_MSG_ERROR([unable to link with XML-Security])])
 261
 262 # XML-Tooling settings
 263 AC_ARG_WITH(xmltooling,
 264     AS_HELP_STRING([--with-xmltooling=PATH],[where xmltooling is installed]),,
 265     [with_xmltooling=/usr])
 266 if test x_$with_xmltooling != x_/usr; then
 267     CPPFLAGS="-I${with_xmltooling}/include $CPPFLAGS"
 268     DX_INCLUDE="${with_xmltooling}/include"
 269     LIBS="-L${with_xmltooling}/lib -lxmltooling $LIBS"
 270 else
 271     LIBS="-lxmltooling $LIBS"
 272 fi
 273
 274 AC_CHECK_HEADER([xmltooling/XMLToolingConfig.h],,AC_MSG_ERROR([unable to find xmltooling header files]))
 275
 276 AC_LINK_IFELSE(
 277     [AC_LANG_PROGRAM([[#include <xmltooling/XMLToolingConfig.h>
 278 #include <xmltooling/version.h>]],
 279         [[#if _XMLTOOLING_VERSION >= 10400
 280 xmltooling::XMLToolingConfig::getConfig();
 281 #else
 282 #error Need XMLTooling version 1.4 or higher
 283 #endif]])],
 284     ,[AC_MSG_ERROR([unable to link with XMLTooling, or version was too old])])
 285
 286 # Check for unit test support
 287 CXXTEST="/usr/bin/cxxtestgen.pl"
 288 CXXTESTFLAGS=""
 289 AC_ARG_WITH(cxxtest,
 290     AS_HELP_STRING([--with-cxxtest=PATH], [where cxxtest is installed]),
 291     [if test x_$with_cxxtest != x_/usr; then
 292         CXXTEST="${with_cxxtest}/cxxtestgen.pl"
 293         CXXTESTFLAGS="-I${with_cxxtest}"
 294     fi])
 295 if ! test -f "${CXXTEST}"; then
 296     AC_MSG_WARN([cxxtestgen not found, won't build unit tests])
 297 fi
 298
 299 AC_SUBST(CXXTEST)
 300 AC_SUBST(CXXTESTFLAGS)
 301 AM_CONDITIONAL(BUILD_UNITTEST,test -f ${CXXTEST})
 302
 303 AX_CREATE_PKGCONFIG_INFO(,,[$LIBS -lsaml],[OpenSAML library])
 304
 305 AC_SUBST(DX_INCLUDE)
 306 LIBTOOL="$LIBTOOL --silent"
 307
 308 # output packaging and makefiles
 309 AC_OUTPUT