configure.ac

   1 AC_PREREQ([2.50])
   2 AC_INIT([opensaml],[2.4.1],[https://bugs.internet2.edu/],[opensaml])
   3 AC_CONFIG_SRCDIR(saml)
   4 AC_CONFIG_AUX_DIR(build-aux)
   5 AC_CONFIG_MACRO_DIR(m4)
   6 AM_INIT_AUTOMAKE
   7 AC_DISABLE_STATIC
   8 AC_PROG_LIBTOOL
   9
  10 # Docygen features
  11 DX_HTML_FEATURE(ON)
  12 DX_CHM_FEATURE(OFF)
  13 DX_CHI_FEATURE(OFF)
  14 DX_MAN_FEATURE(OFF)
  15 DX_RTF_FEATURE(OFF)
  16 DX_XML_FEATURE(OFF)
  17 DX_PDF_FEATURE(OFF)
  18 DX_PS_FEATURE(OFF)
  19 DX_INIT_DOXYGEN(opensaml, doxygen.cfg, doc/api)
  20 DX_INCLUDE=
  21
  22 AC_ARG_ENABLE(debug,
  23     AS_HELP_STRING([--enable-debug],[Have GCC compile with symbols (Default = no)]),
  24     enable_debug=$enableval, enable_debug=no)
  25
  26 if test "$enable_debug" = "yes" ; then
  27     GCC_CFLAGS="$CFLAGS -Wall -g -D_DEBUG"
  28     GCC_CXXFLAGS="$CXXFLAGS -Wall -g -D_DEBUG"
  29 else
  30     GCC_CFLAGS="$CFLAGS -Wall -O2 -DNDEBUG"
  31     GCC_CXXFLAGS="$CXXFLAGS -Wall -O2 -DNDEBUG"
  32 fi
  33
  34 AC_CONFIG_HEADERS([config.h])
  35 AC_CONFIG_FILES([opensaml.spec pkginfo Portfile])
  36 AC_CONFIG_FILES([Makefile saml/Makefile samltest/Makefile samlsign/Makefile schemas/Makefile doc/Makefile])
  37
  38 AC_PROG_CC([gcc gcc3 cc])
  39 AC_PROG_CXX([g++ g++3 c++ CC])
  40 AC_CANONICAL_HOST
  41
  42 if test "$GCC" = "yes" ; then
  43 #    AC_HAVE_GCC_VERSION(4,0,0,0,
  44 #        [
  45 #        AC_DEFINE(GCC_HASCLASSVISIBILITY,1,
  46 #            [Define to enable class visibility control in gcc.])
  47 #        GCC_CFLAGS="$GCC_CFLAGS -fvisibility=hidden -fvisibility-inlines-hidden"
  48 #        GCC_CXXFLAGS="$GCC_CXXFLAGS -fvisibility=hidden -fvisibility-inlines-hidden"
  49 #        ])
  50     CFLAGS="$GCC_CFLAGS"
  51     CXXFLAGS="$GCC_CXXFLAGS"
  52 else
  53 # Fix for Sun Workshop compiler in debug mode, may be Sun case #6360993
  54         case "${host_cpu}-${host_os}" in
  55                 *solaris*)
  56                         if test "$CXX" = "CC" ; then
  57                                 CXXFLAGS="$CXXFLAGS -Qoption ccfe -stabs=no%dfltlit+no%dflthlp"
  58                         fi
  59                 ;;
  60         esac
  61 fi
  62
  63 # Checks for typedefs, structures, and compiler characteristics.
  64 AC_C_CONST
  65 AC_TYPE_SIZE_T
  66
  67 # Checks for library functions.
  68 AC_CHECK_FUNCS([strchr strdup strstr])
  69 AC_CHECK_SIZEOF(time_t)
  70
  71 # checks for pthreads
  72 ACX_PTHREAD([enable_threads="pthread"],[enable_threads="no"])
  73 if test $enable_threads != "pthread"; then
  74     AC_MSG_ERROR([unable to find pthreads, currently this is required])
  75 else
  76     AC_DEFINE(HAVE_PTHREAD,1,[Define if you have POSIX threads libraries and header files.])
  77     LIBS="$PTHREAD_LIBS $LIBS"
  78     CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
  79     CXXFLAGS="$PTHREAD_CFLAGS $CXXFLAGS"
  80 fi
  81
  82 # zlib settings
  83 AC_ARG_WITH(zlib,
  84     AS_HELP_STRING([--with-zlib=PATH],[where zlib is installed]),
  85     [
  86         if test -d "$withval" ; then
  87             CPPFLAGS="${CPPFLAGS} -I$withval/include"
  88             LDFLAGS="${LDFLAGS} -L$withval/lib"
  89         fi
  90     ]
  91 )
  92 AC_CHECK_HEADER([zlib.h],,AC_MSG_ERROR([unable to find zlib header files]))
  93 AC_CHECK_LIB([z],[deflateInit2_],,AC_MSG_ERROR([unable to link with zlib library]))
  94
  95 # OpenSSL settings
  96 AC_ARG_WITH(openssl,
  97     AS_HELP_STRING([--with-openssl=PATH],[where openssl is installed]),
  98     [if test x_$with_openssl != x_/usr; then
  99         SSLFLAGS="-I${with_openssl}/include"
 100     fi])
 101
 102 if test "x$with_openssl" = "x" ; then
 103     AC_PATH_PROG(PKG_CONFIG, pkg-config)
 104     if test "x$PKG_CONFIG" != x && test "x$PKG_CONFIG" != "xno" ; then
 105         if pkg-config openssl ; then
 106             SSLFLAGS="`$PKG_CONFIG --cflags openssl`"
 107         else
 108             AC_MSG_WARN([OpenSSL not supported by pkg-config, try --with-openssl instead])
 109         fi
 110     fi
 111 fi
 112
 113 AC_MSG_CHECKING(for OpenSSL cflags)
 114 AC_MSG_RESULT($SSLFLAGS)
 115 CPPFLAGS="$SSLFLAGS $CPPFLAGS"
 116
 117 AC_CHECK_HEADER([openssl/x509.h],,AC_MSG_ERROR([unable to find openssl header files]))
 118
 119 AC_LANG([C++])
 120
 121 # C++ requirements
 122 AC_CXX_NAMESPACES
 123 AC_CXX_REQUIRE_STL
 124
 125 # log4shib settings (favor this version over the log4cpp code)
 126 AC_PATH_PROG(LOG4SHIB_CONFIG,log4shib-config)
 127 AC_ARG_WITH(log4shib,
 128     AS_HELP_STRING([--with-log4shib=PATH],[where log4shib-config is installed]),
 129     [
 130     LOG4SHIB_CONFIG="${with_log4shib}"
 131     if ! test -f "${LOG4SHIB_CONFIG}"; then
 132         LOG4SHIB_CONFIG="${with_log4shib}/bin/log4shib-config"
 133     fi
 134     ])
 135 if test -f "${LOG4SHIB_CONFIG}" ; then
 136     LIBS="`${LOG4SHIB_CONFIG} --libs` $LIBS"
 137     CPPFLAGS="`${LOG4SHIB_CONFIG} --cflags` $CPPFLAGS"
 138         AC_CHECK_HEADER([log4shib/CategoryStream.hh],,AC_MSG_ERROR([unable to find log4shib header files]))
 139     AC_LINK_IFELSE(
 140         [AC_LANG_PROGRAM([[#include <log4shib/Category.hh>
 141 #include <log4shib/CategoryStream.hh>]],
 142             [[log4shib::Category::getInstance("foo").errorStream() << log4shib::eol]])],
 143         [AC_DEFINE([OPENSAML_LOG4SHIB],[1],[Define to 1 if log4shib library is used.])],
 144         [AC_MSG_ERROR([unable to link with log4shib])])
 145 else
 146     AC_MSG_WARN([log4shib-config not found, may need to use --with-log4shib option])
 147     AC_MSG_WARN([will look for original log4cpp library])
 148
 149     # log4cpp settings
 150     AC_PATH_PROG(LOG4CPP_CONFIG,log4cpp-config)
 151     AC_ARG_WITH(log4cpp,
 152         AS_HELP_STRING([--with-log4cpp=PATH],[where log4cpp-config is installed]),
 153         [
 154         LOG4CPP_CONFIG="${with_log4cpp}"
 155         if ! test -f "${LOG4CPP_CONFIG}"; then
 156                 LOG4CPP_CONFIG="${with_log4cpp}/bin/log4cpp-config"
 157         fi
 158         ])
 159     if test -f "${LOG4CPP_CONFIG}"; then
 160         AC_MSG_WARN([will try to use log4cpp, note that most non-Internet2 supplied versions are not thread-safe])
 161         LIBS="`${LOG4CPP_CONFIG} --libs` $LIBS"
 162         CPPFLAGS="`${LOG4CPP_CONFIG} --cflags` $CPPFLAGS"
 163         AC_CHECK_HEADER([log4cpp/CategoryStream.hh],,AC_MSG_ERROR([unable to find log4cpp header files]))
 164         AC_LINK_IFELSE(
 165             [AC_LANG_PROGRAM([[#include <log4cpp/Category.hh>
 166 #include <log4cpp/CategoryStream.hh>]],
 167                 [[log4cpp::Category::getInstance("foo").errorStream() << log4cpp::eol]])],
 168             [AC_DEFINE([OPENSAML_LOG4CPP],[1],[Define to 1 if log4cpp library is used.])],
 169             [AC_MSG_ERROR([unable to link with log4cpp, need version 1.0 or later])])
 170     else
 171         AC_MSG_ERROR([log4cpp-config not found, may need to use --with-log4cpp option])
 172     fi
 173 fi
 174
 175 # Xerces settings
 176 AC_ARG_WITH(xerces,
 177     AS_HELP_STRING([--with-xerces=PATH],[where xerces-c is installed]),
 178     [if test x_$with_xerces != x_/usr; then
 179         LDFLAGS="-L${with_xerces}/lib $LDFLAGS"
 180         CPPFLAGS="-I${with_xerces}/include $CPPFLAGS"
 181     fi])
 182 LIBS="-lxerces-c $LIBS"
 183 AC_CHECK_HEADER([xercesc/dom/DOM.hpp],,AC_MSG_ERROR([unable to find xerces header files]))
 184 AC_MSG_CHECKING([Xerces version])
 185 AC_PREPROC_IFELSE(
 186     [AC_LANG_PROGRAM([#include <xercesc/util/XercesVersion.hpp>],
 187 [#if  _XERCES_VERSION != 20600
 188 int i = 0;
 189 #else
 190 #error cannot use version 2.6.0
 191 #endif])],
 192     [AC_MSG_RESULT(OK)],
 193     [AC_MSG_FAILURE([Xerces-C v2.6.0 has bugs that inhibit use with signed XML, please use a newer version])])
 194 AC_LINK_IFELSE(
 195     [AC_LANG_PROGRAM([[#include <xercesc/util/PlatformUtils.hpp>]],[[xercesc::XMLPlatformUtils::Initialize()]])],
 196     ,[AC_MSG_ERROR([unable to link with Xerces])])
 197
 198 AC_MSG_CHECKING([whether Xerces XMLString::release(XMLByte**) exists])
 199 AC_COMPILE_IFELSE(
 200     [AC_LANG_PROGRAM([[#include <xercesc/util/XMLString.hpp>]],
 201     [[using namespace XERCES_CPP_NAMESPACE; XMLByte* buf=NULL; XMLString::release(&buf);]])],
 202     [AC_MSG_RESULT([yes])AC_DEFINE([OPENSAML_XERCESC_HAS_XMLBYTE_RELEASE],[1],[Define to 1 if Xerces XMLString includes XMLByte release.])],
 203     [AC_MSG_RESULT([no])])
 204
 205 # XML-Security settings
 206 AC_ARG_WITH(xmlsec,
 207     AS_HELP_STRING([--with-xmlsec=PATH],[where xmlsec is installed]),
 208     [if test x_$with_xmlsec != x_/usr; then
 209         LDFLAGS="-L${with_xmlsec}/lib $LDFLAGS"
 210         CPPFLAGS="-I${with_xmlsec}/include $CPPFLAGS"
 211     fi])
 212 LIBS="-lxml-security-c $LIBS"
 213 AC_CHECK_HEADER([xsec/utils/XSECPlatformUtils.hpp],,AC_MSG_ERROR([unable to find xmlsec header files]))
 214 AC_MSG_CHECKING([XML-Security version])
 215 AC_PREPROC_IFELSE(
 216     [AC_LANG_PROGRAM([#include <xsec/utils/XSECPlatformUtils.hpp>],
 217     [#if XSEC_VERSION_MAJOR > 1 || (XSEC_VERSION_MAJOR == 1 && XSEC_VERSION_MEDIUM > 3)
 218 int i = 0;
 219 #else
 220 #error need version 1.4.0 or later
 221 #endif])],
 222     [AC_MSG_RESULT(OK)],
 223     [AC_MSG_FAILURE([XML-Security version 1.4.0 or greater is required.])])
 224     AC_LINK_IFELSE(
 225         [AC_LANG_PROGRAM([[#include <xsec/utils/XSECPlatformUtils.hpp>]],
 226             [[XSECPlatformUtils::Initialise()]])],,
 227         [AC_MSG_ERROR([unable to link with XML-Security])])
 228
 229 # XML-Tooling settings
 230 AC_ARG_WITH(xmltooling,
 231     AS_HELP_STRING([--with-xmltooling=PATH],[where xmltooling is installed]),
 232     [if test x_$with_xmltooling != x_/usr; then
 233         LDFLAGS="-L${with_xmltooling}/lib $LDFLAGS"
 234         CPPFLAGS="-I${with_xmltooling}/include $CPPFLAGS"
 235         DX_INCLUDE="${with_xmltooling}/include"
 236     fi])
 237 LIBS="-lxmltooling $LIBS"
 238 AC_CHECK_HEADER([xmltooling/XMLToolingConfig.h],,AC_MSG_ERROR([unable to find xmltooling header files]))
 239
 240 AC_LINK_IFELSE(
 241     [AC_LANG_PROGRAM([[#include <xmltooling/XMLToolingConfig.h>
 242 #include <xmltooling/version.h>]],
 243         [[#if _XMLTOOLING_VERSION >= 10400
 244 xmltooling::XMLToolingConfig::getConfig();
 245 #else
 246 #error Need XMLTooling version 1.4 or higher
 247 #endif]])],
 248     ,[AC_MSG_ERROR([unable to link with XMLTooling, or version was too old])])
 249
 250 # Check for unit test support
 251 CXXTEST="/usr/bin/cxxtestgen.pl"
 252 CXXTESTFLAGS=""
 253 AC_ARG_WITH(cxxtest,
 254     AS_HELP_STRING([--with-cxxtest=PATH], [where cxxtest is installed]),
 255     [if test x_$with_cxxtest != x_/usr; then
 256         CXXTEST="${with_cxxtest}/cxxtestgen.pl"
 257         CXXTESTFLAGS="-I${with_cxxtest}"
 258     fi])
 259 if ! test -f "${CXXTEST}"; then
 260     AC_MSG_WARN([cxxtestgen not found, won't build unit tests])
 261 fi
 262
 263 AC_SUBST(CXXTEST)
 264 AC_SUBST(CXXTESTFLAGS)
 265 AM_CONDITIONAL(BUILD_UNITTEST,test -f ${CXXTEST})
 266
 267 AX_CREATE_PKGCONFIG_INFO(,,[$LIBS -lsaml],[OpenSAML library])
 268
 269 AC_SUBST(DX_INCLUDE)
 270 LIBTOOL="$LIBTOOL --silent"
 271
 272 # output packaging and makefiles
 273 AC_OUTPUT