configure.ac

   1 AC_PREREQ([2.50])
   2 AC_INIT([shibboleth], [1.3.1], [shibboleth-users@internet2.edu], [shibboleth])
   3 AM_CONFIG_HEADER(config.h)
   4 AM_INIT_AUTOMAKE([shibboleth],[1.3.1])
   5
   6 sinclude(acx_pthread.m4)
   7 sinclude(acx_rpctest.m4)
   8
   9 AC_ARG_ENABLE(debug,
  10     AC_HELP_STRING(--enable-debug, [Have GCC compile with symbols (Default = no)
  11 ]),
  12     enable_debug=$enableval, enable_debug=no)
  13
  14 if test "$enable_debug" = "yes" ; then
  15     GCC_CFLAGS="$CFLAGS -Wall -g -D_DEBUG"
  16     GCC_CXXFLAGS="$CXXFLAGS -Wall -g -D_DEBUG"
  17 else
  18     GCC_CFLAGS="$CFLAGS -Wall -O2 -DNDEBUG"
  19     GCC_CXXFLAGS="$CXXFLAGS -Wall -O2 -DNDEBUG"
  20 fi
  21
  22 AC_PROG_CC([gcc gcc3 cc])
  23 AC_PROG_CXX([g++ g++3 c++ CC])
  24
  25 if test "$GCC" = "yes" ; then
  26     CFLAGS="$GCC_CFLAGS"
  27     CXXFLAGS="$GCC_CXXFLAGS"
  28 fi
  29
  30 AC_DISABLE_STATIC
  31 AC_PROG_LIBTOOL
  32
  33 AC_LANG(C++)
  34
  35 # C++ requirements
  36 AC_CXX_REQUIRE_STL
  37 AC_CXX_NAMESPACES
  38
  39 AC_LANG(C)
  40
  41 # Checks for typedefs, structures, and compiler characteristics.
  42 AC_C_CONST
  43 AC_TYPE_SIZE_T
  44 AC_STRUCT_TM
  45
  46 # Checks for library functions.
  47 AC_FUNC_STRFTIME
  48 AC_FUNC_STRERROR_R
  49 AC_CHECK_FUNCS([strchr strdup strstr gmtime_r ctime_r strtok_r strcasecmp])
  50 AC_CHECK_HEADERS([dlfcn.h])
  51
  52 # old_LIBS="$LIBS"
  53 # AC_SEARCH_LIBS(xdr_uint64_t,nsl,,
  54 #       [CFLAGS="$CFLAGS -DNEED_XDR_LONGLONG"
  55 #        CXXFLAGS="$CXXFLAGS -DNEED_XDR_LONGLONG"])
  56 # LIBS="$old_LIBS"
  57
  58 # checks for pthreads
  59 ACX_PTHREAD([enable_threads="pthread"],[enable_threads="no"])
  60 if test $enable_threads != "pthread"; then
  61     AC_MSG_ERROR([unable to find pthreads, currently this is required])
  62 else
  63     AC_DEFINE(HAVE_PTHREAD,1,[Define if you have POSIX threads libraries and header files.])
  64     LIBS="$PTHREAD_LIBS $LIBS"
  65     CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
  66     CXXFLAGS="$PTHREAD_CFLAGS $CXXFLAGS"
  67 fi
  68
  69 # Test RPC now -- finish dealing with it later
  70 AC_ARG_ENABLE(native-rpc,
  71         AC_HELP_STRING([--enable-native-rpc], [use the OS-supplied Sun RPC library, default is NO, except Linux]),
  72         [ if test "x$enableval" = "x" ; then
  73               NATIVE_RPC=yes
  74           else
  75               NATIVE_RPC="$enableval"
  76           fi
  77         ], [ NATIVE_RPC=no ])
  78 ACX_RPCTEST([rpctest="yes"],[rpctest="no"])
  79 AC_MSG_NOTICE([does the native Sun RPC library support svcfd_create...$rpctest])
  80 if test $NATIVE_RPC = "no"; then
  81         case "${host}" in
  82                 *-*-linux*)
  83                         if test $rpctest = "yes"; then
  84                                 AC_MSG_WARN([embedded Sun RPC library does not support Linux])
  85                                 NATIVE_RPC="yes"
  86                         else
  87                                 AC_MSG_ERROR([embedded Sun RPC library won't work, but neither will native version])
  88                         fi
  89                 ;;
  90         esac
  91 fi
  92 if test $NATIVE_RPC = "yes" && test $rpctest = "no"; then
  93         AC_MSG_WARN([native Sun RPC won't work, using internal version])
  94         NATIVE_RPC = "no"
  95 fi
  96 if test $NATIVE_RPC = "yes"; then
  97         AC_CHECK_DECLS([svcfd_create],,,[#include <rpc/rpc.h>])
  98         AC_LANG_PUSH(C++)
  99         AC_COMPILE_IFELSE(
 100                 AC_LANG_PROGRAM(
 101                         [[#include <rpc/rpc.h>
 102 static SVCXPRT* xprt = NULL;]],
 103                 [[svc_destroy(xprt);]]),
 104         AC_DEFINE(HAVE_WORKING_SVC_DESTROY,1,[Define if RPC SVC macros work on this platform]),)
 105         AC_LANG_POP(C++)
 106 else
 107         AC_CHECK_TYPES([struct rpcent],,,[#include <netdb.h>])
 108         AC_CHECK_DECLS(sys_errlist)
 109         AC_DEFINE(HAVE_DECL_SVCFD_CREATE,1,[ Define to 1 if you have the declaration of svcfd_create, and to 0 if you don't.])
 110         AC_DEFINE(HAVE_WORKING_SVC_DESTROY,1,[Define if RPC SVC macros work on this platform])
 111 fi
 112
 113 AC_ARG_WITH(dmalloc,
 114             AC_HELP_STRING([--with-dmalloc=PATH], [where dmalloc is installed]),
 115             [if test x_$with_dmalloc != x_/usr; then
 116                 LDFLAGS="-L${with_dmalloc}/lib $LDFLAGS"
 117                 CPPFLAGS="-I${with_dmalloc}/include $CPPFLAGS"
 118             fi
 119             AC_CHECK_LIB(dmallocxx, dmalloc_shutdown,,
 120                          AC_MSG_ERROR([unable to find dmallocxx library]))
 121             ])
 122
 123 # OpenSSL settings
 124 AC_PATH_PROG(PKG_CONFIG, pkg-config)
 125 if test "x$PKG_CONFIG" = x || test "x$PKG_CONFIG" = "xno" ; then
 126     AC_ARG_WITH(openssl,
 127             AC_HELP_STRING([--with-openssl=PATH], [where openssl is installed]),
 128             [if test x_$with_openssl != x_/usr; then
 129             SSLLIBS="-L${with_openssl}/lib"
 130             SSLFLAGS="-I${with_openssl}/include"
 131             fi])
 132     SSLLIBS="$SSLLIBS -lssl -lcrypto"
 133 else
 134     SSLLIBS="`$PKG_CONFIG --libs openssl`"
 135     SSLFLAGS="`$PKG_CONFIG --cflags openssl`"
 136 fi
 137 AC_MSG_CHECKING(for OpenSSL libraries)
 138 AC_MSG_RESULT($SSLLIBS)
 139 LIBS="$LIBS $SSLLIBS"
 140 AC_MSG_CHECKING(for OpenSSL cflags)
 141 AC_MSG_RESULT($SSLFLAGS)
 142 CPPFLAGS="$SSLFLAGS $CPPFLAGS"
 143
 144 AC_CHECK_HEADER([openssl/ssl.h],,
 145                 AC_MSG_ERROR([unable to find openssl header files]))
 146 AC_MSG_CHECKING(for ERR_load_CRYPTO_string)
 147 AC_TRY_LINK_FUNC([ERR_load_CRYPTO_strings],,
 148              AC_MSG_ERROR([unable to link with openssl libraries]))
 149 AC_MSG_RESULT(yes)
 150 AC_MSG_CHECKING(for SSL_library_init)
 151 AC_TRY_LINK_FUNC([SSL_library_init],,
 152              AC_MSG_ERROR([unable to link with openssl libraries]))
 153 AC_MSG_RESULT(yes)
 154
 155 AC_LANG(C++)
 156
 157 # log4shib settings (favor this version over the log4cpp code)
 158 AC_PATH_PROG(LOG4SHIB_CONFIG,log4shib-config)
 159 AC_ARG_WITH(log4shib,
 160     AC_HELP_STRING([--with-log4shib=PATH], [where log4shib-config is installed]),
 161     [
 162     LOG4SHIB_CONFIG="${with_log4shib}"
 163     if ! test -f "${LOG4SHIB_CONFIG}" ; then
 164         LOG4SHIB_CONFIG="${with_log4shib}/bin/log4shib-config"
 165     fi
 166     ])
 167 if test -f "${LOG4SHIB_CONFIG}"; then
 168     LDFLAGS="`${LOG4SHIB_CONFIG} --libs` $LDFLAGS"
 169     CPPFLAGS="`${LOG4SHIB_CONFIG} --cflags` $CPPFLAGS"
 170         AC_CHECK_HEADER([log4shib/CategoryStream.hh],,AC_MSG_ERROR([unable to find log4shib header files]))
 171         AC_TRY_LINK(
 172                 [#include <log4shib/Category.hh> #include <log4shib/CategoryStream.hh>],
 173                 [log4shib::Category::getInstance("foo").errorStream() << log4shib::eol],
 174                 [AC_DEFINE(HAVE_LOG4SHIB,1,[Define if log4shib library is used.])],
 175                 [AC_MSG_ERROR([unable to link with log4shib])])
 176 else
 177     AC_MSG_WARN([log4shib-config not found, may need to use --with-log4shib option])
 178     AC_MSG_WARN([will look for original log4cpp library])
 179
 180         # log4cpp settings
 181         AC_PATH_PROG(LOG4CPP_CONFIG,log4cpp-config)
 182         AC_ARG_WITH(log4cpp,
 183             AC_HELP_STRING([--with-log4cpp=PATH], [where log4cpp-config is installed]),
 184             [
 185             LOG4CPP_CONFIG="${with_log4cpp}"
 186             if ! test -f "${LOG4CPP_CONFIG}" ; then
 187                 LOG4CPP_CONFIG="${with_log4cpp}/bin/log4cpp-config"
 188             fi
 189             ])
 190         if test -f "${LOG4CPP_CONFIG}"; then
 191                 AC_MSG_WARN([will try to use log4cpp, note that most non-Internet2 supplied versions are not thread-safe])
 192             LDFLAGS="`${LOG4CPP_CONFIG} --libs` $LDFLAGS"
 193             CPPFLAGS="`${LOG4CPP_CONFIG} --cflags` $CPPFLAGS"
 194                 AC_CHECK_HEADER([log4cpp/CategoryStream.hh],,AC_MSG_ERROR([unable to find log4cpp header files]))
 195                 AC_TRY_LINK(
 196                         [#include <log4cpp/Category.hh> #include <log4cpp/CategoryStream.hh>],
 197                         [log4cpp::Category::getInstance("foo").errorStream() << log4cpp::eol],
 198                         [AC_DEFINE(HAVE_LOG4CPP,1,[Define if log4cpp library is used.])],
 199                         [AC_MSG_ERROR([unable to link with log4cpp, at least version 1.0 needed])])
 200         else
 201             AC_MSG_ERROR([log4cpp-config not found, may need to use --with-log4cpp option])
 202         fi
 203 fi
 204
 205 # Xerces settings
 206 AC_ARG_WITH(xerces,
 207             AC_HELP_STRING([--with-xerces=PATH], [where xerces-c is installed]),
 208             [if test x_$with_xerces != x_/usr; then
 209                 LDFLAGS="-L${with_xerces}/lib $LDFLAGS"
 210                 CPPFLAGS="-I${with_xerces}/include $CPPFLAGS"
 211             fi])
 212 LIBS="-lxerces-c $LIBS"
 213 AC_CHECK_HEADER([xercesc/dom/DOM.hpp],,
 214                 AC_MSG_ERROR([unable to find xerces header files]))
 215 AC_MSG_CHECKING([Xerces version])
 216 AC_PREPROC_IFELSE(
 217         [AC_LANG_PROGRAM([#include <xercesc/util/XercesVersion.hpp>],
 218 [#if  _XERCES_VERSION > 20200 && _XERCES_VERSION != 20600
 219 int i = 0;
 220 #else
 221 #error requires version > 2.2.0 but not 2.6.0
 222 #endif])],
 223         [AC_MSG_RESULT(OK)],
 224         [AC_MSG_ERROR([Shibboleth requires patched Xerces version 2.6.1 (http://shibboleth.internet2.edu/downloads/)])])
 225 AC_TRY_LINK(
 226         [#include <xercesc/util/PlatformUtils.hpp>],
 227         [xercesc::XMLPlatformUtils::Initialize()],
 228         [AC_DEFINE(HAVE_LIBXERCESC,1,[Define if Xerces-C library was found])],
 229         [AC_MSG_ERROR([unable to link with Xerces])])
 230
 231
 232 # XML-Security settings
 233 AC_ARG_WITH(xmlsec,
 234             AC_HELP_STRING([--with-xmlsec=PATH], [where xmlsec is installed]),
 235             [if test x_$with_xmlsec != x_/usr; then
 236                 LDFLAGS="-L${with_xmlsec}/lib $LDFLAGS"
 237                 CPPFLAGS="-I${with_xmlsec}/include $CPPFLAGS"
 238             fi])
 239 LIBS="-lxml-security-c $LIBS"
 240 AC_CHECK_HEADER([xsec/xenc/XENCEncryptionMethod.hpp],,AC_MSG_ERROR([unable to find xml-security header files]),[#include <xercesc/dom/DOM.hpp>])
 241 AC_MSG_CHECKING([XML-Security version])
 242 AC_PREPROC_IFELSE(
 243     [AC_LANG_PROGRAM([#include <xsec/utils/XSECPlatformUtils.hpp>],
 244         [#if XSEC_VERSION_MAJOR > 1 || (XSEC_VERSION_MAJOR == 1 && XSEC_VERSION_MEDIUM > 2)
 245 int i = 0;
 246 #else
 247 #error need version 1.3.0 or later
 248 #endif])],
 249     [AC_MSG_RESULT(OK)],
 250     [AC_MSG_FAILURE([XML-Security version 1.3.0 or greater is required.])])
 251 AC_TRY_LINK(
 252         [#include <xsec/utils/XSECPlatformUtils.hpp>],
 253         [XSECPlatformUtils::Initialise()],
 254         [AC_DEFINE(HAVE_LIBXSEC,1,[Define if XML-Sec library was found])],
 255         [AC_MSG_ERROR([unable to link with xml-security])])
 256
 257 # OpenSAML settings
 258 AC_ARG_WITH(saml,
 259             AC_HELP_STRING([--with-saml=PATH], [where saml is installed]),
 260             [if test x_$with_saml != x_/usr; then
 261                 LDFLAGS="-L${with_saml}/lib $LDFLAGS"
 262                 CPPFLAGS="-I${with_saml}/include $CPPFLAGS"
 263             fi])
 264 AC_CHECK_HEADER([saml/saml.h],,
 265                 AC_MSG_ERROR([unable to find saml header files]))
 266 LIBS="-lsaml $LIBS"
 267 AC_TRY_LINK(
 268         [#include <saml/saml.h>
 269 #include <saml/version.h>],
 270         [#if _OPENSAML_VERSION >= 10100
 271 saml::SAMLConfig::getConfig();
 272 #else
 273 #error Need OpenSAML version 1.1 or higher
 274 #endif],
 275         [AC_DEFINE(HAVE_SAML,1,[Define if saml library was found])],
 276         [AC_MSG_ERROR([unable to link with saml, or version too old])])
 277
 278 # output the underlying makefiles
 279 WANT_SUBDIRS="doc shib schemas configs shib-target shar siterefresh test xmlproviders adfs"
 280 AC_CONFIG_FILES([Makefile doc/Makefile shib/Makefile schemas/Makefile \
 281                  configs/Makefile oncrpc/Makefile oncrpc/rpc/Makefile \
 282                  shib-target/Makefile shar/Makefile siterefresh/Makefile \
 283                  test/Makefile xmlproviders/Makefile adfs/Makefile selinux/Makefile])
 284
 285
 286 # now deal with the rpc library, to see if we need to build our own
 287 if test $NATIVE_RPC = "no"; then
 288     WANT_SUBDIRS="oncrpc $WANT_SUBDIRS"
 289         AC_DEFINE(USE_OUR_ONCRPC,1,[Define if using embedded version of ONC RPC.])
 290 fi
 291 AM_CONDITIONAL(USE_OUR_ONCRPC,test "$NATIVE_RPC" = "no")
 292
 293 #
 294 # Build NSAPI module?
 295 #
 296 AC_MSG_CHECKING(for NSAPI module option)
 297 AC_ARG_WITH(nsapi,
 298         AC_HELP_STRING([--with-nsapi=DIR], [Build NSAPI module for Netscape/iPlanet/SunONE]),
 299         [WANT_NSAPI=$withval],[WANT_NSAPI=no])
 300 AC_MSG_RESULT($WANT_NSAPI)
 301
 302 if test "$WANT_NSAPI" != "no"; then
 303   if test ! -d $WANT_NSAPI/bin ; then
 304     AC_MSG_ERROR(Please specify the path to the root of your Netscape/iPlanet/SunONE server using --with-nsapi=DIR)
 305   fi
 306   AC_MSG_CHECKING(for NSAPI include files)
 307   if test -d $WANT_NSAPI/include ; then
 308     NSAPI_INCLUDE=$WANT_NSAPI/include
 309     AC_MSG_RESULT(Netscape-Enterprise 3.x style)
 310     AC_CHECK_HEADERS([$NSAPI_INCLUDE/nsapi.h])
 311     NSAPI_INCLUDE="$NSAPI_INC_DIR -I$NSAPI_INCLUDE"
 312   fi
 313   if test -d $WANT_NSAPI/plugins/include ; then
 314     test -n "$NSAPI_INCLUDE" && NSAPI_INC_DIR="-I$NSAPI_INCLUDE"
 315     NSAPI_INCLUDE="$WANT_NSAPI/plugins/include"
 316     AC_MSG_RESULT(iPlanet 4.x / SunONE 6.x style)
 317     AC_CHECK_HEADERS([$NSAPI_INCLUDE/nsapi.h])
 318     NSAPI_INCLUDE="$NSAPI_INC_DIR -I$NSAPI_INCLUDE"
 319   fi
 320   if test "$NSAPI_INCLUDE" = ""; then
 321     AC_MSG_ERROR(Please check you have nsapi.h in either $WANT_NSAPI/include or $WANT_NSAPI/plugins/include)
 322   fi
 323 fi
 324
 325 AC_SUBST(NSAPI_INCLUDE)
 326
 327 # always output the Makefile, even if you don't use it
 328 AC_CONFIG_FILES([nsapi_shib/Makefile])
 329 AM_CONDITIONAL(BUILD_NSAPI,test ! "$WANT_NSAPI" = "no")
 330
 331 # add the NSAPI module to the list of wanted subdirs..
 332 if test ! "$WANT_NSAPI" = "no" ; then
 333     WANT_SUBDIRS="$WANT_SUBDIRS nsapi_shib"
 334 fi
 335
 336
 337 #
 338 # Build FastCGI support?
 339 #
 340 AC_MSG_CHECKING(for FastCGI support)
 341 AC_ARG_WITH(fastcgi,
 342     AC_HELP_STRING([--with-fastcgi=DIR], [Build FastCGI support]),
 343     [WANT_FASTCGI=$withval],[WANT_FASTCGI=no])
 344 AC_MSG_RESULT($WANT_FASTCGI)
 345
 346 if test "$WANT_FASTCGI" != "no"; then
 347     if test "$WANT_FASTCGI" != "yes"; then
 348         if test x_$WANT_FASTCGI != x_/usr; then
 349             FASTCGI_INCLUDE="-I$WANT_FASTCGI/include"
 350             FASTCGI_LDFLAGS="-L$WANT_FASTCGI/lib"
 351         fi
 352     fi
 353     AC_CHECK_HEADER([fcgio.h],,
 354         AC_MSG_ERROR([unable to find FastCGI header files]))
 355     FASTCGI_LIBS="-lfcgi -lfcgi++"
 356 fi
 357
 358 AC_SUBST(FASTCGI_INCLUDE)
 359 AC_SUBST(FASTCGI_LDFLAGS)
 360 AC_SUBST(FASTCGI_LIBS)
 361
 362 # always output the Makefile, even if you don't use it
 363 AC_CONFIG_FILES([fastcgi/Makefile])
 364 AM_CONDITIONAL(BUILD_FASTCGI,test ! "$WANT_FASTCGI" = "no")
 365 if test ! "$WANT_FASTCGI" = "no" ; then
 366     WANT_SUBDIRS="$WANT_SUBDIRS fastcgi"
 367 fi
 368
 369
 370 #
 371 # If no --enable-apache-xx specified
 372 # find a default and fake the specific parameters
 373 #
 374
 375 # simple macro to peek at an enable or a with
 376 AC_DEFUN([Peek],
 377 if test "[${[$1]_][$2]+set}" = set; then
 378   peekval="${[$1]_[$2]}"
 379   $3
 380 fi; dnl
 381 )
 382
 383 AC_MSG_CHECKING(if default apache needed)
 384 need_default=yes
 385 Peek(enable,apache_13,need_default=no)
 386 Peek(enable,apache_20,need_default=no)
 387 Peek(enable,apache_22,need_default=no)
 388 AC_MSG_RESULT($need_default)
 389
 390 if test "$need_default" = "yes"; then
 391   # find an apxs, then the httpd
 392   xs=
 393   Peek(with,apxs,xs="$peekval")
 394   Peek(with,apxs2,xs="$peekval")
 395   Peek(with,apxs22,xs="$peekval")
 396   if test "x$xs" = "x"; then
 397      AC_PATH_PROGS(xs, apxs2 apxs,
 398         AC_MSG_ERROR(No apxs, no apache found.  Try --with-apxs),
 399         [/usr/local/apache2/bin:/usr/local/apache/bin:/usr/sbin:$PATH])
 400   fi
 401   # ask the daemon for the version and set parameters
 402   AC_MSG_CHECKING(default apache version)
 403   httpd="`$xs -q SBINDIR`/`$xs -q TARGET`"
 404   if test "x$httpd" != "x" && test -f $httpd ; then
 405      v=`$httpd -v|$SED -n -e 's/.*Apache\/\.*//p'`
 406      case $v in
 407        1.3*)   [enable_apache_13]=yes
 408                [with_apxs]=$xs
 409                AC_MSG_RESULT(1.3)
 410                ;;
 411        2.0*)   [enable_apache_20]=yes
 412                [with_apxs2]=$xs
 413                AC_MSG_RESULT(2.0)
 414                ;;
 415        2.2*)   [enable_apache_22]=yes
 416                [with_apxs22]=$xs
 417                AC_MSG_RESULT(2.2)
 418                ;;
 419        *)      AC_MSG_ERROR(unusable apache versions: $v. Try setting --with-apxs)
 420      esac
 421   else
 422      AC_MSG_RESULT(cannot determine version.  Try setting --with-apxs)
 423   fi
 424 fi
 425
 426
 427 # Apache 1.3 (mod_shib_13)
 428 #   --enable-apache-13
 429 #   --with-apxs      (DSO build, the normal way, uses apxs to derive build flags)
 430
 431 AC_ARG_ENABLE(apache-13,
 432         AC_HELP_STRING([--enable-apache-13], [enable the Apache 1.3 module]),
 433         [ if test "x$enableval" = "x" ; then
 434               WANT_APACHE_13=yes
 435           else
 436               WANT_APACHE_13="$enableval"
 437           fi
 438         ],[ WANT_APACHE_13=no ])
 439 AC_MSG_CHECKING(whether to build Apache 1.3 module)
 440 if test "$WANT_APACHE_13" != yes && test "$WANT_APACHE_13" != no ; then
 441    WANT_APACHE_13=yes
 442 fi
 443 AC_MSG_RESULT($WANT_APACHE_13)
 444
 445 if test "$WANT_APACHE_13" = "yes" ; then
 446     AC_ARG_WITH(apxs,
 447         AC_HELP_STRING([--with-apxs=FILE], [Specifies where to find the Apache 1.3 apxs script.]),
 448         [
 449         AC_MSG_CHECKING(for user-specified apxs name/location)
 450         if test "$withval" != "no" ; then
 451           if test "$withval" != "yes"; then
 452             APXS=$withval
 453             AC_MSG_RESULT("$withval")
 454           fi
 455         fi
 456         ],
 457         [
 458         AC_PATH_PROG(APXS, apxs, no)
 459         if test "$APXS" = "no" ; then
 460           for i in /usr/sbin /usr/local/apache/bin ; do
 461             if test "$APXS" = "no" && test -f "$i/apxs"; then
 462               APXS="$i/apxs"
 463             fi
 464           done
 465         fi
 466         ])
 467
 468     AC_MSG_CHECKING([to see if apxs was located])
 469     if test ! -f "$APXS" ; then
 470         AC_MSG_RESULT(no)
 471         AC_MSG_ERROR([Unable to locate apxs script. An Apache development package may be missing from your server, or you may need to use the --with-apxs option.])
 472     fi
 473     AC_MSG_RESULT($APXS)
 474     AC_SUBST(APXS)
 475
 476     # extract settings we need from APXS -q
 477     APXS_CC="`$APXS -q CC`"
 478     APXS_CFLAGS="`$APXS -q CPPFLAGS` `$APXS -q CFLAGS` `$APXS -q CFLAGS_SHLIB`"
 479     APXS_INCLUDE="`$APXS -q INCLUDEDIR`"
 480 fi
 481
 482 AC_SUBST(APXS_CFLAGS)
 483 AC_SUBST(APXS_INCLUDE)
 484
 485
 486 # Apache 2.0 (mod_shib_20)
 487 #   --enable-apache-20
 488 #   --with-apxs2      (DSO build, the normal way, uses apxs to derive build flags)
 489 #       --with-apr        (DSO build, APR development package installed separately)
 490
 491 AC_ARG_ENABLE(apache-20,
 492         AC_HELP_STRING([--enable-apache-20], [enable the Apache 2.0 module]),
 493         [ if test "x$enableval" = "x" ; then
 494               WANT_APACHE_20=yes
 495           else
 496               WANT_APACHE_20="$enableval"
 497           fi
 498         ],[ WANT_APACHE_20=no ])
 499 AC_MSG_CHECKING(whether to build Apache 2.0 module)
 500 if test "$WANT_APACHE_20" != yes && test "$WANT_APACHE_20" != no ; then
 501    WANT_APACHE_20=yes
 502 fi
 503 AC_MSG_RESULT($WANT_APACHE_20)
 504
 505 if test "$WANT_APACHE_20" = "yes" ; then
 506     AC_ARG_WITH(apxs2,
 507         AC_HELP_STRING([--with-apxs2=FILE], [Specifies where to find the Apache 2.0 apxs script.]),
 508         [
 509         AC_MSG_CHECKING(for user-specified Apache2 apxs name/location)
 510         if test "$withval" != "no" ; then
 511           if test "$withval" != "yes"; then
 512             APXS2=$withval
 513             AC_MSG_RESULT("$withval")
 514           fi
 515         fi
 516         ],
 517         [
 518         AC_PATH_PROG(APXS2, apxs2, no)
 519         if test "$APXS2" = "no" ; then
 520             AC_PATH_PROG(APXS2, apxs, no)
 521         fi
 522         if test "$APXS2" = "no" ; then
 523           for i in /usr/sbin /usr/local/apache2/bin /usr/local/apache/bin ; do
 524             if test "$APXS2" = "no" && test -f "$i/apxs2" ; then
 525               APXS2="$i/apxs2"
 526             fi
 527           done
 528           if test "$APXS2" = "no" ; then
 529             for i in /usr/sbin /usr/local/apache2/bin /usr/local/apache/bin ; do
 530               if test "$APXS2" = "no" && test -f "$i/apxs" ; then
 531                 APXS2="$i/apxs"
 532               fi
 533             done
 534           fi
 535         fi
 536         ])
 537
 538     AC_MSG_CHECKING([to see if Apache2 apxs was located])
 539     if test ! -f "$APXS2" ; then
 540         AC_MSG_RESULT(no)
 541         AC_MSG_ERROR([Unable to locate Apache2 apxs script. An Apache development package may be missing from your server, or you may need to use the --with-apxs2 option.])
 542     fi
 543     AC_MSG_RESULT($APXS2)
 544     AC_SUBST(APXS2)
 545
 546     # APR settings
 547     AC_ARG_WITH(apr,
 548         AC_HELP_STRING([--with-apr=PATH], [where apr-config is installed]),
 549         [
 550         AC_MSG_CHECKING(for user-specified apr-config name/location)
 551         if test "$withval" != "no" ; then
 552             if test "$withval" != "yes"; then
 553                 APR_CONFIG=$withval
 554                 AC_MSG_RESULT("$withval")
 555             fi
 556         fi
 557         ],
 558         [
 559         AC_PATH_PROG(APR_CONFIG, apr-config,,[`$APXS2 -q SBINDIR`]:[$PATH])
 560         ])
 561         if test -f "${APR_CONFIG}"; then
 562         APR_CFLAGS="`${APR_CONFIG} --cflags` `${APR_CONFIG} --cppflags` `${APR_CONFIG} --includes`"
 563     else
 564         AC_MSG_ERROR([Unable to locate apr-config, may need --with-apr option.])
 565     fi
 566
 567     # extract settings we need from APXS2 -q
 568     APXS2_CC="`$APXS2 -q CC`"
 569     APXS2_CFLAGS="`$APXS2 -q CPPFLAGS` `$APXS2 -q CFLAGS` `$APXS2 -q CFLAGS_SHLIB` $APR_CFLAGS"
 570     APXS2_INCLUDE="`$APXS2 -q INCLUDEDIR`"
 571 fi
 572
 573 AC_SUBST(APXS2_CFLAGS)
 574 AC_SUBST(APXS2_INCLUDE)
 575
 576
 577 # Apache 2.2 (mod_shib_22)
 578 #   --enable-apache-22
 579 #   --with-apxs22     (DSO build, the normal way, uses apxs to derive build flags)
 580 #       --with-apr1       (DSO build, APR development package installed separately)
 581
 582 AC_ARG_ENABLE(apache-22,
 583         AC_HELP_STRING([--enable-apache-22], [enable the Apache 2.2 module]),
 584         [ if test "x$enableval" = "x" ; then
 585               WANT_APACHE_22=yes
 586           else
 587               WANT_APACHE_22="$enableval"
 588           fi
 589         ],[ WANT_APACHE_22=no ])
 590 AC_MSG_CHECKING(whether to build Apache 2.2 module)
 591 if test "$WANT_APACHE_22" != yes && test "$WANT_APACHE_22" != no ; then
 592    WANT_APACHE_22=yes
 593 fi
 594 AC_MSG_RESULT($WANT_APACHE_22)
 595
 596 if test "$WANT_APACHE_22" = "yes" ; then
 597     AC_ARG_WITH(apxs22,
 598         AC_HELP_STRING([--with-apxs22=FILE], [Specifies where to find the Apache 2.2 apxs script.]),
 599         [
 600         AC_MSG_CHECKING(for user-specified Apache2.2 apxs name/location)
 601         if test "$withval" != "no" ; then
 602           if test "$withval" != "yes"; then
 603             APXS22=$withval
 604             AC_MSG_RESULT("$withval")
 605           fi
 606         fi
 607         ],
 608         [
 609         AC_PATH_PROG(APXS22, apxs2, no)
 610         if test "$APXS22" = "no" ; then
 611             AC_PATH_PROG(APXS22, apxs, no)
 612         fi
 613         if test "$APXS22" = "no" ; then
 614           for i in /usr/sbin /usr/local/apache2/bin /usr/local/apache/bin ; do
 615             if test "$APXS22" = "no" && test -f "$i/apxs2" ; then
 616               APXS22="$i/apxs2"
 617             fi
 618           done
 619           if test "$APXS22" = "no" ; then
 620             for i in /usr/sbin /usr/local/apache2/bin /usr/local/apache/bin ; do
 621               if test "$APXS22" = "no" && test -f "$i/apxs" ; then
 622                 APXS22="$i/apxs"
 623               fi
 624             done
 625           fi
 626         fi
 627         ])
 628
 629     AC_MSG_CHECKING([to see if Apache2.2 apxs was located])
 630     if test ! -f "$APXS22" ; then
 631         AC_MSG_RESULT(no)
 632         AC_MSG_ERROR([Unable to locate Apache2.2 apxs script. An Apache development package may be missing from your server, or you may need to use the --with-apxs22 option.])
 633     fi
 634     AC_MSG_RESULT($APXS22)
 635     AC_SUBST(APXS22)
 636
 637     # APR1 settings
 638     AC_ARG_WITH(apr1,
 639         AC_HELP_STRING([--with-apr1=PATH], [where apr-1-config is installed]),
 640         [
 641         AC_MSG_CHECKING(for user-specified apr-1-config name/location)
 642         if test "$withval" != "no" ; then
 643             if test "$withval" != "yes"; then
 644                 APR1_CONFIG=$withval
 645                 AC_MSG_RESULT("$withval")
 646             fi
 647         fi
 648         ],
 649         [
 650         AC_PATH_PROG(APR1_CONFIG, apr-1-config,,[`$APXS22 -q SBINDIR`]:[$PATH])
 651         ])
 652         if test -f "${APR1_CONFIG}"; then
 653         APR1_CFLAGS="`${APR1_CONFIG} --cflags` `${APR1_CONFIG} --cppflags` `${APR1_CONFIG} --includes`"
 654     else
 655         AC_MSG_ERROR([Unable to locate apr-1-config, may need --with-apr1 option.])
 656     fi
 657
 658     # extract settings we need from APXS22 -q
 659     APXS22_CC="`$APXS22 -q CC`"
 660     APXS22_CFLAGS="`$APXS22 -q CPPFLAGS` `$APXS22 -q CFLAGS` `$APXS22 -q CFLAGS_SHLIB` $APR1_CFLAGS"
 661     APXS22_INCLUDE="`$APXS22 -q INCLUDEDIR`"
 662 fi
 663
 664 AC_SUBST(APXS22_CFLAGS)
 665 AC_SUBST(APXS22_INCLUDE)
 666
 667 # always output the Makefile, even if you don't use it
 668 AC_CONFIG_FILES([apache/Makefile])
 669 AM_CONDITIONAL(BUILD_AP13,test "$WANT_APACHE_13" = "yes")
 670 AM_CONDITIONAL(BUILD_AP20,test "$WANT_APACHE_20" = "yes")
 671 AM_CONDITIONAL(BUILD_AP22,test "$WANT_APACHE_22" = "yes")
 672
 673 # add the apache module to the list of wanted subdirs..
 674 if test "$WANT_APACHE_13" = "yes" || test "$WANT_APACHE_20" = "yes" || test "$WANT_APACHE_22" = "yes" ; then
 675     WANT_SUBDIRS="$WANT_SUBDIRS apache"
 676 fi
 677
 678
 679 #
 680 # Implement the checks of the MySQL Credential Cache
 681 #
 682 # 1) Assume the user wants MySQL; if it's not found then just continue without
 683 # 2) If the user specifically requested Mysql, look for it and ERROR if not found
 684 # 3) If the user specifically requested no-mysql, don't build it.
 685 #
 686
 687 AC_CONFIG_FILES([shib-mysql-ccache/Makefile])
 688
 689 # determine whether we should enable the mysql ccache
 690 AC_ARG_ENABLE([mysql],
 691         AC_HELP_STRING([--disable-mysql], [disable the MySQL Credential Cache]),
 692         [mysql_enabled=$enableval], [mysql_enabled=default])
 693
 694 if test "x$mysql_enabled" = "x" ; then
 695    mysql_enabled=yes
 696 fi
 697
 698 # Are we trying to build MySQL?
 699 AC_MSG_CHECKING(whether to build the MySQL ccache)
 700 if test "$mysql_enabled" = "yes" ; then
 701    build_mysql=yes
 702    AC_MSG_RESULT(yes)
 703 elif test "$mysql_enabled" = "default" ; then
 704    build_mysql=yes
 705    AC_MSG_RESULT([yes, if it can be found])
 706 else
 707    build_mysql=no
 708    AC_MSG_RESULT(no)
 709 fi
 710
 711 # If we're trying to build MySQL, try to find the mysql_config program,
 712 # verify we've got mysql >= 4, and make sure we can build with mysqld
 713 if test "$build_mysql" = "yes" ; then
 714    mysql_dir=""
 715    AC_ARG_WITH(mysql,
 716         AC_HELP_STRING([--with-mysql=PATH], [directory where mysql is installed]),
 717             [if test "$with_mysql" = no ; then
 718              AC_MSG_ERROR([Try running --disable-mysql instead.])
 719          elif test "$with_mysql" != yes ; then
 720              mysql_dir="$with_mysql/bin"
 721          fi ])
 722
 723    # Try to find the mysql_config program
 724    AC_PATH_PROG(MYSQL_CONFIG, mysql_config, no, $mysql_dir $PATH )
 725
 726    if test "$MYSQL_CONFIG" = no ; then
 727       if test "$mysql_enabled" = "yes" ; then
 728         AC_MSG_ERROR(Cannot find mysql_config)
 729       else
 730         AC_MSG_WARN(MySQL not found.  skipping.)
 731       fi
 732    fi
 733 fi
 734
 735 # if we found mysql_config then build_mysql is 'yes'
 736 if test "$MYSQL_CONFIG" != no ; then
 737    AC_MSG_CHECKING(for mysql version >= 4)
 738    mysql_version=`$MYSQL_CONFIG --version`
 739    mysql_major_version=`echo $mysql_version | awk -F. '{print $1}'`
 740    mysql_version_ok=yes
 741    if test $mysql_major_version -lt 4 ; then
 742      mysql_version_ok=no
 743      if test "$mysql_enabled" = "yes" ; then
 744        AC_MSG_ERROR(You need MySQL version >= 4, found $mysql_version)
 745      fi
 746      AC_MSG_RESULT(no.. skipping MySQL)
 747    else
 748      AC_MSG_RESULT(yes)
 749    fi
 750 fi
 751
 752 # if mysql_version_ok is 'yes', then we've made it this far.. ;)
 753 if test "$mysql_version_ok" = "yes" ; then
 754    AC_MSG_CHECKING(for embedded-MySQL libraries)
 755    MYSQL_LIBS=`$MYSQL_CONFIG --libmysqld-libs`
 756    if test $? != 0 ; then
 757       found_mysql=no
 758       if test "$mysql_enabled" = "yes" ; then
 759         AC_MSG_ERROR(Could not find the MySQL Embedded-server libraries.)
 760       else
 761         AC_MSG_RESULT(no.. skipping MySQL)
 762       fi
 763    else
 764       found_mysql=yes
 765       AC_MSG_RESULT(yes)
 766    fi
 767 fi
 768
 769 # if found_mysql=yes then test that we can actually build mysql
 770 if test "$found_mysql" = yes ; then
 771    MYSQL_CFLAGS=`$MYSQL_CONFIG --cflags`
 772    MYSQL_CFLAGS=`eval echo $MYSQL_CFLAGS`
 773    MYSQL_LIBS=`eval echo $MYSQL_LIBS`
 774
 775    save_CPPFLAGS="$CPPFLAGS"
 776    CPPFLAGS="$CPPFLAGS $MYSQL_CFLAGS"
 777
 778    AC_CHECK_HEADER([mysql.h], [have_mysql_h=yes], [have_mysql_h=no])
 779    if test "$have_mysql_h" = no -a "$mysql_enabled" = "yes" ; then
 780      AC_MSG_ERROR(unable to find MySQL header files)
 781    fi
 782
 783    if test "$have_mysql_h" = yes ; then
 784       save_LIBS="$LIBS"
 785       LIBS="$LIBS $MYSQL_LIBS"
 786       AC_MSG_CHECKING(if we can link againt mysql)
 787       AC_TRY_LINK(
 788         [#include <mysql.h>
 789          #include <stdio.h>],
 790         [mysql_server_init(0, NULL, NULL)],
 791         [have_mysql_libs=yes],
 792         [have_mysql_libs=no])
 793       LIBS="$save_LIBS"
 794
 795       if test "$have_mysql_libs" = no ; then
 796          if test "$mysql_enabled" = "yes" ; then
 797             AC_MSG_ERROR([unable to link with MySQL Embedded Server Library])
 798          else
 799             AC_MSG_RESULT(no.  skipping MySQL)
 800          fi
 801       fi
 802    fi
 803
 804    CPPFLAGS="$save_CPPFLAGS"
 805 fi
 806
 807 # if have_mysql_libs=yes then go ahead with building MySQL
 808 if test "$have_mysql_libs" = yes ; then
 809    # this AC_MSG_RESULT is from above!
 810    AC_MSG_RESULT(yes)
 811    WANT_SUBDIRS="$WANT_SUBDIRS shib-mysql-ccache"
 812    AC_SUBST(MYSQL_CFLAGS)
 813    AC_SUBST(MYSQL_LIBS)
 814 fi
 815
 816
 817 AC_SUBST(WANT_SUBDIRS)
 818
 819 if test -n "$APXS_CC" && test "$APXS_CC" != "$CC" ; then
 820   echo "=================================================================="
 821   echo "WARNING: You have chosen to compile Apache-1.3 modules with a different"
 822   echo "         compiler than the one used to compile Apache."
 823   echo ""
 824   echo "    Current compiler:      $CC"
 825   echo "   Apache's compiler:      $APXS_CC"
 826   echo ""
 827   echo "This could cause problems."
 828   echo "=================================================================="
 829 fi
 830
 831 if test -n "$APXS2_CC" && test "$APXS2_CC" != "$CC" ; then
 832   echo "=================================================================="
 833   echo "WARNING: You have chosen to compile Apache-2 modules with a different"
 834   echo "         compiler than the one used to compile Apache."
 835   echo ""
 836   echo "    Current compiler:      $CC"
 837   echo "   Apache's compiler:      $APXS2_CC"
 838   echo ""
 839   echo "This could cause problems."
 840   echo "=================================================================="
 841 fi
 842
 843 LIBTOOL="$LIBTOOL --silent"
 844
 845 AC_OUTPUT
 846