configure.ac

   1 # Process this file with autoreconf
   2 AC_PREREQ([2.50])
   3 AC_INIT([xmltooling],[1.5],[https://issues.shibboleth.net/],[xmltooling])
   4 AC_CONFIG_SRCDIR(xmltooling)
   5 AC_CONFIG_AUX_DIR(build-aux)
   6 AC_CONFIG_MACRO_DIR(m4)
   7 AM_INIT_AUTOMAKE
   8 AC_DISABLE_STATIC
   9 AC_PROG_LIBTOOL
  10
  11 # Docygen features
  12 DX_HTML_FEATURE(ON)
  13 DX_CHM_FEATURE(OFF)
  14 DX_CHI_FEATURE(OFF)
  15 DX_MAN_FEATURE(OFF)
  16 DX_RTF_FEATURE(OFF)
  17 DX_XML_FEATURE(OFF)
  18 DX_PDF_FEATURE(OFF)
  19 DX_PS_FEATURE(OFF)
  20 DX_INIT_DOXYGEN(xmltooling, doxygen.cfg, doc/api)
  21
  22 AC_ARG_ENABLE(debug,
  23     AS_HELP_STRING([--enable-debug],[Have GCC compile with symbols (Default = no)]),
  24     enable_debug=$enableval, enable_debug=no)
  25
  26 if test "$enable_debug" = "yes" ; then
  27     GCC_CFLAGS="$CFLAGS -g -D_DEBUG"
  28     GCC_CXXFLAGS="$CXXFLAGS -g -D_DEBUG"
  29 else
  30     GCC_CFLAGS="$CFLAGS -O2 -DNDEBUG"
  31     GCC_CXXFLAGS="$CXXFLAGS -O2 -DNDEBUG"
  32 fi
  33
  34 AC_CONFIG_HEADERS([config.h xmltooling/config_pub.h])
  35 AC_CONFIG_FILES([xmltooling.spec])
  36 AC_CONFIG_FILES([Makefile xmltooling/Makefile xmltoolingtest/Makefile schemas/Makefile doc/Makefile])
  37
  38 AC_PROG_CC([gcc gcc3 cc])
  39 AC_PROG_CXX([g++ g++3 c++ CC])
  40 AC_CANONICAL_HOST
  41
  42 if test "$GCC" = "yes" ; then
  43 #    AC_HAVE_GCC_VERSION(4,0,0,0,
  44 #        [
  45 #        AC_DEFINE(GCC_HASCLASSVISIBILITY,1,
  46 #            [Define to enable class visibility control in gcc.])
  47 #        GCC_CFLAGS="$GCC_CFLAGS -fvisibility=hidden -fvisibility-inlines-hidden"
  48 #        GCC_CXXFLAGS="$GCC_CXXFLAGS -fvisibility=hidden -fvisibility-inlines-hidden"
  49 #        ])
  50     CFLAGS="-Wall $GCC_CFLAGS"
  51     CXXFLAGS="-Wall $GCC_CXXFLAGS"
  52 fi
  53
  54 # Fix for Sun Workshop compiler in debug mode, may be Sun case #6360993
  55 # Also enables POSIX semantics for some functions.
  56 case "${host_cpu}-${host_os}" in
  57     *solaris*)
  58         CFLAGS="$CFLAGS -D_POSIX_PTHREAD_SEMANTICS"
  59         CXXFLAGS="$CXXFLAGS -D_POSIX_PTHREAD_SEMANTICS"
  60         if test "$CXX" = "CC" ; then
  61                 CXXFLAGS="$CXXFLAGS -Qoption ccfe -stabs=no%dfltlit+no%dflthlp"
  62         fi
  63     ;;
  64 esac
  65
  66 # Checks for typedefs, structures, and compiler characteristics.
  67 AC_C_CONST
  68 AC_TYPE_SIZE_T
  69 AC_CHECK_SIZEOF([long])
  70
  71 # Checks for library functions.
  72 AC_CHECK_FUNCS([strchr strdup strstr timegm strcasecmp])
  73 AC_CHECK_HEADERS([dlfcn.h])
  74 AC_CHECK_FUNC(dlclose, , [ AC_CHECK_LIB(dl, dlopen) ])
  75
  76 # checks for pthreads
  77 ACX_PTHREAD([enable_threads="pthread"],[enable_threads="no"])
  78 if test $enable_threads != "pthread"; then
  79     AC_MSG_ERROR([unable to find pthreads, currently this is required])
  80 else
  81     AC_DEFINE([HAVE_PTHREAD],[1],[Define if you have POSIX threads libraries and header files.])
  82         AM_CONDITIONAL(BUILD_PTHREAD,test "$enable_threads" = "pthread")
  83     LIBS="$PTHREAD_LIBS $LIBS"
  84     CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
  85     CXXFLAGS="$PTHREAD_CFLAGS $CXXFLAGS"
  86 fi
  87
  88 AC_CHECK_FUNCS([pthread_rwlock_init])
  89
  90 AC_LANG([C++])
  91
  92 # C++ requirements
  93 AC_CXX_NAMESPACES
  94 AC_CXX_REQUIRE_STL
  95
  96 # Boost
  97 BOOST_REQUIRE
  98 BOOST_BIND
  99 BOOST_LAMBDA
 100 BOOST_PTR_CONTAINER
 101 BOOST_STRING_ALGO
 102
 103 # are covariant methods allowed?
 104 AC_LINK_IFELSE(
 105     [AC_LANG_PROGRAM([[]],
 106         [[
 107         class base { public: virtual base *GetPtr( void ) { return this; } };
 108         class derived: virtual public base { public: virtual derived *GetPtr( void ) { return this; } };
 109         ]])],
 110     [AC_DEFINE([HAVE_COVARIANT_RETURNS],[1],[Define to 1 if C++ compiler supports covariant virtual methods.])])
 111
 112 # is nullptr supported?
 113 AC_COMPILE_IFELSE(
 114     [AC_LANG_PROGRAM([[]],[[const char* ptr = nullptr;]])],
 115     [AC_DEFINE([HAVE_NULLPTR],[1],[Define to 1 if C++ compiler supports nullptr keyword.])])
 116
 117 # log4shib settings (favor this version over the log4cpp code)
 118 AC_PATH_PROG(LOG4SHIB_CONFIG,log4shib-config)
 119 AC_ARG_WITH(log4shib,
 120     AS_HELP_STRING([--with-log4shib=PATH],[where log4shib-config is installed]),
 121     [
 122     LOG4SHIB_CONFIG="${with_log4shib}"
 123     if ! test -f "${LOG4SHIB_CONFIG}" ; then
 124         LOG4SHIB_CONFIG="${with_log4shib}/bin/log4shib-config"
 125     fi
 126     ])
 127 if test -f "${LOG4SHIB_CONFIG}" ; then
 128     LIBS="`${LOG4SHIB_CONFIG} --libs` $LIBS"
 129     CPPFLAGS="`${LOG4SHIB_CONFIG} --cflags` $CPPFLAGS"
 130     AC_CHECK_HEADER([log4shib/CategoryStream.hh],,AC_MSG_ERROR([unable to find log4shib header files]))
 131     AC_LINK_IFELSE(
 132         [AC_LANG_PROGRAM([[#include <log4shib/Category.hh>
 133 #include <log4shib/CategoryStream.hh>]],
 134             [[log4shib::Category::getInstance("foo").errorStream() << log4shib::eol]])],
 135         [AC_DEFINE([XMLTOOLING_LOG4SHIB],[1],[Define to 1 if log4shib library is used.])],
 136         [AC_MSG_ERROR([unable to link with log4shib])])
 137 else
 138     AC_MSG_WARN([log4shib-config not found, may need to use --with-log4shib option])
 139     AC_MSG_WARN([will look for original log4cpp library])
 140
 141     # log4cpp settings
 142     AC_PATH_PROG(LOG4CPP_CONFIG,log4cpp-config)
 143     AC_ARG_WITH(log4cpp,
 144         AS_HELP_STRING([--with-log4cpp=PATH],[where log4cpp-config is installed]),
 145         [
 146         LOG4CPP_CONFIG="${with_log4cpp}"
 147         if ! test -f "${LOG4CPP_CONFIG}" ; then
 148                 LOG4CPP_CONFIG="${with_log4cpp}/bin/log4cpp-config"
 149         fi
 150         ])
 151     if test -f "${LOG4CPP_CONFIG}"; then
 152         AC_MSG_WARN([will try to use log4cpp, note that most non-Internet2 supplied versions are not thread-safe])
 153         LIBS="`${LOG4CPP_CONFIG} --libs` $LIBS"
 154         CPPFLAGS="`${LOG4CPP_CONFIG} --cflags` $CPPFLAGS"
 155         AC_CHECK_HEADER([log4cpp/CategoryStream.hh],,AC_MSG_ERROR([unable to find log4cpp header files]))
 156         AC_LINK_IFELSE(
 157             [AC_LANG_PROGRAM([[#include <log4cpp/Category.hh>
 158 #include <log4cpp/CategoryStream.hh>]],
 159                 [[log4cpp::Category::getInstance("foo").errorStream() << log4cpp::eol]])],
 160             [AC_DEFINE([XMLTOOLING_LOG4CPP],[1],[Define to 1 if log4cpp library is used.])],
 161             [AC_MSG_ERROR([unable to link with log4cpp, need version 1.0 or later])])
 162         else
 163             AC_MSG_ERROR([log4cpp-config not found, may need to use --with-log4cpp option])
 164         fi
 165 fi
 166
 167 # Xerces settings
 168 AC_ARG_WITH(xerces,
 169     AS_HELP_STRING([--with-xerces=PATH],[where xerces-c is installed]),,
 170     [with_xerces=/usr])
 171 if test x_$with_xerces != x_/usr; then
 172     CPPFLAGS="-I${with_xerces}/include $CPPFLAGS"
 173     LIBS="-L${with_xerces}/lib -lxerces-c $LIBS"
 174 else
 175     LIBS="-lxerces-c $LIBS"
 176 fi
 177
 178 AC_CHECK_HEADER([xercesc/dom/DOM.hpp],,AC_MSG_ERROR([unable to find xerces header files]))
 179 AC_MSG_CHECKING([Xerces version])
 180 AC_PREPROC_IFELSE(
 181     [AC_LANG_PROGRAM([#include <xercesc/util/XercesVersion.hpp>],
 182 [#if  _XERCES_VERSION != 20600
 183 int i = 0;
 184 #else
 185 #error cannot use version 2.6.0
 186 #endif])],
 187     [AC_MSG_RESULT(OK)],
 188     [AC_MSG_FAILURE([Xerces-C v2.6.0 has bugs that inhibit use with signed XML, please use a newer version])])
 189 AC_LINK_IFELSE(
 190     [AC_LANG_PROGRAM([[#include <xercesc/util/PlatformUtils.hpp>]],
 191         [[xercesc::XMLPlatformUtils::Initialize()]])],
 192     ,[AC_MSG_ERROR([unable to link with Xerces])])
 193
 194 AC_MSG_CHECKING([whether Xerces is 64-bit clean])
 195 AC_COMPILE_IFELSE(
 196     [AC_LANG_PROGRAM([[#include <xercesc/framework/MemBufInputSource.hpp>]],
 197         [[using namespace XERCES_CPP_NAMESPACE; XMLFilePos testvar;]])],
 198     [AC_MSG_RESULT([yes])AC_DEFINE([XMLTOOLING_XERCESC_64BITSAFE],[1],[Define to 1 if Xerces has a 64-bit-safe API.])],
 199     [AC_MSG_RESULT([no])])
 200
 201 AC_MSG_CHECKING([whether Xerces BinInputStream requires getContentType])
 202 AC_COMPILE_IFELSE(
 203     [AC_LANG_PROGRAM([[#include <xercesc/util/BinMemInputStream.hpp>]],
 204         [[using namespace XERCES_CPP_NAMESPACE; XMLByte buf[1024]; BinMemInputStream in(buf,1024); in.getContentType();]])],
 205     [AC_MSG_RESULT([yes])AC_DEFINE([XMLTOOLING_XERCESC_INPUTSTREAM_HAS_CONTENTTYPE],[1],[Define to 1 if Xerces InputStream class requires getContentType.])],
 206     [AC_MSG_RESULT([no])])
 207
 208 AC_MSG_CHECKING([whether Xerces DOMLS API is compliant])
 209 AC_COMPILE_IFELSE(
 210     [AC_LANG_PROGRAM([[#include <xercesc/dom/DOM.hpp>]],
 211         [[using namespace XERCES_CPP_NAMESPACE;
 212         DOMImplementation *impl = DOMImplementationRegistry::getDOMImplementation(NULL);
 213         DOMLSSerializer *ls = ((DOMImplementationLS*)impl)->createLSSerializer();]])],
 214     [AC_MSG_RESULT([yes])AC_DEFINE([XMLTOOLING_XERCESC_COMPLIANT_DOMLS],[1],[Define to 1 if Xerces supports a compliant DOMLS API.])],
 215     [AC_MSG_RESULT([no])])
 216
 217 AC_MSG_CHECKING([whether Xerces has setIdAttribute(XMLCh*, bool)])
 218 AC_COMPILE_IFELSE(
 219     [AC_LANG_PROGRAM([[#include <xercesc/dom/DOM.hpp>]],
 220         [[using namespace XERCES_CPP_NAMESPACE; DOMElement * elt; elt->setIdAttribute(NULL, false);]])],
 221     [AC_MSG_RESULT([yes])AC_DEFINE([XMLTOOLING_XERCESC_BOOLSETIDATTRIBUTE],[1],[Define to 1 if Xerces DOM ID methods take extra parameter.])],
 222     [AC_MSG_RESULT([no])])
 223
 224 AC_MSG_CHECKING([whether Xerces XMLString::release(XMLByte**) exists])
 225 AC_COMPILE_IFELSE(
 226     [AC_LANG_PROGRAM([[#include <xercesc/util/XMLString.hpp>]],
 227     [[using namespace XERCES_CPP_NAMESPACE; XMLByte* buf=NULL; XMLString::release(&buf);]])],
 228     [AC_MSG_RESULT([yes])AC_DEFINE([XMLTOOLING_XERCESC_HAS_XMLBYTE_RELEASE],[1],[Define to 1 if Xerces XMLString includes XMLByte release.])],
 229     [AC_MSG_RESULT([no])])
 230
 231 # XML-Security settings
 232 AC_ARG_WITH(xmlsec,
 233     AS_HELP_STRING([--with-xmlsec=PATH], [where xmlsec is installed]),,
 234     [with_xmlsec=/usr])
 235
 236 if test x_$with_xmlsec != x_no; then
 237
 238     # OpenSSL settings (need to do this first in case it's in a different spot from xmlsec)
 239     AC_ARG_WITH(openssl,
 240         AS_HELP_STRING([--with-openssl=PATH], [where openssl is installed]),
 241         [if test x_$with_openssl != x_/usr; then
 242             SSLFLAGS="-I${with_openssl}/include"
 243             SSLLIBS="-L${with_openssl}/lib -lcrypto -lssl"
 244         else
 245             SSLLIBS="-lcrypto -lssl"
 246         fi])
 247
 248     if test "x$SSLLIBS" = "x" ; then
 249         AC_PATH_PROG(PKG_CONFIG, pkg-config)
 250         if test "x$PKG_CONFIG" != x && test "x$PKG_CONFIG" != "xno" ; then
 251             if pkg-config openssl ; then
 252                 SSLLIBS="`$PKG_CONFIG --libs openssl`"
 253                 SSLFLAGS="`$PKG_CONFIG --cflags openssl`"
 254             else
 255                 AC_MSG_WARN([OpenSSL not supported by pkg-config, try --with-openssl instead])
 256             fi
 257         fi
 258     fi
 259
 260     if test "x$SSLLIBS" = "x" ; then
 261         SSLLIBS="-lcrypto -lssl"
 262     fi
 263
 264     AC_MSG_CHECKING(for OpenSSL cflags)
 265     AC_MSG_RESULT($SSLFLAGS)
 266     CPPFLAGS="$CPPFLAGS $SSLFLAGS"
 267     AC_MSG_CHECKING(for OpenSSL libraries)
 268     AC_MSG_RESULT($SSLLIBS)
 269     XMLSEC_LIBS="$XMLSEC_LIBS $SSLLIBS"
 270
 271     # save and append master libs
 272     save_LIBS="$LIBS"
 273     LIBS="$XMLSEC_LIBS $LIBS"
 274
 275     AC_CHECK_HEADER([openssl/pem.h],,AC_MSG_ERROR([unable to find openssl header files]))
 276     AC_MSG_CHECKING(for ERR_load_CRYPTO_string)
 277     AC_TRY_LINK_FUNC([ERR_load_CRYPTO_strings],,AC_MSG_ERROR([unable to link with openssl libraries]))
 278     AC_MSG_RESULT(yes)
 279
 280     AC_CHECK_DECL(EVP_sha512,
 281         [AC_DEFINE([XMLTOOLING_OPENSSL_HAVE_SHA2],[1],[Define to 1 if OpenSSL supports the SHA-2 hash family.])],
 282                 ,[#include <openssl/evp.h>])
 283     AC_CHECK_DECL(EVP_PKEY_set1_EC_KEY,
 284         [AC_DEFINE([XMLTOOLING_OPENSSL_HAVE_EC],[1],[Define to 1 if OpenSSL has EC support.])],
 285         ,[#include <openssl/evp.h>])
 286
 287     # restore master libs
 288     LIBS="$save_LIBS"
 289
 290     if test x_$with_xmlsec != x_/usr; then
 291         CPPFLAGS="-I${with_xmlsec}/include $CPPFLAGS"
 292         XMLSEC_LIBS="-L${with_xmlsec}/lib -lxml-security-c $XMLSEC_LIBS"
 293     else
 294         XMLSEC_LIBS="-lxml-security-c $XMLSEC_LIBS"
 295     fi
 296
 297     # save and append master libs
 298     save_LIBS="$LIBS"
 299     LIBS="$XMLSEC_LIBS $LIBS"
 300
 301     AC_CHECK_HEADER([xsec/utils/XSECPlatformUtils.hpp],,AC_MSG_ERROR([unable to find XML-Security header files]))
 302     AC_MSG_CHECKING([XML-Security version])
 303     AC_PREPROC_IFELSE(
 304             [AC_LANG_PROGRAM([#include <xsec/utils/XSECPlatformUtils.hpp>],
 305         [#if XSEC_VERSION_MAJOR > 1 || (XSEC_VERSION_MAJOR == 1 && XSEC_VERSION_MEDIUM > 3)
 306 int i = 0;
 307 #else
 308 #error need version 1.4.0 or later
 309 #endif])],
 310         [AC_MSG_RESULT(OK)],
 311         [AC_MSG_FAILURE([XML-Security version 1.4.0 or greater is required.])])
 312
 313     AC_LINK_IFELSE(
 314         [AC_LANG_PROGRAM([[#include <xsec/utils/XSECPlatformUtils.hpp>]],
 315             [[XSECPlatformUtils::Initialise()]])],,
 316         [AC_MSG_ERROR([unable to link with XML-Security])])
 317     AC_CHECK_TYPE([xsecsize_t],[AC_DEFINE([HAVE_XSECSIZE_T],[1],[Define to 1 if you have the 'xsecsize_t' type.])])
 318
 319     AC_MSG_CHECKING([whether XML-Security-C has multiple CRL support])
 320     AC_COMPILE_IFELSE(
 321         [AC_LANG_PROGRAM([[#include <xsec/dsig/DSIGKeyInfoX509.hpp>]],
 322             [[DSIGKeyInfoX509* klist; klist->getX509CRLListSize();]])],
 323         [AC_MSG_RESULT([yes])AC_DEFINE([XMLTOOLING_XMLSEC_MULTIPLECRL],[1],[Define to 1 if XML-Security-C handles multiple CRLs.])],
 324         [AC_MSG_RESULT([no])])
 325
 326     AC_MSG_CHECKING([whether XML-Security-C exposes the signature algorithm URI])
 327     AC_COMPILE_IFELSE(
 328         [AC_LANG_PROGRAM([[#include <xsec/dsig/DSIGSignature.hpp>]],
 329             [[DSIGSignature* sig; sig->getAlgorithmURI();]])],
 330         [AC_MSG_RESULT([yes])AC_DEFINE([XMLTOOLING_XMLSEC_SIGALGORITHM],[1],[Define to 1 if XML-Security-C exposes the signature algorithm URI.])],
 331         [AC_MSG_RESULT([no])])
 332
 333     AC_MSG_CHECKING([whether XML-Security-C includes ECC support])
 334     AC_COMPILE_IFELSE(
 335         [AC_LANG_PROGRAM([[#include <xsec/dsig/DSIGKeyInfoValue.hpp>]],
 336             [[DSIGKeyInfoValue* info; info->getECNamedCurve();]])],
 337         [AC_MSG_RESULT([yes])AC_DEFINE([XMLTOOLING_XMLSEC_ECC],[1],[Define to 1 if XML-Security-C includes ECC support.])],
 338         [AC_MSG_RESULT([no])])
 339
 340     AC_MSG_CHECKING([whether XML-Security-C includes C14N 1.1 support])
 341     AC_COMPILE_IFELSE(
 342         [AC_LANG_PROGRAM([[#include <xsec/dsig/DSIGConstants.hpp>]],
 343             [[transformType t = TRANSFORM_C14N11;]])],
 344         [AC_MSG_RESULT([yes])AC_DEFINE([XMLTOOLING_XMLSEC_C14N11],[1],[Define to 1 if XML-Security-C includes C14N 1.1 support.])],
 345         [AC_MSG_RESULT([no])])
 346
 347     AC_MSG_CHECKING([whether XML-Security-C includes debug logging support])
 348     AC_COMPILE_IFELSE(
 349         [AC_LANG_PROGRAM([[#include <xsec/utils/XSECPlatformUtils.hpp>]],
 350             [[XSECPlatformUtils::SetReferenceLoggingSink(NULL)]])],
 351         [AC_MSG_RESULT([yes])AC_DEFINE([XMLTOOLING_XMLSEC_DEBUGLOGGING],[1],[Define to 1 if XML-Security-C includes debug logging support.])],
 352         [AC_MSG_RESULT([no])])
 353
 354     # restore master libs
 355     LIBS="$save_LIBS"
 356
 357     # libcurl settings
 358     AC_PATH_PROG(CURL_CONFIG,curl-config)
 359     AC_ARG_WITH(curl,
 360         AS_HELP_STRING([--with-curl=PATH], [where curl-config is installed]),
 361         [
 362         CURL_CONFIG="${with_curl}"
 363         if ! test -f "${CURL_CONFIG}" ; then
 364             CURL_CONFIG="${with_curl}/bin/curl-config"
 365         fi
 366         ])
 367     if test -f "${CURL_CONFIG}" ; then
 368         CPPFLAGS="`${CURL_CONFIG} --cflags` $CPPFLAGS"
 369         XMLSEC_LIBS="`${CURL_CONFIG} --libs` $XMLSEC_LIBS"
 370     else
 371         AC_MSG_ERROR([curl-config not found, may need to use --with-curl option])
 372     fi
 373
 374     # save and append master libs
 375     save_LIBS="$LIBS"
 376     LIBS="$XMLSEC_LIBS $LIBS"
 377
 378     AC_CHECK_HEADER([curl/curl.h],,AC_MSG_ERROR([unable to find libcurl header files]))
 379     AC_LINK_IFELSE(
 380         [AC_LANG_PROGRAM([[#include <curl/curl.h>]],
 381             [[curl_global_init(CURL_GLOBAL_ALL)]])],,
 382         [AC_MSG_ERROR([unable to link with libcurl])])
 383     AC_MSG_CHECKING([for CURLOPT_SSL_CTX_FUNCTION in curl.h])
 384     AC_EGREP_HEADER([CURLOPT_SSL_CTX_FUNCTION], [curl/curl.h],
 385         [AC_MSG_RESULT(yes)],
 386         [AC_MSG_ERROR([need libcurl that supports CURLOPT_SSL_CTX_FUNCTION])])
 387     AC_CHECK_TYPE([curl_off_t],[AC_DEFINE([HAVE_CURL_OFF_T],[1],[Define to 1 if you have the 'curl_off_t' type.])],,[[#include <curl/curl.h>]])
 388
 389     # restore master libs
 390     LIBS="$save_LIBS"
 391
 392     AC_SUBST(XMLSEC_LIBS)
 393 else
 394     AC_MSG_WARN([xmlsec disabled, building without signature/encryption support])
 395     AC_DEFINE([XMLTOOLING_NO_XMLSEC],[1],[Define to 1 if you wish to disable XML-Security-dependent features.])
 396 fi
 397 AM_CONDITIONAL(BUILD_XMLSEC,test x_$with_xmlsec != x_no)
 398
 399 # Does the STL in use help or screw us?
 400 AC_LINK_IFELSE(
 401     [AC_LANG_PROGRAM([[#include <string>]],[[std::basic_string<unsigned short> foo; foo=foo+(unsigned short)65]])],
 402     [AC_DEFINE([HAVE_GOOD_STL],[1],[Define to 1 if you have an STL implementation that supports useful string specialization.])],[])
 403 AC_LINK_IFELSE(
 404     [AC_LANG_PROGRAM([[#include <vector>]],[[std::iterator_traits<std::vector<int>::iterator>::value_type foo=0]])],
 405     [AC_DEFINE([HAVE_ITERATOR_TRAITS],[1],[Define to 1 if you have an STL implementation that supports std::iterator_traits.])],[])
 406
 407 # Check for unit test support
 408 CXXTEST="/usr/bin/cxxtestgen.pl"
 409 CXXTESTFLAGS=""
 410 AC_ARG_WITH(cxxtest,
 411     AS_HELP_STRING([--with-cxxtest=PATH], [where cxxtest is installed]),
 412     [if test x_$with_cxxtest != x_/usr; then
 413         CXXTEST="${with_cxxtest}/cxxtestgen.pl"
 414         CXXTESTFLAGS="-I${with_cxxtest}"
 415     fi])
 416 if ! test -f "${CXXTEST}"; then
 417     AC_MSG_WARN([cxxtestgen not found, won't build unit tests])
 418 fi
 419
 420 AC_SUBST(CXXTEST)
 421 AC_SUBST(CXXTESTFLAGS)
 422 AM_CONDITIONAL(BUILD_UNITTEST,test -f ${CXXTEST})
 423
 424 AX_CREATE_PKGCONFIG_INFO(,,[$XMLSEC_LIBS -lxmltooling],[OpenSAML XMLTooling-C library])
 425
 426 LIBTOOL="$LIBTOOL --silent"
 427
 428 # output packaging and makefiles
 429 AC_OUTPUT