configure.ac

   1 AC_PREREQ([2.50])
   2 AC_INIT([shibboleth], [2.2.1], [shibboleth-users@internet2.edu], [shibboleth])
   3 AM_CONFIG_HEADER(config.h)
   4 AM_INIT_AUTOMAKE([shibboleth],[2.2.1])
   5
   6 sinclude(doxygen.m4)
   7 sinclude(acx_pthread.m4)
   8
   9 # Docygen features
  10 DX_HTML_FEATURE(ON)
  11 DX_CHM_FEATURE(OFF)
  12 DX_CHI_FEATURE(OFF)
  13 DX_MAN_FEATURE(OFF)
  14 DX_RTF_FEATURE(OFF)
  15 DX_XML_FEATURE(OFF)
  16 DX_PDF_FEATURE(OFF)
  17 DX_PS_FEATURE(OFF)
  18 DX_INIT_DOXYGEN(shibboleth, doxygen.cfg, doc/api)
  19 DX_INCLUDE=
  20
  21 AC_ARG_ENABLE(debug,
  22     AC_HELP_STRING(--enable-debug, [Have GCC compile with symbols (Default = no)
  23 ]),
  24     enable_debug=$enableval, enable_debug=no)
  25
  26 if test "$enable_debug" = "yes" ; then
  27     GCC_CFLAGS="$CFLAGS -g -D_DEBUG"
  28     GCC_CXXFLAGS="$CXXFLAGS -g -D_DEBUG"
  29 else
  30     GCC_CFLAGS="$CFLAGS -O2 -DNDEBUG"
  31     GCC_CXXFLAGS="$CXXFLAGS -O2 -DNDEBUG"
  32 fi
  33
  34 AC_PROG_CC([gcc gcc3 cc])
  35 AC_PROG_CXX([g++ g++3 c++ CC])
  36 AC_CANONICAL_HOST
  37
  38 if test "$GCC" = "yes" ; then
  39 #    AC_HAVE_GCC_VERSION(4,0,0,0,
  40 #        [
  41 #        AC_DEFINE(GCC_HASCLASSVISIBILITY,1,
  42 #            [Define to enable class visibility control in gcc.])
  43 #        GCC_CFLAGS="$GCC_CFLAGS -fvisibility=hidden -fvisibility-inlines-hidden"
  44 #        GCC_CXXFLAGS="$GCC_CXXFLAGS -fvisibility=hidden -fvisibility-inlines-hidden"
  45 #        ])
  46     CFLAGS="-Wall $GCC_CFLAGS"
  47     CXXFLAGS="-Wall $GCC_CXXFLAGS"
  48 else
  49 # Fix for Sun Workshop compiler in debug mode, may be Sun case #6360993
  50         case "${host_cpu}-${host_os}" in
  51                 *solaris*)
  52                         if test "$CXX" = "CC" ; then
  53                                 CXXFLAGS="$CXXFLAGS -Qoption ccfe -stabs=no%dfltlit+no%dflthlp"
  54                         fi
  55                         ;;
  56                 *osf*)
  57                         CXXFLAGS="$CXXFLAGS -D_POSIX_PII_SOCKET"
  58                         ;;
  59         esac
  60 fi
  61
  62 AC_DISABLE_STATIC
  63 AC_PROG_LIBTOOL
  64
  65 AC_LANG(C)
  66
  67 # Checks for typedefs, structures, and compiler characteristics.
  68 AC_C_CONST
  69 AC_TYPE_SIZE_T
  70 AC_STRUCT_TM
  71
  72 # Checks for library functions.
  73 AC_FUNC_STRFTIME
  74 AC_FUNC_STRERROR_R
  75 AC_CHECK_FUNCS([strchr strdup strstr timegm gmtime_r strtok_r strcasecmp])
  76
  77 # checks for pthreads
  78 ACX_PTHREAD([enable_threads="pthread"],[enable_threads="no"])
  79 if test $enable_threads != "pthread"; then
  80     AC_MSG_ERROR([unable to find pthreads, currently this is required])
  81 else
  82     AC_DEFINE(HAVE_PTHREAD,1,[Define if you have POSIX threads libraries and header files.])
  83     LIBS="$PTHREAD_LIBS $LIBS"
  84     CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
  85     CXXFLAGS="$PTHREAD_CFLAGS $CXXFLAGS"
  86 fi
  87
  88 # OpenSSL settings
  89 AC_ARG_WITH(openssl,
  90     AC_HELP_STRING([--with-openssl=PATH], [where openssl is installed]),
  91     [if test x_$with_openssl != x_/usr; then
  92         SSLFLAGS="-I${with_openssl}/include"
  93     fi])
  94
  95 if test "x$SSLFLAGS" = "x" ; then
  96     AC_PATH_PROG(PKG_CONFIG, pkg-config)
  97     if test "x$PKG_CONFIG" != x && test "x$PKG_CONFIG" != "xno" ; then
  98         if pkg-config openssl ; then
  99             SSLFLAGS="`$PKG_CONFIG --cflags openssl`"
 100         else
 101             AC_MSG_ERROR([OpenSSL not supported by pkg-config, try --with-openssl instead])
 102         fi
 103     fi
 104 fi
 105
 106 AC_MSG_CHECKING(for OpenSSL cflags)
 107 AC_MSG_RESULT($SSLFLAGS)
 108 CPPFLAGS="$SSLFLAGS $CPPFLAGS"
 109
 110 AC_CHECK_HEADER([openssl/x509.h],,
 111                 AC_MSG_ERROR([unable to find openssl header files]))
 112
 113 AC_LANG(C++)
 114
 115 # C++ requirements
 116 AC_CXX_REQUIRE_STL
 117 AC_CXX_NAMESPACES
 118
 119 # Thank you Solaris, really.
 120 AC_MSG_CHECKING(for ctime_r)
 121  if test -z "$ac_cv_ctime_args"; then
 122      AC_TRY_COMPILE(
 123      [#include <time.h>],
 124      [
 125          time_t clock;
 126          char buf[26];
 127          ctime_r(&clock, buf);
 128      ], ac_cv_ctime_args=2)
 129
 130      AC_TRY_COMPILE(
 131      [#include <time.h>],
 132      [
 133          time_t clock;
 134          char buf[26];
 135          ctime_r(&clock, buf, 26);
 136      ], ac_cv_ctime_args=3)
 137  fi
 138  if test -z "$ac_cv_ctime_args"; then
 139      AC_MSG_RESULT(no)
 140  else
 141      if test "$ac_cv_ctime_args" = 2; then
 142          AC_DEFINE(HAVE_CTIME_R_2,1,[Define if ctime_r is present with 2 parameters.])
 143      elif test "$ac_cv_ctime_args" = 3; then
 144          AC_DEFINE(HAVE_CTIME_R_3,1,[Define if ctime_r is present with 3 parameters.])
 145      fi
 146      AC_MSG_RESULT([yes, and it takes $ac_cv_ctime_args arguments])
 147  fi
 148
 149 # log4shib settings (favor this version over the log4cpp code)
 150 AC_PATH_PROG(LOG4SHIB_CONFIG,log4shib-config)
 151 AC_ARG_WITH(log4shib,
 152     AC_HELP_STRING([--with-log4shib=PATH], [where log4shib-config is installed]),
 153     [
 154     LOG4SHIB_CONFIG="${with_log4shib}"
 155     if ! test -f "${LOG4SHIB_CONFIG}" ; then
 156         LOG4SHIB_CONFIG="${with_log4shib}/bin/log4shib-config"
 157     fi
 158     ])
 159 if test -f "${LOG4SHIB_CONFIG}"; then
 160     LDFLAGS="`${LOG4SHIB_CONFIG} --libs` $LDFLAGS"
 161     CPPFLAGS="`${LOG4SHIB_CONFIG} --cflags` $CPPFLAGS"
 162         AC_CHECK_HEADER([log4shib/CategoryStream.hh],,AC_MSG_ERROR([unable to find log4shib header files]))
 163         AC_TRY_LINK(
 164                 [#include <log4shib/Category.hh>
 165 #include <log4shib/CategoryStream.hh>],
 166                 [log4shib::Category::getInstance("foo").errorStream() << log4shib::eol],
 167                 [AC_DEFINE(SHIBSP_LOG4SHIB,1,[Define if log4shib library is used.])],
 168                 [AC_MSG_ERROR([unable to link with log4shib])])
 169 else
 170     AC_MSG_WARN([log4shib-config not found, may need to use --with-log4shib option])
 171     AC_MSG_WARN([will look for original log4cpp library])
 172
 173         # log4cpp settings
 174         AC_PATH_PROG(LOG4CPP_CONFIG,log4cpp-config)
 175         AC_ARG_WITH(log4cpp,
 176             AC_HELP_STRING([--with-log4cpp=PATH], [where log4cpp-config is installed]),
 177             [
 178             LOG4CPP_CONFIG="${with_log4cpp}"
 179             if ! test -f "${LOG4CPP_CONFIG}" ; then
 180                 LOG4CPP_CONFIG="${with_log4cpp}/bin/log4cpp-config"
 181             fi
 182             ])
 183         if test -f "${LOG4CPP_CONFIG}"; then
 184                 AC_MSG_WARN([will try to use log4cpp, note that most non-Internet2 supplied versions are not thread-safe])
 185             LDFLAGS="`${LOG4CPP_CONFIG} --libs` $LDFLAGS"
 186             CPPFLAGS="`${LOG4CPP_CONFIG} --cflags` $CPPFLAGS"
 187                 AC_CHECK_HEADER([log4cpp/CategoryStream.hh],,AC_MSG_ERROR([unable to find log4cpp header files]))
 188                 AC_TRY_LINK(
 189                         [#include <log4cpp/Category.hh>
 190 #include <log4cpp/CategoryStream.hh>],
 191                         [log4cpp::Category::getInstance("foo").errorStream() << log4cpp::eol],
 192                         [AC_DEFINE(SHIBSP_LOG4CPP,1,[Define if log4cpp library is used.])],
 193                         [AC_MSG_ERROR([unable to link with log4cpp, need version 1.0 or later])])
 194         else
 195             AC_MSG_ERROR([log4cpp-config not found, may need to use --with-log4cpp option])
 196         fi
 197 fi
 198
 199 # Xerces settings
 200 AC_ARG_WITH(xerces,
 201             AC_HELP_STRING([--with-xerces=PATH], [where xerces-c is installed]),
 202             [if test x_$with_xerces != x_/usr; then
 203                 LDFLAGS="-L${with_xerces}/lib $LDFLAGS"
 204                 CPPFLAGS="-I${with_xerces}/include $CPPFLAGS"
 205             fi])
 206 LIBS="-lxerces-c $LIBS"
 207 AC_CHECK_HEADER([xercesc/dom/DOM.hpp],,
 208                 AC_MSG_ERROR([unable to find xerces header files]))
 209 AC_MSG_CHECKING([Xerces version])
 210 AC_PREPROC_IFELSE(
 211     [AC_LANG_PROGRAM([#include <xercesc/util/XercesVersion.hpp>],
 212 [#if  _XERCES_VERSION != 20600
 213 int i = 0;
 214 #else
 215 #error cannot use version 2.6.0
 216 #endif])],
 217     [AC_MSG_RESULT(OK)],
 218     [AC_MSG_FAILURE([Xerces-C v2.6.0 has bugs that inhibit use with signed XML, please use a newer version])])
 219 AC_TRY_LINK(
 220         [#include <xercesc/util/PlatformUtils.hpp>],
 221         [xercesc::XMLPlatformUtils::Initialize()],
 222         [AC_DEFINE(HAVE_LIBXERCESC,1,[Define if Xerces-C library was found])],
 223         [AC_MSG_ERROR([unable to link with Xerces])])
 224
 225 AC_MSG_CHECKING([whether Xerces XMLString::release(XMLByte**) exists])
 226 AC_TRY_COMPILE([#include <xercesc/util/XMLString.hpp>],
 227     [using namespace XERCES_CPP_NAMESPACE;
 228       XMLByte* buf=NULL;
 229       XMLString::release(&buf);
 230     ],
 231     [AC_MSG_RESULT([yes])]
 232     [AC_DEFINE([SHIBSP_XERCESC_HAS_XMLBYTE_RELEASE], [1], [Define to 1 if Xerces XMLString includes XMLByte release.])],
 233     [AC_MSG_RESULT([no])])
 234
 235 AC_MSG_CHECKING([whether Xerces DOMNodeFilter API returns a short])
 236 AC_TRY_COMPILE([#include <xercesc/dom/DOM.hpp>],
 237     [using namespace XERCES_CPP_NAMESPACE;
 238       class Blocker : public DOMNodeFilter {
 239       public:
 240         short acceptNode(const DOMNode* node) const {
 241             return FILTER_REJECT;
 242         }
 243       };
 244       static Blocker g_Blocker;
 245     ],
 246     [AC_MSG_RESULT([yes])]
 247     [AC_DEFINE([SHIBSP_XERCESC_SHORT_ACCEPTNODE], [1], [Define to 1 if Xerces DOMNodeFilter API returns a short.])],
 248     [AC_MSG_RESULT([no])])
 249
 250 #XML-Tooling settings
 251 AC_ARG_WITH(xmltooling,
 252             AC_HELP_STRING([--with-xmltooling=PATH], [where xmltooling-c is installed]),
 253             [if test x_$with_xmltooling != x_/usr; then
 254                 LDFLAGS="-L${with_xmltooling}/lib $LDFLAGS"
 255                 CPPFLAGS="-I${with_xmltooling}/include $CPPFLAGS"
 256             fi])
 257 LITE_LIBS="-lxmltooling-lite"
 258 XMLSEC_LIBS="-lxmltooling"
 259 AC_CHECK_HEADER([xmltooling/base.h],,
 260                 AC_MSG_ERROR([unable to find xmltooling header files]))
 261
 262 # Establish location of xmltooling catalog.
 263 XMLTOOLINGXMLDIR=""
 264 if test "x$with_xmltooling" = "x" ; then
 265    with_xmltooling="/usr"
 266 fi
 267 if test -f $with_xmltooling/share/xml/xmltooling/catalog.xml ; then
 268     XMLTOOLINGXMLDIR="$with_xmltooling"
 269 elif test -f $with_xerces/share/xml/xmltooling/catalog.xml ; then
 270     XMLTOOLINGXMLDIR="$with_xerces"
 271 elif test -f $with_log4shib/share/xml/xmltooling/catalog.xml ; then
 272     XMLTOOLINGXMLDIR="$with_log4shib"
 273 fi
 274 if test "x$XMLTOOLINGXMLDIR" = "x" ; then
 275     AC_MSG_ERROR([xmltooling XML catalog not found, may need to use --with-xmltooling option])
 276 fi
 277 XMLTOOLINGXMLDIR="$XMLTOOLINGXMLDIR/share/xml/xmltooling"
 278 AC_SUBST(XMLTOOLINGXMLDIR)
 279
 280 # XML-Security settings
 281 AC_ARG_WITH(xmlsec,
 282             AC_HELP_STRING([--with-xmlsec=PATH], [where xmlsec is installed]),,
 283             [with_xmlsec=/usr])
 284
 285 if test x_$with_xmlsec != x_/usr; then
 286     LDFLAGS="-L${with_xmlsec}/lib $LDFLAGS"
 287     CPPFLAGS="-I${with_xmlsec}/include $CPPFLAGS"
 288 fi
 289 XMLSEC_LIBS="-lxml-security-c $XMLSEC_LIBS"
 290
 291 # save and append master libs
 292 save_LIBS="$LIBS"
 293 LIBS="$XMLSEC_LIBS $LIBS"
 294
 295 AC_CHECK_HEADER([xsec/utils/XSECPlatformUtils.hpp],,AC_MSG_ERROR([unable to find XML-Security header files]))
 296 AC_MSG_CHECKING([XML-Security version])
 297 AC_PREPROC_IFELSE(
 298     [AC_LANG_PROGRAM([#include <xsec/utils/XSECPlatformUtils.hpp>],
 299     [#if XSEC_VERSION_MAJOR > 1 || (XSEC_VERSION_MAJOR == 1 && XSEC_VERSION_MEDIUM > 3)
 300 int i = 0;
 301 #else
 302 #error need version 1.4.0 or later
 303 #endif])],
 304     [AC_MSG_RESULT(OK)],
 305     [AC_MSG_FAILURE([XML-Security version 1.4.0 or greater is required.])])
 306 AC_TRY_LINK(
 307         [#include <xsec/utils/XSECPlatformUtils.hpp>],
 308         [XSECPlatformUtils::Initialise()],,
 309         [AC_MSG_ERROR([unable to link with XML-Security])])
 310
 311 # restore master libs
 312 LIBS="$save_LIBS"
 313
 314 # OpenSAML settings
 315 AC_ARG_WITH(saml,
 316     AC_HELP_STRING([--with-saml=PATH], [where saml is installed]),
 317     [if test x_$with_saml != x_/usr; then
 318         LDFLAGS="-L${with_saml}/lib $LDFLAGS"
 319         CPPFLAGS="-I${with_saml}/include $CPPFLAGS"
 320     fi])
 321 XMLSEC_LIBS="-lsaml $XMLSEC_LIBS"
 322
 323 # save and append master libs
 324 save_LIBS="$LIBS"
 325 LIBS="$XMLSEC_LIBS $LIBS"
 326
 327 AC_CHECK_HEADER([saml/saml2/metadata/Metadata.h],,
 328                 AC_MSG_ERROR([unable to find OpenSAML header files]))
 329 AC_TRY_LINK(
 330         [#include <saml/SAMLConfig.h>
 331 #include <saml/version.h>],
 332         [#if _OPENSAML_VERSION >= 20200
 333 opensaml::SAMLConfig::getConfig();
 334 #else
 335 #error Need OpenSAML version 2.2 or higher
 336 #endif],
 337         [AC_DEFINE(HAVE_SAML,1,[Define if saml library was found])],
 338         [AC_MSG_ERROR([unable to link with OpenSAML, or version was too old])])
 339
 340 # restore master libs
 341 LIBS="$save_LIBS"
 342
 343 # Establish location of opensaml catalogs.
 344 OPENSAMLXMLDIR=""
 345 if test "x$with_saml" = "x" ; then
 346     with_saml="/usr"
 347 fi
 348 if test -f $with_saml/share/xml/opensaml/saml20-catalog.xml ; then
 349     OPENSAMLXMLDIR="$with_saml"
 350 elif test -f $with_xmltooling/share/xml/opensaml/saml20-catalog.xml ; then
 351     OPENSAMLXMLDIR="$with_xmltooling"
 352 elif test -f $with_xerces/share/xml/opensaml/saml20-catalog.xml ; then
 353     OPENSAMLXMLDIR="$with_xerces"
 354 elif test -f $with_log4shib/share/xml/opensaml/saml20-catalog.xml ; then
 355     OPENSAMLXMLDIR="$with_log4shib"
 356 fi
 357 if test "x$OPENSAMLXMLDIR" = "x" ; then
 358     AC_MSG_ERROR([opensaml XML catalogs not found, may need to use --with-saml option])
 359 fi
 360 OPENSAMLXMLDIR="$OPENSAMLXMLDIR/share/xml/opensaml"
 361 AC_SUBST(OPENSAMLXMLDIR)
 362
 363 AC_SUBST(LITE_LIBS)
 364 AC_SUBST(XMLSEC_LIBS)
 365
 366 # output the underlying makefiles
 367 WANT_SUBDIRS="doc schemas configs shibsp shibd util"
 368 AC_CONFIG_FILES([Makefile doc/Makefile schemas/Makefile \
 369         configs/Makefile shibsp/Makefile shibd/Makefile \
 370         util/Makefile selinux/Makefile])
 371
 372 ## ADFS?
 373 AC_CONFIG_FILES([adfs/Makefile])
 374 AC_ARG_ENABLE([adfs],
 375         AC_HELP_STRING([--disable-adfs], [don't build the ADFS module]),
 376         [adfs_enabled=$enableval], [adfs_enabled=yes])
 377 if test "x$adfs_enabled" = "x" ; then
 378    adfs_enabled=yes
 379 fi
 380 AC_MSG_CHECKING(whether to build the ADFS module)
 381 if test "$adfs_enabled" = "no" ; then
 382    AC_MSG_RESULT(no)
 383 else
 384    AC_MSG_RESULT(yes)
 385    WANT_SUBDIRS="$WANT_SUBDIRS adfs"
 386 fi
 387
 388
 389 #
 390 # Build NSAPI module?
 391 #
 392 AC_MSG_CHECKING(for NSAPI module option)
 393 AC_ARG_WITH(nsapi,
 394         AC_HELP_STRING([--with-nsapi=DIR], [Build NSAPI module for Netscape/iPlanet/SunONE]),
 395         [WANT_NSAPI=$withval],[WANT_NSAPI=no])
 396 AC_MSG_RESULT($WANT_NSAPI)
 397
 398 if test "$WANT_NSAPI" != "no"; then
 399   if test ! -d $WANT_NSAPI/bin ; then
 400     AC_MSG_ERROR(Please specify the path to the root of your Netscape/iPlanet/SunONE server using --with-nsapi=DIR)
 401   fi
 402   AC_MSG_CHECKING(for NSAPI include files)
 403   if test -d $WANT_NSAPI/include ; then
 404     NSAPI_INCLUDE=$WANT_NSAPI/include
 405     AC_MSG_RESULT(Netscape-Enterprise 3.x style)
 406     AC_CHECK_HEADERS([$NSAPI_INCLUDE/nsapi.h],,,[#define XP_UNIX])
 407     NSAPI_INCLUDE="$NSAPI_INC_DIR -I$NSAPI_INCLUDE"
 408   fi
 409   if test -d $WANT_NSAPI/plugins/include ; then
 410     test -n "$NSAPI_INCLUDE" && NSAPI_INC_DIR="-I$NSAPI_INCLUDE"
 411     NSAPI_INCLUDE="$WANT_NSAPI/plugins/include"
 412     AC_MSG_RESULT(iPlanet 4.x / SunONE 6.x style)
 413     AC_CHECK_HEADERS([$NSAPI_INCLUDE/nsapi.h],,,[#define XP_UNIX])
 414     NSAPI_INCLUDE="$NSAPI_INC_DIR -I$NSAPI_INCLUDE"
 415   fi
 416   if test "$NSAPI_INCLUDE" = ""; then
 417     AC_MSG_ERROR(Please check you have nsapi.h in either $WANT_NSAPI/include or $WANT_NSAPI/plugins/include)
 418   fi
 419 fi
 420
 421 AC_SUBST(NSAPI_INCLUDE)
 422
 423 # always output the Makefile, even if you don't use it
 424 AC_CONFIG_FILES([nsapi_shib/Makefile])
 425 AM_CONDITIONAL(BUILD_NSAPI,test ! "$WANT_NSAPI" = "no")
 426
 427 # add the NSAPI module to the list of wanted subdirs..
 428 if test ! "$WANT_NSAPI" = "no" ; then
 429     WANT_SUBDIRS="$WANT_SUBDIRS nsapi_shib"
 430 fi
 431
 432
 433 #
 434 # Build FastCGI support?
 435 #
 436 AC_MSG_CHECKING(for FastCGI support)
 437 AC_ARG_WITH(fastcgi,
 438     AC_HELP_STRING([--with-fastcgi=DIR], [Build FastCGI support]),
 439     [WANT_FASTCGI=$withval],[WANT_FASTCGI=no])
 440 AC_MSG_RESULT($WANT_FASTCGI)
 441
 442 if test "$WANT_FASTCGI" != "no"; then
 443     if test "$WANT_FASTCGI" != "yes"; then
 444         if test x_$WANT_FASTCGI != x_/usr; then
 445             FASTCGI_INCLUDE="-I$WANT_FASTCGI/include"
 446             FASTCGI_LDFLAGS="-L$WANT_FASTCGI/lib"
 447         fi
 448     fi
 449     AC_CHECK_HEADER([fcgio.h],,
 450         AC_MSG_ERROR([unable to find FastCGI header files]))
 451     FASTCGI_LIBS="-lfcgi -lfcgi++"
 452 fi
 453
 454 AC_SUBST(FASTCGI_INCLUDE)
 455 AC_SUBST(FASTCGI_LDFLAGS)
 456 AC_SUBST(FASTCGI_LIBS)
 457
 458 # always output the Makefile, even if you don't use it
 459 AC_CONFIG_FILES([fastcgi/Makefile])
 460 AM_CONDITIONAL(BUILD_FASTCGI,test ! "$WANT_FASTCGI" = "no")
 461
 462 if test ! "$WANT_FASTCGI" = "no" ; then
 463     WANT_SUBDIRS="$WANT_SUBDIRS fastcgi"
 464 fi
 465
 466 #
 467 # Build Memcached support?
 468 #
 469 AC_MSG_CHECKING(for Memcached support)
 470 AC_ARG_WITH(memcached,
 471     AC_HELP_STRING([--with-memcached=DIR], [Build Memcached support]),
 472     [WANT_MEMCACHED=$withval],[WANT_MEMCACHED=no])
 473 AC_MSG_RESULT($WANT_MEMCACHED)
 474
 475 if test "$WANT_MEMCACHED" != "no"; then
 476     if test "$WANT_MEMCACHED" != "yes"; then
 477         if test x_$WANT_MEMCACHED != x_/usr; then
 478             MEMCACHED_INCLUDE="-I$WANT_MEMCACHED/include"
 479             MEMCACHED_LDFLAGS="-L$WANT_MEMCACHED/lib"
 480         fi
 481     fi
 482     AC_CHECK_HEADER([libmemcached/memcached.h],,
 483         AC_MSG_ERROR([unable to find Memcached header files]))
 484     MEMCACHED_LIBS="-lmemcached"
 485 fi
 486
 487 AC_SUBST(MEMCACHED_INCLUDE)
 488 AC_SUBST(MEMCACHED_LDFLAGS)
 489 AC_SUBST(MEMCACHED_LIBS)
 490
 491 # always output the Makefile, even if you don't use it
 492 AC_CONFIG_FILES([memcache-store/Makefile])
 493 AM_CONDITIONAL(BUILD_MEMCACHED,test ! "$WANT_MEMCACHED" = "no")
 494
 495 if test ! "$WANT_MEMCACHED" = "no" ; then
 496     WANT_SUBDIRS="$WANT_SUBDIRS memcache-store"
 497 fi
 498
 499
 500 #
 501 # If no --enable-apache-xx specified
 502 # find a default and fake the specific parameters
 503 #
 504
 505 # simple macro to peek at an enable or a with
 506 AC_DEFUN([Peek],
 507 if test "[${[$1]_][$2]+set}" = set; then
 508   peekval="${[$1]_[$2]}"
 509   $3
 510 fi; dnl
 511 )
 512
 513 AC_MSG_CHECKING(if default apache needed)
 514 need_default=yes
 515 Peek(enable,apache_13,need_default=no)
 516 Peek(enable,apache_20,need_default=no)
 517 Peek(enable,apache_22,need_default=no)
 518 AC_MSG_RESULT($need_default)
 519
 520 if test "$need_default" = "yes"; then
 521   # find an apxs, then the httpd
 522   xs=
 523   Peek(with,apxs,xs="$peekval")
 524   Peek(with,apxs2,xs="$peekval")
 525   Peek(with,apxs22,xs="$peekval")
 526   if test "x$xs" = "x"; then
 527      AC_PATH_PROGS(xs, apxs2 apxs,
 528         AC_MSG_ERROR(No apxs, no apache found.  Try --with-apxs),
 529         [/usr/local/apache2/bin:/usr/local/apache/bin:/usr/sbin:$PATH])
 530   fi
 531   # ask the daemon for the version and set parameters
 532   AC_MSG_CHECKING(default apache version)
 533   httpd="`$xs -q SBINDIR`/`$xs -q TARGET`"
 534   if test "x$httpd" != "x" && test -f $httpd ; then
 535      v=`$httpd -v|$SED -n -e 's/.*Apache\/\.*//p'`
 536      case $v in
 537        1.3*)   [enable_apache_13]=yes
 538                [with_apxs]=$xs
 539                AC_MSG_RESULT(1.3)
 540                ;;
 541        2.0*)   [enable_apache_20]=yes
 542                [with_apxs2]=$xs
 543                AC_MSG_RESULT(2.0)
 544                ;;
 545        2.2*)   [enable_apache_22]=yes
 546                [with_apxs22]=$xs
 547                AC_MSG_RESULT(2.2)
 548                ;;
 549        *)      AC_MSG_ERROR(unusable apache versions: $v. Try setting --with-apxs)
 550      esac
 551   else
 552      AC_MSG_RESULT(cannot determine version.  Try setting --with-apxs)
 553   fi
 554 fi
 555
 556 # Apache 1.3 (mod_shib_13)
 557 #   --enable-apache-13
 558 #   --with-apxs      (DSO build, the normal way, uses apxs to derive build flags)
 559
 560 AC_ARG_ENABLE(apache-13,
 561         AC_HELP_STRING([--enable-apache-13], [enable the Apache 1.3 module]),
 562         [ if test "x$enableval" = "x" ; then
 563               WANT_APACHE_13=yes
 564           else
 565               WANT_APACHE_13="$enableval"
 566           fi
 567         ],[ WANT_APACHE_13=no ])
 568 AC_MSG_CHECKING(whether to build Apache 1.3 module)
 569 if test "$WANT_APACHE_13" != yes && test "$WANT_APACHE_13" != no ; then
 570    WANT_APACHE_13=yes
 571 fi
 572 AC_MSG_RESULT($WANT_APACHE_13)
 573
 574 if test "$WANT_APACHE_13" = "yes" ; then
 575     AC_ARG_WITH(apxs,
 576         AC_HELP_STRING([--with-apxs=FILE], [Specifies where to find the Apache 1.3 apxs script.]),
 577         [
 578         AC_MSG_CHECKING(for user-specified apxs name/location)
 579         if test "$withval" != "no" ; then
 580           if test "$withval" != "yes"; then
 581             APXS=$withval
 582             AC_MSG_RESULT("$withval")
 583           fi
 584         fi
 585         ],
 586         [
 587         AC_PATH_PROG(APXS, apxs, no)
 588         if test "$APXS" = "no" ; then
 589           for i in /usr/sbin /usr/local/apache/bin ; do
 590             if test "$APXS" = "no" && test -f "$i/apxs"; then
 591               APXS="$i/apxs"
 592             fi
 593           done
 594         fi
 595         ])
 596
 597     AC_MSG_CHECKING([to see if apxs was located])
 598     if test ! -f "$APXS" ; then
 599         AC_MSG_RESULT(no)
 600         AC_MSG_ERROR([Unable to locate apxs script. An Apache development package may be missing from your server, or you may need to use the --with-apxs option.])
 601     fi
 602     AC_MSG_RESULT($APXS)
 603     AC_SUBST(APXS)
 604
 605     # extract settings we need from APXS -q
 606     APXS_CC="`$APXS -q CC`"
 607     APXS_CFLAGS="`$APXS -q CFLAGS` `$APXS -q CFLAGS_SHLIB`"
 608     APXS_INCLUDE="`$APXS -q INCLUDEDIR`"
 609 fi
 610
 611 AC_SUBST(APXS_CFLAGS)
 612 AC_SUBST(APXS_INCLUDE)
 613
 614
 615 # Apache 2.0 (mod_shib_20)
 616 #   --enable-apache-20
 617 #   --with-apxs2      (DSO build, the normal way, uses apxs to derive build flags)
 618 #       --with-apr        (DSO build, APR development package installed separately)
 619
 620 AC_ARG_ENABLE(apache-20,
 621         AC_HELP_STRING([--enable-apache-20], [enable the Apache 2.0 module]),
 622         [ if test "x$enableval" = "x" ; then
 623               WANT_APACHE_20=yes
 624           else
 625               WANT_APACHE_20="$enableval"
 626           fi
 627         ],[ WANT_APACHE_20=no ])
 628 AC_MSG_CHECKING(whether to build Apache 2.0 module)
 629 if test "$WANT_APACHE_20" != yes && test "$WANT_APACHE_20" != no ; then
 630    WANT_APACHE_20=yes
 631 fi
 632 AC_MSG_RESULT($WANT_APACHE_20)
 633
 634 if test "$WANT_APACHE_20" = "yes" ; then
 635     AC_ARG_WITH(apxs2,
 636         AC_HELP_STRING([--with-apxs2=FILE], [Specifies where to find the Apache 2.0 apxs script.]),
 637         [
 638         AC_MSG_CHECKING(for user-specified Apache2 apxs name/location)
 639         if test "$withval" != "no" ; then
 640           if test "$withval" != "yes"; then
 641             APXS2=$withval
 642             AC_MSG_RESULT("$withval")
 643           fi
 644         fi
 645         ],
 646         [
 647         AC_PATH_PROG(APXS2, apxs2, no)
 648         if test "$APXS2" = "no" ; then
 649             AC_PATH_PROG(APXS2, apxs, no)
 650         fi
 651         if test "$APXS2" = "no" ; then
 652           for i in /usr/sbin /usr/local/apache2/bin /usr/local/apache/bin ; do
 653             if test "$APXS2" = "no" && test -f "$i/apxs2" ; then
 654               APXS2="$i/apxs2"
 655             fi
 656           done
 657           if test "$APXS2" = "no" ; then
 658             for i in /usr/sbin /usr/local/apache2/bin /usr/local/apache/bin ; do
 659               if test "$APXS2" = "no" && test -f "$i/apxs" ; then
 660                 APXS2="$i/apxs"
 661               fi
 662             done
 663           fi
 664         fi
 665         ])
 666
 667     AC_MSG_CHECKING([to see if Apache2 apxs was located])
 668     if test ! -f "$APXS2" ; then
 669         AC_MSG_RESULT(no)
 670         AC_MSG_ERROR([Unable to locate Apache2 apxs script. An Apache development package may be missing from your server, or you may need to use the --with-apxs2 option.])
 671     fi
 672     AC_MSG_RESULT($APXS2)
 673     AC_SUBST(APXS2)
 674
 675     # APR settings
 676     AC_ARG_WITH(apr,
 677         AC_HELP_STRING([--with-apr=PATH], [where apr-config is installed]),
 678         [
 679         AC_MSG_CHECKING(for user-specified apr-config name/location)
 680         if test "$withval" != "no" ; then
 681             if test "$withval" != "yes"; then
 682                 APR_CONFIG=$withval
 683                 AC_MSG_RESULT("$withval")
 684             fi
 685         fi
 686         ],
 687         [
 688         AC_PATH_PROG(APR_CONFIG, apr-config,,[`$APXS2 -q SBINDIR`]:[$PATH])
 689         ])
 690         if test -f "${APR_CONFIG}"; then
 691         APR_CFLAGS="`${APR_CONFIG} --cflags` `${APR_CONFIG} --cppflags` `${APR_CONFIG} --includes`"
 692     else
 693         AC_MSG_ERROR([Unable to locate apr-config, may need --with-apr option.])
 694     fi
 695
 696     # extract settings we need from APXS2 -q
 697     APXS2_CC="`$APXS2 -q CC`"
 698     APXS2_CFLAGS="`$APXS2 -q CPPFLAGS` `$APXS2 -q CFLAGS` $APR_CFLAGS"
 699     APXS2_INCLUDE="`$APXS2 -q INCLUDEDIR`"
 700 fi
 701
 702 AC_SUBST(APXS2_CFLAGS)
 703 AC_SUBST(APXS2_INCLUDE)
 704
 705
 706 # Apache 2.2 (mod_shib_22)
 707 #   --enable-apache-22
 708 #   --with-apxs22     (DSO build, the normal way, uses apxs to derive build flags)
 709 #       --with-apr1       (DSO build, APR development package installed separately)
 710
 711 AC_ARG_ENABLE(apache-22,
 712         AC_HELP_STRING([--enable-apache-22], [enable the Apache 2.2 module]),
 713         [ if test "x$enableval" = "x" ; then
 714               WANT_APACHE_22=yes
 715           else
 716               WANT_APACHE_22="$enableval"
 717           fi
 718         ],[ WANT_APACHE_22=no ])
 719 AC_MSG_CHECKING(whether to build Apache 2.2 module)
 720 if test "$WANT_APACHE_22" != yes && test "$WANT_APACHE_22" != no ; then
 721    WANT_APACHE_22=yes
 722 fi
 723 AC_MSG_RESULT($WANT_APACHE_22)
 724
 725 if test "$WANT_APACHE_22" = "yes" ; then
 726     AC_ARG_WITH(apxs22,
 727         AC_HELP_STRING([--with-apxs22=FILE], [Specifies where to find the Apache 2.2 apxs script.]),
 728         [
 729         AC_MSG_CHECKING(for user-specified Apache2.2 apxs name/location)
 730         if test "$withval" != "no" ; then
 731           if test "$withval" != "yes"; then
 732             APXS22=$withval
 733             AC_MSG_RESULT("$withval")
 734           fi
 735         fi
 736         ],
 737         [
 738         AC_PATH_PROG(APXS22, apxs2, no)
 739         if test "$APXS22" = "no" ; then
 740             AC_PATH_PROG(APXS22, apxs, no)
 741         fi
 742         if test "$APXS22" = "no" ; then
 743           for i in /usr/sbin /usr/local/apache2/bin /usr/local/apache/bin ; do
 744             if test "$APXS22" = "no" && test -f "$i/apxs2" ; then
 745               APXS22="$i/apxs2"
 746             fi
 747           done
 748           if test "$APXS22" = "no" ; then
 749             for i in /usr/sbin /usr/local/apache2/bin /usr/local/apache/bin ; do
 750               if test "$APXS22" = "no" && test -f "$i/apxs" ; then
 751                 APXS22="$i/apxs"
 752               fi
 753             done
 754           fi
 755         fi
 756         ])
 757
 758     AC_MSG_CHECKING([to see if Apache2.2 apxs was located])
 759     if test ! -f "$APXS22" ; then
 760         AC_MSG_RESULT(no)
 761         AC_MSG_ERROR([Unable to locate Apache2.2 apxs script. An Apache development package may be missing from your server, or you may need to use the --with-apxs22 option.])
 762     fi
 763     AC_MSG_RESULT($APXS22)
 764     AC_SUBST(APXS22)
 765
 766     # APR1 settings
 767     AC_ARG_WITH(apr1,
 768         AC_HELP_STRING([--with-apr1=PATH], [where apr-1-config is installed]),
 769         [
 770         AC_MSG_CHECKING(for user-specified apr-1-config name/location)
 771         if test "$withval" != "no" ; then
 772             if test "$withval" != "yes"; then
 773                 APR1_CONFIG=$withval
 774                 AC_MSG_RESULT("$withval")
 775             fi
 776         fi
 777         ],
 778         [
 779         AC_PATH_PROG(APR1_CONFIG, apr-1-config,,[`$APXS22 -q SBINDIR`]:[$PATH])
 780         ])
 781         if test -f "${APR1_CONFIG}"; then
 782         APR1_CFLAGS="`${APR1_CONFIG} --cflags` `${APR1_CONFIG} --cppflags` `${APR1_CONFIG} --includes`"
 783     else
 784         AC_MSG_ERROR([Unable to locate apr-1-config, may need --with-apr1 option.])
 785     fi
 786
 787     # extract settings we need from APXS22 -q
 788     APXS22_CC="`$APXS22 -q CC`"
 789     APXS22_CFLAGS="`$APXS22 -q CPPFLAGS` `$APXS22 -q CFLAGS` $APR1_CFLAGS"
 790     APXS22_INCLUDE="`$APXS22 -q INCLUDEDIR`"
 791 fi
 792
 793 AC_SUBST(APXS22_CFLAGS)
 794 AC_SUBST(APXS22_INCLUDE)
 795
 796 # always output the Makefile, even if you don't use it
 797 AC_CONFIG_FILES([apache/Makefile])
 798 AM_CONDITIONAL(BUILD_AP13,test "$WANT_APACHE_13" = "yes")
 799 AM_CONDITIONAL(BUILD_AP20,test "$WANT_APACHE_20" = "yes")
 800 AM_CONDITIONAL(BUILD_AP22,test "$WANT_APACHE_22" = "yes")
 801
 802 # add the apache module to the list of wanted subdirs..
 803 if test "$WANT_APACHE_13" = "yes" || test "$WANT_APACHE_20" = "yes" || test "$WANT_APACHE_22" = "yes" ; then
 804     WANT_SUBDIRS="$WANT_SUBDIRS apache"
 805 fi
 806
 807
 808 #
 809 # Implement the checks of the ODBC Storage Service
 810 #
 811 # 1) Assume the user wants ODBC; if it's not found then just continue without
 812 # 2) If the user specifically requested odbc, look for it and ERROR if not found
 813 # 3) If the user specifically requested no odbc, don't build it.
 814 #
 815
 816 AC_CONFIG_FILES([odbc-store/Makefile])
 817
 818 # determine whether we should enable the odbc ccache
 819 AC_ARG_ENABLE([odbc],
 820         AC_HELP_STRING([--disable-odbc], [disable the ODBC Storage Service]),
 821         [odbc_enabled=$enableval], [odbc_enabled=default])
 822
 823 if test "x$odbc_enabled" = "x" ; then
 824    odbc_enabled=yes
 825 fi
 826
 827 # Are we trying to build ODBC?
 828 AC_MSG_CHECKING(whether to build the ODBC storage service)
 829 if test "$odbc_enabled" = "yes" ; then
 830    build_odbc=yes
 831    AC_MSG_RESULT(yes)
 832 elif test "$odbc_enabled" = "default" ; then
 833    build_odbc=yes
 834    AC_MSG_RESULT([yes, if it can be found])
 835 else
 836    build_odbc=no
 837    AC_MSG_RESULT(no)
 838 fi
 839
 840 # If we're trying to build ODBC, try to find the odbc_config program.
 841 if test "$build_odbc" = "yes" ; then
 842    odbc_dir=""
 843    AC_ARG_WITH(odbc,
 844         AC_HELP_STRING([--with-odbc=PATH], [directory where odbc is installed]),
 845             [if test "$with_odbc" = no ; then
 846                AC_MSG_ERROR([Try running --disable-odbc instead.])
 847              elif test "$with_odbc" != yes ; then
 848                odbc_dir="$with_odbc/bin"
 849                if test "$with_odbc" != /usr ; then
 850                  ODBC_CFLAGS="-I$with_odbc/include"
 851                  ODBC_LIBS="-L$with_odbc/lib"
 852                fi
 853              fi ])
 854
 855    AC_PATH_PROG(ODBC_CONFIG, odbc_config, no, $odbc_dir $PATH )
 856    if test "$ODBC_CONFIG" = no ; then
 857       AC_MSG_WARN([Cannot find odbc_config, will try to guess settings.])
 858       ODBC_LIBS="$ODBC_LIBS -lodbc"
 859    else
 860       ODBC_CFLAGS=`$ODBC_CONFIG --cflags`
 861       ODBC_LIBS=`$ODBC_CONFIG --libs`
 862    fi
 863
 864    save_CPPFLAGS="$CPPFLAGS"
 865    CPPFLAGS="$CPPFLAGS $ODBC_CFLAGS"
 866
 867    AC_CHECK_HEADER([sql.h], [have_sql_h=yes], [have_sql_h=no])
 868    if test "$have_sql_h" = no -a "$odbc_enabled" = "yes" ; then
 869      AC_MSG_ERROR(unable to find ODBC header files)
 870    fi
 871
 872    if test "$have_sql_h" = yes ; then
 873       save_LIBS="$LIBS"
 874       LIBS="$LIBS $ODBC_LIBS"
 875       AC_MSG_CHECKING(if we can link againt ODBC)
 876       AC_TRY_LINK(
 877         [#include <sql.h>
 878          #include <sqlext.h>
 879          #include <stdio.h>],
 880         [SQLSetEnvAttr(SQL_NULL_HANDLE, SQL_ATTR_CONNECTION_POOLING, (void*)SQL_CP_ONE_PER_HENV, 0)],
 881         [have_odbc_libs=yes],
 882         [have_odbc_libs=no])
 883       LIBS="$save_LIBS"
 884
 885       if test "$have_odbc_libs" = no ; then
 886          if test "$odbc_enabled" = "yes" ; then
 887             AC_MSG_ERROR([unable to link with ODBC Library])
 888          else
 889             AC_MSG_RESULT(no, skipping ODBC)
 890          fi
 891       fi
 892    fi
 893
 894    CPPFLAGS="$save_CPPFLAGS"
 895 fi
 896
 897 # if have_odbc_libs=yes then go ahead with building ODBC
 898 if test "$have_odbc_libs" = yes ; then
 899    # this AC_MSG_RESULT is from above!
 900    AC_MSG_RESULT(yes)
 901    WANT_SUBDIRS="$WANT_SUBDIRS odbc-store"
 902    AC_SUBST(ODBC_CFLAGS)
 903    AC_SUBST(ODBC_LIBS)
 904 fi
 905
 906
 907 AC_SUBST(WANT_SUBDIRS)
 908
 909 if test -n "$APXS_CC" && test "$APXS_CC" != "$CC" ; then
 910   echo "=================================================================="
 911   echo "WARNING: You have chosen to compile Apache-1.3 modules with a different"
 912   echo "         compiler than the one used to compile Apache."
 913   echo ""
 914   echo "    Current compiler:      $CC"
 915   echo "   Apache's compiler:      $APXS_CC"
 916   echo ""
 917   echo "This could cause problems."
 918   echo "=================================================================="
 919 fi
 920
 921 if test -n "$APXS2_CC" && test "$APXS2_CC" != "$CC" ; then
 922   echo "=================================================================="
 923   echo "WARNING: You have chosen to compile Apache-2.0 modules with a different"
 924   echo "         compiler than the one used to compile Apache."
 925   echo ""
 926   echo "    Current compiler:      $CC"
 927   echo "   Apache's compiler:      $APXS2_CC"
 928   echo ""
 929   echo "This could cause problems."
 930   echo "=================================================================="
 931 fi
 932
 933 if test -n "$APXS22_CC" && test "$APXS22_CC" != "$CC" ; then
 934   echo "=================================================================="
 935   echo "WARNING: You have chosen to compile Apache-2.2 modules with a different"
 936   echo "         compiler than the one used to compile Apache."
 937   echo ""
 938   echo "    Current compiler:      $CC"
 939   echo "   Apache's compiler:      $APXS22_CC"
 940   echo ""
 941   echo "This could cause problems."
 942   echo "=================================================================="
 943 fi
 944
 945 LIBTOOL="$LIBTOOL --silent"
 946
 947 AC_OUTPUT
 948