configure.ac

   1 AC_PREREQ([2.50])
   2 AC_INIT([xmltooling], [1.0], [mace-opensaml-users@internet2.edu], [xmltooling])
   3 AM_CONFIG_HEADER(config.h)
   4 AM_CONFIG_HEADER(xmltooling/config_pub.h)
   5 AM_INIT_AUTOMAKE([xmltooling], [1.0])
   6
   7 sinclude(doxygen.m4)
   8 sinclude(acx_pthread.m4)
   9
  10 # Docygen features
  11 DX_HTML_FEATURE(ON)
  12 DX_CHM_FEATURE(OFF)
  13 DX_CHI_FEATURE(OFF)
  14 DX_MAN_FEATURE(OFF)
  15 DX_RTF_FEATURE(OFF)
  16 DX_XML_FEATURE(OFF)
  17 DX_PDF_FEATURE(OFF)
  18 DX_PS_FEATURE(OFF)
  19 DX_INIT_DOXYGEN(xmltooling, doxygen.cfg, doc/api)
  20
  21 AC_ARG_ENABLE(debug,
  22     AC_HELP_STRING(--enable-debug, [Have GCC compile with symbols (Default = no)]),
  23     enable_debug=$enableval, enable_debug=no)
  24
  25 if test "$enable_debug" = "yes" ; then
  26     GCC_CFLAGS="$CFLAGS -Wall -g -D_DEBUG"
  27     GCC_CXXFLAGS="$CXXFLAGS -Wall -g -D_DEBUG"
  28 else
  29     GCC_CFLAGS="$CFLAGS -Wall -O2 -DNDEBUG"
  30     GCC_CXXFLAGS="$CXXFLAGS -Wall -O2 -DNDEBUG"
  31 fi
  32
  33 AC_PROG_CC([gcc gcc3 cc])
  34 AC_PROG_CXX([g++ g++3 c++ CC])
  35 AC_CANONICAL_HOST
  36
  37 if test "$GCC" = "yes" ; then
  38 #    AC_HAVE_GCC_VERSION(4,0,0,0,
  39 #        [
  40 #        AC_DEFINE(GCC_HASCLASSVISIBILITY,1,
  41 #            [Define to enable class visibility control in gcc.])
  42 #        GCC_CFLAGS="$GCC_CFLAGS -fvisibility=hidden -fvisibility-inlines-hidden"
  43 #        GCC_CXXFLAGS="$GCC_CXXFLAGS -fvisibility=hidden -fvisibility-inlines-hidden"
  44 #        ])
  45     CFLAGS="$GCC_CFLAGS"
  46     CXXFLAGS="$GCC_CXXFLAGS"
  47 else
  48 # Fix for Sun Workshop compiler in debug mode, may be Sun case #6360993
  49         case "${host_cpu}-${host_os}" in
  50                 *solaris*)
  51                         if test "$CXX" = "CC" ; then
  52                                 CXXFLAGS="$CXXFLAGS -Qoption ccfe -stabs=no%dfltlit+no%dflthlp"
  53                         fi
  54                 ;;
  55         esac
  56 fi
  57
  58 AC_DISABLE_STATIC
  59 AC_PROG_LIBTOOL
  60
  61 # Checks for typedefs, structures, and compiler characteristics.
  62 AC_C_CONST
  63 AC_TYPE_SIZE_T
  64
  65 # Checks for library functions.
  66 AC_CHECK_FUNCS([strchr strdup strstr timegm strcasecmp])
  67 AC_CHECK_HEADERS([dlfcn.h])
  68 AC_CHECK_FUNC(dlclose, , [ AC_CHECK_LIB(dl, dlopen) ])
  69
  70 # checks for pthreads
  71 ACX_PTHREAD([enable_threads="pthread"],[enable_threads="no"])
  72 if test $enable_threads != "pthread"; then
  73     AC_MSG_ERROR([unable to find pthreads, currently this is required])
  74 else
  75     AC_DEFINE(HAVE_PTHREAD,1,[Define if you have POSIX threads libraries and header files.])
  76         AM_CONDITIONAL(BUILD_PTHREAD,test "$enable_threads" = "pthread")
  77     LIBS="$PTHREAD_LIBS $LIBS"
  78     CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
  79     CXXFLAGS="$PTHREAD_CFLAGS $CXXFLAGS"
  80 fi
  81
  82 # OpenSSL settings
  83 AC_ARG_WITH(openssl,
  84     AC_HELP_STRING([--with-openssl=PATH], [where openssl is installed]),
  85     [if test x_$with_openssl != x_/usr; then
  86         SSLLIBS="-L${with_openssl}/lib -lcrypto -lssl"
  87         SSLFLAGS="-I${with_openssl}/include"
  88     fi])
  89
  90 if test "x$SSLLIBS" = "x" ; then
  91     AC_PATH_PROG(PKG_CONFIG, pkg-config)
  92     if test "x$PKG_CONFIG" != x && test "x$PKG_CONFIG" != "xno" ; then
  93         if pkg-config openssl ; then
  94             SSLLIBS="`$PKG_CONFIG --libs openssl`"
  95             SSLFLAGS="`$PKG_CONFIG --cflags openssl`"
  96         else
  97             AC_MSG_ERROR([OpenSSL not supported by pkg-config, try --with-openssl instead])
  98         fi
  99     fi
 100 fi
 101
 102 if test "x$SSLLIBS" = "x" ; then
 103     SSLLIBS="-lcrypto -lssl"
 104 fi
 105
 106 AC_MSG_CHECKING(for OpenSSL libraries)
 107 AC_MSG_RESULT($SSLLIBS)
 108 LIBS="$LIBS $SSLLIBS"
 109 AC_MSG_CHECKING(for OpenSSL cflags)
 110 AC_MSG_RESULT($SSLFLAGS)
 111 CPPFLAGS="$SSLFLAGS $CPPFLAGS"
 112
 113 AC_CHECK_HEADER([openssl/pem.h],,
 114                 AC_MSG_ERROR([unable to find openssl header files]))
 115 AC_MSG_CHECKING(for ERR_load_CRYPTO_string)
 116 AC_TRY_LINK_FUNC([ERR_load_CRYPTO_strings],,
 117              AC_MSG_ERROR([unable to link with openssl libraries]))
 118 AC_MSG_RESULT(yes)
 119
 120 # libcurl settings
 121 AC_PATH_PROG(CURL_CONFIG,curl-config)
 122 AC_ARG_WITH(curl,
 123     AC_HELP_STRING([--with-curl=PATH], [where curl-config is installed]),
 124     [
 125     CURL_CONFIG="${with_curl}"
 126     if ! test -f "${CURL_CONFIG}" ; then
 127         CURL_CONFIG="${with_curl}/bin/curl-config"
 128     fi
 129     ])
 130 if test -f "${CURL_CONFIG}" ; then
 131     LDFLAGS="`${CURL_CONFIG} --libs` $LDFLAGS"
 132     CPPFLAGS="`${CURL_CONFIG} --cflags` $CPPFLAGS"
 133 else
 134     AC_MSG_ERROR([curl-config not found, may need to use --with-curl option])
 135 fi
 136 AC_CHECK_HEADER([curl/curl.h],,AC_MSG_ERROR([unable to find libcurl header files]))
 137 AC_CHECK_LIB([curl],[curl_global_init],,AC_MSG_ERROR([unable to link with libcurl]))
 138 AC_MSG_CHECKING([for CURLOPT_SSL_CTX_FUNCTION in curl.h])
 139 AC_EGREP_HEADER([CURLOPT_SSL_CTX_FUNCTION], [curl/curl.h],
 140                 [AC_MSG_RESULT(yes)],
 141                 [AC_MSG_ERROR([need libcurl that supports CURLOPT_SSL_CTX_FUNCTION])])
 142
 143
 144 AC_LANG(C++)
 145
 146 # C++ requirements
 147 AC_CXX_REQUIRE_STL
 148 AC_CXX_NAMESPACES
 149
 150 # are covariant methods allowed?
 151 AC_TRY_LINK(
 152      [ class base { public: virtual base *GetPtr( void ) { return this; } }; ],
 153      [ class derived: virtual public base { public: virtual derived *GetPtr( void ) { return this; } }; ],
 154      [AC_DEFINE(HAVE_COVARIANT_RETURNS,1,[Define if C++ compiler supports covariant virtual methods.])])
 155
 156 # log4cpp settings
 157 AC_PATH_PROG(LOG4CPP_CONFIG,log4cpp-config)
 158 AC_ARG_WITH(log4cpp,
 159     AC_HELP_STRING([--with-log4cpp=PATH], [where log4cpp-config is installed]),
 160     [
 161     LOG4CPP_CONFIG="${with_log4cpp}"
 162     if ! test -f "${LOG4CPP_CONFIG}" ; then
 163         LOG4CPP_CONFIG="${with_log4cpp}/bin/log4cpp-config"
 164     fi
 165     ])
 166 if test -f "${LOG4CPP_CONFIG}"; then
 167     LDFLAGS="`${LOG4CPP_CONFIG} --libs` $LDFLAGS"
 168     CPPFLAGS="`${LOG4CPP_CONFIG} --cflags` $CPPFLAGS"
 169 else
 170     AC_MSG_ERROR([log4cpp-config not found, may need to use --with-log4cpp option])
 171     LIBS="-llog4cpp $LIBS"
 172 fi
 173 AC_CHECK_HEADER([log4cpp/Category.hh],,AC_MSG_ERROR([unable to find log4cpp header files]))
 174 AC_CHECK_HEADER([log4cpp/PropertyConfigurator.hh],,AC_MSG_ERROR([you need at least log4cpp 0.3.x]))
 175 AC_TRY_LINK(
 176         [#include <log4cpp/Category.hh>],
 177         [log4cpp::Category::getInstance("foo")],
 178         [AC_DEFINE(HAVE_LIBLOG4CPP,1,[Define if log4cpp library was found])],
 179         [AC_MSG_ERROR([unable to link with log4cpp])])
 180
 181 # Xerces settings
 182 AC_ARG_WITH(xerces,
 183             AC_HELP_STRING([--with-xerces=PATH], [where xerces-c is installed]),
 184             [if test x_$with_xerces != x_/usr; then
 185                 LDFLAGS="-L${with_xerces}/lib $LDFLAGS"
 186                 CPPFLAGS="-I${with_xerces}/include $CPPFLAGS"
 187             fi])
 188 LIBS="-lxerces-c $LIBS"
 189 AC_CHECK_HEADER([xercesc/dom/DOM.hpp],,AC_MSG_ERROR([unable to find xerces header files]))
 190 AC_MSG_CHECKING([Xerces version])
 191 AC_PREPROC_IFELSE(
 192     [AC_LANG_PROGRAM([#include <xercesc/util/XercesVersion.hpp>],
 193 [#if  _XERCES_VERSION != 20600
 194 int i = 0;
 195 #else
 196 #error cannot use version 2.6.0
 197 #endif])],
 198     [AC_MSG_RESULT(OK)],
 199     [AC_MSG_FAILURE([Xerces-C v2.6.0 has bugs that inhibit use with signed XML, please use a newer version])])
 200 AC_TRY_LINK(
 201         [#include <xercesc/util/PlatformUtils.hpp>],
 202         [xercesc::XMLPlatformUtils::Initialize()],
 203         [AC_DEFINE(HAVE_LIBXERCESC,1,[Define if Xerces-C library was found])],
 204         [AC_MSG_ERROR([unable to link with Xerces])])
 205
 206
 207 # XML-Security settings
 208 AC_ARG_WITH(xmlsec,
 209             AC_HELP_STRING([--with-xmlsec=PATH], [where xmlsec is installed]),,
 210             [with_xmlsec=/usr])
 211
 212 if test x_$with_xmlsec != x_no; then
 213     if test x_$with_xmlsec != x_/usr; then
 214         LDFLAGS="-L${with_xmlsec}/lib $LDFLAGS"
 215         CPPFLAGS="-I${with_xmlsec}/include $CPPFLAGS"
 216     fi
 217     LIBS="-lxml-security-c $LIBS"
 218     AC_CHECK_HEADER([xsec/utils/XSECPlatformUtils.hpp],,AC_MSG_ERROR([unable to find XML-Security header files]))
 219     AC_MSG_CHECKING([XML-Security version])
 220     AC_PREPROC_IFELSE(
 221             [AC_LANG_PROGRAM([#include <xsec/utils/XSECPlatformUtils.hpp>],
 222         [#if XSEC_VERSION_MAJOR > 1 || (XSEC_VERSION_MAJOR == 1 && XSEC_VERSION_MEDIUM > 3) || (XSEC_VERSION_MAJOR == 1 && XSEC_VERSION_MEDIUM == 3 && XSEC_VERSION_MINOR > 0)
 223 int i = 0;
 224 #else
 225 #error need version 1.3.1 or later
 226 #endif])],
 227         [AC_MSG_RESULT(OK)],
 228         [AC_MSG_FAILURE([XML-Security version 1.3.1 or greater is required.])])
 229     AC_TRY_LINK(
 230             [#include <xsec/utils/XSECPlatformUtils.hpp>],
 231             [XSECPlatformUtils::Initialise()],,
 232             [AC_MSG_ERROR([unable to link with XML-Sec])])
 233 else
 234     AC_MSG_WARN([xmlsec disabled, building without signature/encryption support])
 235     AC_DEFINE(XMLTOOLING_NO_XMLSEC,1,
 236         [Define if you wish to disable XML-Security-dependent features.])
 237 fi
 238 AM_CONDITIONAL(BUILD_XMLSEC,test x_$with_xmlsec != x_no)
 239
 240 # Does the STL in use help or screw us?
 241 AC_TRY_LINK(
 242         [#include <string>],
 243         [std::basic_string<unsigned short> foo; foo=foo+(unsigned short)65],
 244         [AC_DEFINE(HAVE_GOOD_STL,1,
 245             [Define if you have an STL implementation that supports useful string specialization.])],
 246         )
 247
 248 # Check for unit test support
 249 CXXTEST="/usr/bin/cxxtestgen.pl"
 250 CXXTESTFLAGS=""
 251 AC_ARG_WITH(cxxtest,
 252             AC_HELP_STRING([--with-cxxtest=PATH], [where cxxtest is installed]),
 253             [if test x_$with_cxxtest != x_/usr; then
 254                 CXXTEST="${with_cxxtest}/cxxtestgen.pl"
 255                 CXXTESTFLAGS="-I${with_cxxtest}"
 256             fi])
 257 if ! test -f "${CXXTEST}"; then
 258     AC_MSG_WARN([cxxtestgen not found, won't build unit tests])
 259 fi
 260
 261 AC_SUBST(CXXTEST)
 262 AC_SUBST(CXXTESTFLAGS)
 263 AM_CONDITIONAL(BUILD_UNITTEST,test -f ${CXXTEST})
 264
 265 LIBTOOL="$LIBTOOL --silent"
 266
 267 # output makefiles
 268 AC_OUTPUT(Makefile xmltooling/Makefile xmltoolingtest/Makefile schemas/Makefile)