acx_pthread.m4

   1 dnl @synopsis ACX_PTHREAD([ACTION-IF-FOUND[, ACTION-IF-NOT-FOUND]])
   2 dnl
   3 dnl This macro figures out how to build C programs using POSIX
   4 dnl threads.  It sets the PTHREAD_LIBS output variable to the threads
   5 dnl library and linker flags, and the PTHREAD_CFLAGS output variable
   6 dnl to any special C compiler flags that are needed.  (The user can also
   7 dnl force certain compiler flags/libs to be tested by setting these
   8 dnl environment variables.)
   9 dnl
  10 dnl Also sets PTHREAD_CC to any special C compiler that is needed for
  11 dnl multi-threaded programs (defaults to the value of CC otherwise).
  12 dnl (This is necessary on AIX to use the special cc_r compiler alias.)
  13 dnl
  14 dnl If you are only building threads programs, you may wish to
  15 dnl use these variables in your default LIBS, CFLAGS, and CC:
  16 dnl
  17 dnl        LIBS="$PTHREAD_LIBS $LIBS"
  18 dnl        CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
  19 dnl        CC="$PTHREAD_CC"
  20 dnl
  21 dnl In addition, if the PTHREAD_CREATE_JOINABLE thread-attribute
  22 dnl constant has a nonstandard name, defines PTHREAD_CREATE_JOINABLE
  23 dnl to that name (e.g. PTHREAD_CREATE_UNDETACHED on AIX).
  24 dnl
  25 dnl ACTION-IF-FOUND is a list of shell commands to run if a threads
  26 dnl library is found, and ACTION-IF-NOT-FOUND is a list of commands
  27 dnl to run it if it is not found.  If ACTION-IF-FOUND is not specified,
  28 dnl the default action will define HAVE_PTHREAD.
  29 dnl
  30 dnl Please let the authors know if this macro fails on any platform,
  31 dnl or if you have any other suggestions or comments.  This macro was
  32 dnl based on work by SGJ on autoconf scripts for FFTW (www.fftw.org)
  33 dnl (with help from M. Frigo), as well as ac_pthread and hb_pthread
  34 dnl macros posted by AFC to the autoconf macro repository.  We are also
  35 dnl grateful for the helpful feedback of numerous users.
  36 dnl
  37 dnl @author Steven G. Johnson <stevenj@alum.mit.edu> and Alejandro Forero Cuervo <bachue@bachue.com>
  38
  39 AC_DEFUN([ACX_PTHREAD], [
  40 AC_REQUIRE([AC_CANONICAL_HOST])
  41 AC_LANG_SAVE
  42 AC_LANG_C
  43 acx_pthread_ok=no
  44
  45 # We used to check for pthread.h first, but this fails if pthread.h
  46 # requires special compiler flags (e.g. on True64 or Sequent).
  47 # It gets checked for in the link test anyway.
  48
  49 # First of all, check if the user has set any of the PTHREAD_LIBS,
  50 # etcetera environment variables, and if threads linking works using
  51 # them:
  52 if test x"$PTHREAD_LIBS$PTHREAD_CFLAGS" != x; then
  53         save_CFLAGS="$CFLAGS"
  54         CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
  55         save_LIBS="$LIBS"
  56         LIBS="$PTHREAD_LIBS $LIBS"
  57         AC_MSG_CHECKING([for pthread_join in LIBS=$PTHREAD_LIBS with CFLAGS=$PTHREAD_CFLAGS])
  58         AC_TRY_LINK_FUNC(pthread_join, acx_pthread_ok=yes)
  59         AC_MSG_RESULT($acx_pthread_ok)
  60         if test x"$acx_pthread_ok" = xno; then
  61                 PTHREAD_LIBS=""
  62                 PTHREAD_CFLAGS=""
  63         fi
  64         LIBS="$save_LIBS"
  65         CFLAGS="$save_CFLAGS"
  66 fi
  67
  68 # We must check for the threads library under a number of different
  69 # names; the ordering is very important because some systems
  70 # (e.g. DEC) have both -lpthread and -lpthreads, where one of the
  71 # libraries is broken (non-POSIX).
  72
  73 # Create a list of thread flags to try.  Items starting with a "-" are
  74 # C compiler flags, and other items are library names, except for "none"
  75 # which indicates that we try without any flags at all.
  76
  77 acx_pthread_flags="pthreads none -Kthread -kthread lthread -pthread -pthreads -mthreads pthread --thread-safe -mt"
  78
  79 # The ordering *is* (sometimes) important.  Some notes on the
  80 # individual items follow:
  81
  82 # pthreads: AIX (must check this before -lpthread)
  83 # none: in case threads are in libc; should be tried before -Kthread and
  84 #       other compiler flags to prevent continual compiler warnings
  85 # -Kthread: Sequent (threads in libc, but -Kthread needed for pthread.h)
  86 # -kthread: FreeBSD kernel threads (preferred to -pthread since SMP-able)
  87 # lthread: LinuxThreads port on FreeBSD (also preferred to -pthread)
  88 # -pthread: Linux/gcc (kernel threads), BSD/gcc (userland threads)
  89 # -pthreads: Solaris/gcc
  90 # -mthreads: Mingw32/gcc, Lynx/gcc
  91 # -mt: Sun Workshop C (may only link SunOS threads [-lthread], but it
  92 #      doesn't hurt to check since this sometimes defines pthreads too;
  93 #      also defines -D_REENTRANT)
  94 # pthread: Linux, etcetera
  95 # --thread-safe: KAI C++
  96
  97 case "${host_cpu}-${host_os}" in
  98         *solaris*)
  99
 100         # On Solaris (at least, for some versions), libc contains stubbed
 101         # (non-functional) versions of the pthreads routines, so link-based
 102         # tests will erroneously succeed.  (We need to link with -pthread or
 103         # -lpthread.)  (The stubs are missing pthread_cleanup_push, or rather
 104         # a function called by this macro, so we could check for that, but
 105         # who knows whether they'll stub that too in a future libc.)  So,
 106         # we'll just look for -pthreads and -lpthread first:
 107
 108         acx_pthread_flags="-pthread -pthreads pthread -mt $acx_pthread_flags"
 109         ;;
 110 esac
 111
 112 if test x"$acx_pthread_ok" = xno; then
 113 for flag in $acx_pthread_flags; do
 114
 115         case $flag in
 116                 none)
 117                 AC_MSG_CHECKING([whether pthreads work without any flags])
 118                 ;;
 119
 120                 -*)
 121                 AC_MSG_CHECKING([whether pthreads work with $flag])
 122                 PTHREAD_CFLAGS="$flag"
 123                 ;;
 124
 125                 *)
 126                 AC_MSG_CHECKING([for the pthreads library -l$flag])
 127                 PTHREAD_LIBS="-l$flag"
 128                 ;;
 129         esac
 130
 131         save_LIBS="$LIBS"
 132         save_CFLAGS="$CFLAGS"
 133         LIBS="$PTHREAD_LIBS $LIBS"
 134         CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 135
 136         # Check for various functions.  We must include pthread.h,
 137         # since some functions may be macros.  (On the Sequent, we
 138         # need a special flag -Kthread to make this header compile.)
 139         # We check for pthread_join because it is in -lpthread on IRIX
 140         # while pthread_create is in libc.  We check for pthread_attr_init
 141         # due to DEC craziness with -lpthreads.  We check for
 142         # pthread_cleanup_push because it is one of the few pthread
 143         # functions on Solaris that doesn't have a non-functional libc stub.
 144         # We try pthread_create on general principles.
 145         AC_TRY_LINK([#include <pthread.h>],
 146                     [pthread_t th; pthread_join(th, 0);
 147                      pthread_attr_init(0); pthread_cleanup_push(0, 0);
 148                      pthread_create(0,0,0,0); pthread_cleanup_pop(0); ],
 149                     [acx_pthread_ok=yes])
 150
 151         LIBS="$save_LIBS"
 152         CFLAGS="$save_CFLAGS"
 153
 154         AC_MSG_RESULT($acx_pthread_ok)
 155         if test "x$acx_pthread_ok" = xyes; then
 156                 break;
 157         fi
 158
 159         PTHREAD_LIBS=""
 160         PTHREAD_CFLAGS=""
 161 done
 162 fi
 163
 164 # Various other checks:
 165 if test "x$acx_pthread_ok" = xyes; then
 166         save_LIBS="$LIBS"
 167         LIBS="$PTHREAD_LIBS $LIBS"
 168         save_CFLAGS="$CFLAGS"
 169         CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 170
 171         # Detect AIX lossage: threads are created detached by default
 172         # and the JOINABLE attribute has a nonstandard name (UNDETACHED).
 173         AC_MSG_CHECKING([for joinable pthread attribute])
 174         AC_TRY_LINK([#include <pthread.h>],
 175                     [int attr=PTHREAD_CREATE_JOINABLE;],
 176                     ok=PTHREAD_CREATE_JOINABLE, ok=unknown)
 177         if test x"$ok" = xunknown; then
 178                 AC_TRY_LINK([#include <pthread.h>],
 179                             [int attr=PTHREAD_CREATE_UNDETACHED;],
 180                             ok=PTHREAD_CREATE_UNDETACHED, ok=unknown)
 181         fi
 182         if test x"$ok" != xPTHREAD_CREATE_JOINABLE; then
 183                 AC_DEFINE(PTHREAD_CREATE_JOINABLE, $ok,
 184                           [Define to the necessary symbol if this constant
 185                            uses a non-standard name on your system.])
 186         fi
 187         AC_MSG_RESULT(${ok})
 188         if test x"$ok" = xunknown; then
 189                 AC_MSG_WARN([we do not know how to create joinable pthreads])
 190         fi
 191
 192         AC_MSG_CHECKING([if more special flags are required for pthreads])
 193         flag=no
 194         case "${host_cpu}-${host_os}" in
 195                 *-aix* | *-freebsd*)     flag="-D_THREAD_SAFE";;
 196                 *-osf* | *-hpux*) flag="-D_REENTRANT";;
 197                 *solaris*)
 198                 if test "$GCC" = "yes"; then
 199                     flag="-D_REENTRANT"
 200                 else
 201                     flag="-mt -D_REENTRANT"
 202                 fi
 203                 ;;
 204         esac
 205         AC_MSG_RESULT(${flag})
 206         if test "x$flag" != xno; then
 207                 PTHREAD_CFLAGS="$flag $PTHREAD_CFLAGS"
 208         fi
 209
 210         LIBS="$save_LIBS"
 211         CFLAGS="$save_CFLAGS"
 212
 213         # More AIX lossage: must compile with cc_r
 214         AC_CHECK_PROG(PTHREAD_CC, cc_r, cc_r, ${CC})
 215 else
 216         PTHREAD_CC="$CC"
 217 fi
 218
 219 AC_SUBST(PTHREAD_LIBS)
 220 AC_SUBST(PTHREAD_CFLAGS)
 221 AC_SUBST(PTHREAD_CC)
 222
 223 # Finally, execute ACTION-IF-FOUND/ACTION-IF-NOT-FOUND:
 224 if test x"$acx_pthread_ok" = xyes; then
 225         ifelse([$1],,AC_DEFINE(HAVE_PTHREAD,1,[Define if you have POSIX threads libraries and header files.]),[$1])
 226         :
 227 else
 228         acx_pthread_ok=no
 229         $2
 230 fi
 231
 232 saveCFLAGS="$CFLAGS"
 233 saveLIBS="$LIBS"
 234 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 235 LIBS="$LIBS $PTHREAD_LIBS"
 236 AC_CHECK_FUNCS([pthread_rwlock_init])
 237 LIBS="$saveLIBS"
 238 CFLAGS="$saveCFLAGS"
 239
 240 AC_LANG_RESTORE
 241 ])dnl ACX_PTHREAD